/*------------------------------------------------------------------------
    File        : MHDListe.p
    Purpose     : 

    Syntax      :

    Description : 

    Author(s)   : walter.riechsteiner
    Created     : Thu May 06 09:09:53 CEST 2021
    Notes       :
  ----------------------------------------------------------------------*/

/* ***************************  Definitions  ************************** */

BLOCK-LEVEL ON ERROR UNDO, THROW.

DEFINE TEMP-TABLE tArtLager LIKE ArtLager
    FIELD TagesBestand AS INTEGER.

DEFINE TEMP-TABLE tMHDListe
    FIELD Artnr      AS INTEGER
    FIELD Inhalt     AS INTEGER
    FIELD Jahr       AS INTEGER
    FIELD Lagerplatz AS CHARACTER
    FIELD Bestand    AS INTEGER
    FIELD Verfall    AS DATE      FORMAT "99.99.9999"
    FIELD Menge      AS INTEGER
    
    INDEX tMHDListe-k1 IS PRIMARY 
    Artnr
    Inhalt
    Jahr
    Lagerplatz
    Verfall
    .

/* ********************  Preprocessor Definitions  ******************** */


/* ***************************  Main Block  *************************** */

FOR EACH Artst NO-LOCK 
    WHERE Artst.Firma  = '1000'
    AND   Artst.Aktiv
    AND   Artst.Lager
    AND   Artst.lVerfall,
    
    FIRST ArtLager NO-LOCK OF Artst:
        
    CREATE  tArtLager.
    BUFFER-COPY ArtLager TO tArtLager
        ASSIGN  
        tArtLager.TagesBestand = ArtLager.Bestand.
        
    FOR EACH Aufze NO-LOCK
        WHERE Aufze.Firma    = Artst.Firma
        AND   Aufze.Artnr    = Artst.Artnr
        AND   Aufze.Inhalt   = Artst.Inhalt
        AND   Aufze.Jahr     = Artst.Jahr
        AND   Aufze.Lag_Buch = TRUE ,
            
        FIRST Aufko NO-LOCK OF Aufze:
                
        IF Aufko.Lief_Datum <= (TODAY + 1) THEN NEXT.
        tArtLager.TagesBestand = tArtLager.TagesBestand + Aufze.MGeli.
    END.
END.

FOR EACH tArtLager:
    FOR EACH HoReLager NO-LOCK 
        WHERE HoReLager.Firma  = tArtLager.Firma
        AND   HoReLager.Lager  = tArtLager.Lager
        AND   HoReLager.Artnr  = tArtLager.Artnr
        AND   HoReLager.Inhalt = tArtLager.Inhalt
        AND   HoReLager.Jahr   = tArtLager.Jahr:
            
        FOR EACH LotLager NO-LOCK 
            WHERE LotLager.HoReLager_Id = HoReLager.HoReLager_Id:
                
            CREATE  tMHDListe.
            ASSIGN  
                tMHDListe.Artnr      = tArtLager.Artnr
                tMHDListe.Inhalt     = tArtLager.Inhalt
                tMHDListe.Jahr       = tArtLager.Jahr
                tMHDListe.Lagerplatz = HoReLager.cSort
                tMHDListe.Bestand    = HoReLager.Bestand
                tMHDListe.Verfall    = LotLager.Verfall
                tMHDListe.Menge      = LotLager.Bestand.
        END.
    END.
END.

OUTPUT TO 'D:\LogFiles\MHDListe.csv' NO-MAP NO-CONVERT.
FOR EACH tArtLager:
    FIND Artst NO-LOCK OF tArtLager.
    FIND FIRST Artbez NO-LOCK
        WHERE ArtBez.Firma  = tArtLager.Firma
        AND   ArtBez.Artnr  = tArtLager.Artnr
        AND   ArtBez.Inhalt = tArtLager.Inhalt
        AND   ArtBez.Jahr   = tArtLager.Jahr.
    FIND KGebinde NO-LOCK 
        WHERE KGebinde.Firma  = Artst.Firma
        AND   KGebinde.Geb_Cd = Artst.KGeb_Cd.
    FOR EACH tMHDListe
        WHERE tMHDListe.Artnr  = tArtLager.Artnr
        AND   tMHDListe.Inhalt = tArtLager.Inhalt
        AND   tMHDListe.Jahr   = tArtLager.Jahr.
        EXPORT DELIMITER ';'
            tArtLager.Artnr
            tArtLager.Inhalt
            tArtLager.Jahr
            tArtLager.Bestand
            tArtLager.TagesBestand
            Artbez.Bez1 + ' ' + Artbez.Bez2
            KGebinde.KBez
            tMHDListe.Lagerplatz
            tMHDListe.Bestand
            tMHDListe.Verfall
            tMHDListe.Menge.
    END.
END.
OUTPUT CLOSE.