DEF VAR cPath   AS CHAR                     NO-UNDO
                INIT 'C:\Entwicklung\subversion\Ge_MIS\TRUNK\OE102A\'.
DEF VAR xPath   AS CHAR                     NO-UNDO.
DEF VAR xName   AS CHAR                     NO-UNDO.
DEF VAR cParam  AS CHAR                     NO-UNDO.
DEF VAR cExt    AS CHAR                     NO-UNDO.
DEF VAR cNext   AS CHAR                     NO-UNDO
                INIT 'r,wrx,bmp,jpg,ico,tif,gif'.
DEF VAR iNum    AS INT                      NO-UNDO.

DEF TEMP-TABLE TDateien FIELD   cName       AS CHAR     FORMAT "x(15)"
                        FIELD   cPath       AS CHAR     FORMAT "x(40)"
                        FIELD   cType       AS CHAR.

EMPTY TEMP-TABLE TDateien.

RUN Fuellen_TDateien ( INPUT cPath ).

OUTPUT TO 'CreateLibListe' NO-ECHO NO-MAP.
cParam = '-add'.
xPath  = ''.
DO WHILE TRUE:
    FOR EACH TDateien.
        IF TDateien.cType = 'D' THEN DO:
            IF TDateien.cName = '.' THEN DO:
                DELETE  TDateien.
                NEXT.
            END.
            IF TDateien.cName = '..' THEN DO:
                DELETE  TDateien.
                NEXT.
            END.
            IF TDateien.cName <> 'adm2'         AND
               TDateien.cName <> 'grafik'       AND
               TDateien.cName <> 'v8'           AND
               TDateien.cName <> 'src_dlcv91c'  AND
               TDateien.cName <> 'src'          AND
               TDateien.cName <> 'template'     AND
               TDateien.cName <> 'TRIGGERS'     AND
               TDateien.cName <> 'super'        THEN DO:
                DELETE  TDateien.
                NEXT.
            END.
            NEXT.
        END.
        IF TDateien.cType <> 'F' THEN DO:
            DELETE  TDateien.
            NEXT.
        END.
        iNum = NUM-ENTRIES(TDateien.cName, '.').
        IF iNum < 2 THEN DO:
            DELETE  TDateien.
            NEXT.
        END.
        cExt = ENTRY(iNum, TDateien.cName, '.').
        IF LOOKUP(cExt, cNext, ',') = 0 THEN DO:
            DELETE  TDateien.
            NEXT.
        END.
        xName = REPLACE(TDateien.cPath, cPath, '').
        IF (LENGTH(xName) + LENGTH(cParam)) > 230 THEN DO:
            PUT CONTROL cParam.
            PUT ' ' SKIP.
            cParam = '-add'.
        END.
        cParam = cParam + ' ' + xName.
        DELETE  TDateien.
    END.
    FIND FIRST TDateien NO-LOCK NO-ERROR.
    IF NOT AVAILABLE TDateien THEN LEAVE.
    xPath = REPLACE(TDateien.cPath, cPath, '') + '\'.
    DELETE  TDateien.
    RUN Fuellen_TDateien ( INPUT xPath ).
END.
PUT CONTROL cParam.
PUT ' ' SKIP.
OUTPUT CLOSE.

RETURN.

PROCEDURE Fuellen_TDateien:

    DEF INPUT PARAMETER ipDir   AS CHAR             NO-UNDO.

    INPUT FROM OS-DIR(ipDir) NO-ECHO.
    REPEAT TRANSACTION ON ERROR UNDO, LEAVE:
        CREATE  TDateien.
        IMPORT  TDateien.
    END.
    INPUT CLOSE.

END PROCEDURE.