DEF VAR ii      AS INT NO-UNDO.

DEF BUFFER bArtbw FOR Artbw.

DEF TEMP-TABLE tStatistik
    FIELD iKnr          AS INT
    FIELD cAnschrift    AS CHAR     EXTENT 12
    FIELD cMail         AS CHAR
    FIELD cSprache      AS CHAR 
    FIELD nUmsatz       AS DEC      EXTENT 10
    FIELD nTotal        AS DEC
    FIELD dLetztVerkauf AS DATE
    .
    
FOR EACH Debst NO-LOCK
    WHERE Debst.Firma = '1000'
    AND   Debst.Aktiv,
    
    FIRST Adresse NO-LOCK
        WHERE Adresse.Firma = Debst.Firma
        AND   Adresse.Knr   = Debst.Knr
        AND   Adresse.Aktiv,
        
    FIRST Artbw NO-LOCK USE-INDEX Artbw-k3
        WHERE Artbw.Firma  = Debst.Firma
        AND   Artbw.Knr    = Debst.Knr
        AND   Artbw.Datum <> ?
        AND   Artbw.Datum >= 01/01/2017
        AND   Artbw.Tr_Art = 1:
        
    CREATE  tStatistik.
    ASSIGN  tStatistik.iKnr          = Debst.Knr
            tStatistik.cAnschrift    = Adresse.Anschrift
            tStatistik.cMail         = Adresse.Mail
            tStatistik.dLetztVerkauf = Artbw.Datum.
    CASE Adresse.Sprcd:
        WHEN 1 THEN tStatistik.cSprache = 'Deutsch'.
        WHEN 2 THEN tStatistik.cSprache = 'Italienisch'.
        WHEN 3 THEN tStatistik.cSprache = 'Französisch'.
        WHEN 4 THEN tStatistik.cSprache = 'Englisch'.
    END CASE.
    
    FOR EACH bArtbw NO-LOCK USE-INDEX Artbw-k3
        WHERE bArtbw.Firma  = Debst.Firma
        AND   bArtbw.Knr    = Debst.Knr
        AND   bArtbw.Datum <> ?
        AND   bArtbw.Datum >= 01/01/2017
        AND   bArtbw.Tr_Art = 1:
        
        ii = YEAR(TODAY) - YEAR(bArtbw.Datum) + 1.
        IF ii < 1 THEN ii = 1.
        ASSIGN  tStatistik.nUmsatz[ii] = tStatistik.nUmsatz[ii] + bArtbw.Net_Betr
                tStatistik.nTotal      = tStatistik.nTotal      + bArtbw.Net_Betr.
        IF bArtbw.Datum > tStatistik.dLetztVerkauf THEN tStatistik.dLetztVerkauf = bArtbw.Datum.
    END.
END.

OUTPUT TO 'C:\TEMP\KundenAuswertung.csv' NO-MAP NO-CONVERT.
FOR EACH tStatistik:
    EXPORT DELIMITER ';'
        tStatistik.iKnr
        tStatistik.cAnschrift[05]
        tStatistik.cAnschrift[06]
        tStatistik.cAnschrift[07]
        tStatistik.cAnschrift[08]
        tStatistik.cAnschrift[09]
        tStatistik.cAnschrift[10]
        tStatistik.cAnschrift[11]
        tStatistik.cMail
        tStatistik.cSprache
        tStatistik.nUmsatz[01]
        tStatistik.nUmsatz[02]
        tStatistik.nUmsatz[03]
        tStatistik.nUmsatz[04]
        tStatistik.nUmsatz[05]
        tStatistik.nUmsatz[06]
        tStatistik.nTotal
        STRING(tStatistik.dLetztVerkauf,'99.99.9999')
        .
END.
OUTPUT CLOSE.