TRIGGER PROCEDURE FOR WRITE OF ArtLager
    NEW BUFFER NArtLager
    OLD BUFFER OArtLager.

    DEF VAR cDiff       AS CHAR                     NO-UNDO.
    DEF VAR cFeld       AS CHAR                     NO-UNDO.
    DEF VAR kk          AS INT                      NO-UNDO.
    DEF VAR kx          AS INT                      NO-UNDO.
    DEF VAR cWort       AS CHAR                     NO-UNDO.
    
    DISABLE TRIGGERS FOR LOAD OF Artst.
 
    BUFFER-COMPARE NArtLager USING Bestand  Reserviert
                                   Bestellt Mind_Bestand Soll_Bestand
                   TO OArtLager
                   SAVE RESULT IN cDiff.
    IF cDiff = '' THEN RETURN.
    
    FIND Artst
            WHERE Artst.Firma  = NArtLager.Firma
            AND   Artst.Artnr  = NArtLager.Artnr
            AND   Artst.Inhalt = NArtLager.Inhalt
            AND   Artst.Jahr   = NArtLager.Jahr NO-ERROR.
    IF NOT AVAILABLE Artst THEN RETURN.
    IF NOT Artst.Lager     THEN RETURN.
    ASSIGN  Artst.Bestand      = NArtLager.Bestand
            Artst.Reserviert   = NArtLager.Reserviert
            Artst.Bestellt     = NArtLager.Bestellt
            Artst.Mind_Bestand = NArtLager.Mind_Bestand
            Artst.Soll_Bestand = NArtLager.Soll_Bestand
            .
    FOR EACH ArtLager NO-LOCK
            WHERE ArtLager.Firma  = NArtLager.Firma
            AND   ArtLager.Artnr  = NArtLager.Artnr
            AND   ArtLager.Inhalt = NArtLager.Inhalt
            AND   ArtLager.Jahr   = NArtLager.Jahr
            AND   ArtLager.Lager <> NArtLager.Lager:
        ASSIGN  Artst.Bestand      = Artst.Bestand      + ArtLager.Bestand
                Artst.Reserviert   = Artst.Reserviert   + ArtLager.Reserviert
                Artst.Bestellt     = Artst.Bestellt     + ArtLager.Bestellt
                Artst.Mind_Bestand = Artst.Mind_Bestand + ArtLager.Mind_Bestand
                Artst.Soll_Bestand = Artst.Soll_Bestand + ArtLager.Soll_Bestand
                .
    END.
    
    RELEASE Artst.