GeMIS_WEB/GUI/DruckProgramme/realwines/Sav_Faktura_pdf.p

&ANALYZE-SUSPEND _VERSION-NUMBER AB_v10r12
&ANALYZE-RESUME
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _DEFINITIONS Procedure 
/*------------------------------------------------------------------------
    File        : 
    Purpose     :

    Syntax      :

    Description :

    Author(s)   :
    Created     :
    Notes       :
  ----------------------------------------------------------------------*/
/*          This .W file was created with the Progress AppBuilder.      */
/*----------------------------------------------------------------------*/

/* ***************************  Definitions  ************************** */

DEFINE INPUT  PARAMETER iphParam   AS HANDLE           NO-UNDO.
DEFINE OUTPUT PARAMETER opcResult  AS CHARACTER        NO-UNDO.

DEFINE VARIABLE iSeite        AS INTEGER   NO-UNDO.
DEFINE VARIABLE iAnzDok       AS INTEGER   NO-UNDO.
DEFINE VARIABLE iLauf         AS INTEGER   NO-UNDO.
DEFINE VARIABLE lFirst        AS LOG       INIT FALSE NO-UNDO.
DEFINE VARIABLE lLast         AS LOG       INIT FALSE NO-UNDO.
DEFINE VARIABLE lPreis        AS LOG       NO-UNDO.

DEFINE VARIABLE cFirma        AS CHARACTER NO-UNDO.
DEFINE VARIABLE AdFirma       AS CHARACTER NO-UNDO.
DEFINE VARIABLE nFakBetr      AS DECIMAL   NO-UNDO.
DEFINE VARIABLE dFakDatum     AS DATE      NO-UNDO.
DEFINE VARIABLE iFaknr        AS INTEGER   NO-UNDO.
DEFINE VARIABLE iSprcd        AS INTEGER   NO-UNDO.
DEFINE VARIABLE nTotale       AS DECIMAL   EXTENT 15 NO-UNDO.
DEFINE VARIABLE cFormtext     AS CHARACTER EXTENT 30 NO-UNDO.
DEFINE VARIABLE cRabText      AS CHARACTER NO-UNDO.
DEFINE VARIABLE cZusText      AS CHARACTER NO-UNDO.
DEFINE VARIABLE cEpzText      AS CHARACTER NO-UNDO.
DEFINE VARIABLE cBesrKopf     AS CHARACTER EXTENT 12 NO-UNDO.
DEFINE VARIABLE lDebIncl      AS LOG       NO-UNDO.
DEFINE VARIABLE Rundbetr      AS DECIMAL   DECIMALS 4 NO-UNDO.
DEFINE VARIABLE RundCode      AS INTEGER   INIT 1 NO-UNDO.
DEFINE VARIABLE htTabTexte    AS HANDLE    NO-UNDO.
DEFINE VARIABLE hSavko        AS HANDLE    NO-UNDO.
DEFINE VARIABLE cInstallation AS CHARACTER NO-UNDO.
DEFINE VARIABLE cFileName     AS CHARACTER NO-UNDO.
DEFINE VARIABLE iBesrArt      AS INTEGER   NO-UNDO.
DEFINE VARIABLE dMwstDatum    AS DATE      NO-UNDO.

DEFINE VARIABLE iMaxPos       AS INTEGER   INIT 2650 NO-UNDO.
DEFINE VARIABLE cvpr_Dokument AS CHARACTER NO-UNDO.
DEFINE VARIABLE iArtZeile     AS INTEGER   NO-UNDO.
DEFINE VARIABLE iVPagePos     AS INTEGER   NO-UNDO.
DEFINE VARIABLE iVGroupPos    AS INTEGER   NO-UNDO.

DEFINE BUFFER bSavko   FOR Savko   .
DEFINE BUFFER bSavze   FOR Savze   .
DEFINE BUFFER FDebst   FOR Debst   .       /*  Fakturaadresse  */
DEFINE BUFFER LDebst   FOR Debst   .       /*  Lieferadresse   */
DEFINE BUFFER bDebst   FOR Debst   .       /*  Bank/Verband    */
DEFINE BUFFER LAdresse FOR Adresse .
DEFINE BUFFER bAdresse FOR Adresse .
DEFINE BUFFER bWust    FOR Wust    .
DEFINE BUFFER bSteuer  FOR Steuer  .

{ incl/properties.i }
{ incl/ttdruckparam.i }
{ swissqr/propertiesSwissQR.i }

DEFINE TEMP-TABLE tDokument
    FIELD cGruppe AS CHARACTER
    FIELD iZeile  AS INTEGER
    FIELD cFeld   AS CHARACTER
    FIELD cInhalt AS CHARACTER
    
    INDEX tDokument-k1 IS PRIMARY
    cGruppe
    iZeile
    cFeld
    .
DEFINE TEMP-TABLE tTotale
    FIELD nMwstPfl AS DECIMAL EXTENT 12
    FIELD nMwstBet AS DECIMAL EXTENT 12
    FIELD nSammTot AS DECIMAL
    FIELD nSkBer   AS DECIMAL
    FIELD nWW      AS DECIMAL
    .
DEFINE TEMP-TABLE sSavko
    FIELD cFirma   AS CHARACTER
    FIELD iAufnr   AS INTEGER
    FIELD iFak_Knr AS INTEGER
    FIELD iKnr     AS INTEGER
    FIELD iSamm_Nr AS INTEGER
    FIELD iRecid   AS RECID
    FIELD iFaknr   AS INTEGER
    FIELD dFakDat  AS DATE
    .
DEFINE TEMP-TABLE tSavko LIKE Savko
    FIELD iRecid  AS RECID
    FIELD lBetrag AS LOGICAL
    .
DEFINE TEMP-TABLE tSavze
    FIELD Aufnr  AS INTEGER
    FIELD Sort1  AS CHARACTER
    FIELD Sort2  AS CHARACTER
    FIELD Sort3  AS CHARACTER
    FIELD Artnr  AS INTEGER
    FIELD Inhalt AS INTEGER
    FIELD Jahr   AS INTEGER
    FIELD Pos    AS INTEGER
    FIELD Zeile  AS RECID
    FIELD Preis  AS DECIMAL   DECIMALS 4
    FIELD Aktion AS LOG
    FIELD LagOrt AS CHARACTER
    FIELD MGeli  AS DECIMAL
    FIELD MRuek  AS DECIMAL
    
    INDEX tSavze-k1 IS PRIMARY
    Aufnr
    Sort1
    Sort2
    Sort3
    .
DEFINE TEMP-TABLE tRueckst LIKE tSavze
    .

DEFINE TEMP-TABLE tSpeRab
    FIELD Rab_Grp  AS INTEGER
    FIELD Auf_Betr AS DECIMAL DECIMALS 4
    .
DEFINE TEMP-TABLE tGebKto
    FIELD Sort_Cd  AS CHARACTER
    FIELD Geb_Cd   AS CHARACTER
    FIELD Bez      AS CHARACTER
    FIELD Preis    AS DECIMAL
    FIELD A_Anz    AS DECIMAL
    FIELD A_Betrag AS DECIMAL
    FIELD E_Anz    AS DECIMAL
    FIELD E_Betrag AS DECIMAL
    FIELD MWST_Art AS INTEGER
    FIELD MWST_Cd  AS INTEGER
    .
DEFINE TEMP-TABLE tRabSumm
    FIELD Rab_Summ  AS INTEGER
    FIELD Bez       AS CHARACTER
    FIELD F_Rab_Art AS INTEGER
    FIELD F_Wert    AS DECIMAL   DECIMALS 4
    FIELD A_Rab_Art AS INTEGER
    FIELD A_Wert    AS DECIMAL   DECIMALS 4
    FIELD Auf_Rab   AS DECIMAL   DECIMALS 4
    FIELD Abh_Rab   AS DECIMAL   DECIMALS 4
    .
DEFINE TEMP-TABLE tUmsGrp
    FIELD Ums_Grp  AS INTEGER
    FIELD Mwst     AS INTEGER
    FIELD Ansatz   AS DECIMAL
    FIELD Bez      AS CHARACTER
    FIELD lInkl    AS LOG
    FIELD Ums_Betr AS DECIMAL   DECIMALS 4
    .
DEFINE TEMP-TABLE tTabTexte
    FIELD cRecArt AS CHARACTER
    FIELD iZeile  AS INTEGER
    FIELD cFeld1  AS CHARACTER
    FIELD cFeld2  AS CHARACTER
    FIELD cFeld3  AS CHARACTER
    FIELD iFeld1  AS INTEGER
    FIELD iFeld2  AS INTEGER
    FIELD iFeld3  AS INTEGER
    
    INDEX tTabTexte-k1 IS PRIMARY
    cRecArt
    iZeile.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ANALYZE-SUSPEND _UIB-PREPROCESSOR-BLOCK 

/* ********************  Preprocessor Definitions  ******************** */

&Scoped-define PROCEDURE-TYPE Procedure
&Scoped-define DB-AWARE no



/* _UIB-PREPROCESSOR-BLOCK-END */
&ANALYZE-RESUME



/* *********************** Procedure Settings ************************ */

&ANALYZE-SUSPEND _PROCEDURE-SETTINGS
/* Settings for THIS-PROCEDURE
   Type: Procedure
   Allow: 
   Frames: 0
   Add Fields to: Neither
   Other Settings: CODE-ONLY COMPILE
 */
&ANALYZE-RESUME _END-PROCEDURE-SETTINGS

/* *************************  Create Window  ************************** */

&ANALYZE-SUSPEND _CREATE-WINDOW
/* DESIGN Window definition (used by the UIB) 
  CREATE WINDOW Procedure ASSIGN
         HEIGHT             = 18.62
         WIDTH              = 59.4.
/* END WINDOW DEFINITION */
                                                                        */
&ANALYZE-RESUME

 


&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _MAIN-BLOCK Procedure 


/* ***************************  Main Block  *************************** */

opcResult = ''.

EMPTY TEMP-TABLE tParam.
CREATE tParam.
htParam:BUFFER-COPY(iphParam).
ASSIGN  
    cFirma        = tParam.cFirma
    iAnzDok       = tParam.Anzahl
    lPreis        = TRUE
    cInstallation = DYNAMIC-FUNCTION ('getInstallation':U) NO-ERROR.
            
FIND bSteuer NO-LOCK WHERE bSteuer.Firma = cFirma.
AdFirma = bSteuer.AdFirma.

RUN AUFTRAG_ERMITTELN.
IF opcResult <> '' THEN RETURN.

FOR EACH sSavko
    BY sSavko.iFak_Knr:
        
    FIND FIRST tParam.

    FIND bAdresse NO-LOCK
        WHERE bAdresse.Firma = AdFirma
        AND   bAdresse.Knr   = sSavko.iFak_Knr.
    iSprcd = bAdresse.Sprcd.
    IF  iSprcd <> 1 AND
        iSprcd <> 3 AND
        iSprcd <> 4 THEN iSprcd = 1.
    RUN GET_FORMTEXT ( tParam.cInstall, tParam.Template, iSprcd,
        OUTPUT cFormText ) NO-ERROR.
    cRabText =   TRIM(SUBSTRING(cFormText[04],01,20)).
    cZusText =   TRIM(SUBSTRING(cFormText[04],21,20)).
    cEpzText =   TRIM(SUBSTRING(cFormText[04],41,20)).
        
    { vpr.i INIT  }
{ vpr.i START }
                
    DO iLauf = 1 TO iAnzDok:
        
        dFakDatum = sSavko.dFakDat.
        iSeite    = 0.
        iFaknr    = sSavko.iFaknr.
        lFirst    = TRUE.
        lLast     = FALSE.
                    
        EMPTY TEMP-TABLE tUmsGrp    .
        EMPTY TEMP-TABLE tTotale    .
        EMPTY TEMP-TABLE tDokument  .
            
        CREATE  tTotale.
            
        FOR EACH bSavko NO-LOCK
            WHERE bSavko.Firma      = sSavko.cFirma
            AND   bSavko.Aufnr      = sSavko.iAufnr
                    
            BREAK
            BY bSavko.Firma
            BY bSavko.Aufnr :

            EMPTY TEMP-TABLE tSavze     .
            EMPTY TEMP-TABLE tGebKto    .
            EMPTY TEMP-TABLE tRabSumm   .
            EMPTY TEMP-TABLE tSpeRab    .
            EMPTY TEMP-TABLE tTabTexte  .
            EMPTY TEMP-TABLE tRueckst   .
            EMPTY TEMP-TABLE tSavko     .
                
            CREATE tSavko.
            BUFFER-COPY bSavko TO tSavko
                ASSIGN  
                tSavko.lBetrag = TRUE.
                
            FIND bAdresse NO-LOCK USE-INDEX Adresse-k1
                WHERE bAdresse.Firma = AdFirma
                AND   bAdresse.Knr   = bSavko.Fak_Knr NO-ERROR.
            FIND LDebst NO-LOCK USE-INDEX Debst-k1
                WHERE LDebst.Firma  = cFirma
                AND   LDebst.Knr    = bSavko.Knr NO-ERROR.
            FIND FDebst NO-LOCK USE-INDEX Debst-k1
                WHERE FDebst.Firma  = cFirma
                AND   FDebst.Knr    = bSavko.Fak_Knr NO-ERROR.
            FIND bWust NO-LOCK USE-INDEX Wust-k1
                WHERE bWust.CodeK    = LDebst.MWST
                AND   bWust.CodeA    = 99 NO-ERROR.
            lDebIncl  = FALSE.
            IF AVAILABLE bWust THEN lDebIncl = bWust.Incl.
        
            hSavko     = BUFFER bSavko:HANDLE.
            htTabTexte = TEMP-TABLE tTabTexte:DEFAULT-BUFFER-HANDLE.
                
            /*  Texte und Werte aus Tabelle 'Tabel' laden für RecArt */
            /*  FAKART, AUFSTATUS, LIEFART, FAHRER, WISO, ABLAD      */
                
            RUN CREATE_TABTEXTE ( hSavko, INPUT-OUTPUT htTabTexte ) NO-ERROR.
                
            RUN FUELLEN_tSavze ( bSavko.Aufnr ) NO-ERROR.
            
            dMwstDatum = (IF bSavko.Lief_Datum <> ? THEN bSavko.Lief_Datum ELSE bSavko.Kond_Datum).
            IF dMwstDatum = ? THEN dMwstDatum = bSavko.Fak_Datum.
            IF dMwstDatum = ? THEN dMwstDatum = TODAY. 
                
            FOR EACH tSavze
                WHERE tSavze.Artnr > 0:
                
                FIND bSavze NO-LOCK WHERE RECID(bSavze) = tSavze.Zeile.
                    
                /*  Spezial-Auftragsrabatt pro Lieferschein bilden  */
                
                IF bSavze.Auf_Sp_Grp > 0 THEN 
                DO:
                    FIND FIRST tSpeRab
                        WHERE tSpeRab.Rab_Grp = bSavze.Auf_Sp_Grp NO-ERROR.
                    IF NOT AVAILABLE tSpeRab THEN 
                    DO:
                        CREATE  tSpeRab.
                        ASSIGN  
                            tSpeRab.Rab_Grp = bSavze.Auf_Sp_Grp.
                    END.
                    tSpeRab.Auf_Betr = tSpeRab.Auf_Betr + bSavze.Auf_Sp_Rab.
                END.
                    
                /*  Summengruppen-Totale pro Lieferschein bilden  */
                    
                DO WHILE bSavze.Rab_Su_Grp > 0:
                    FIND FIRST tRabSumm
                        WHERE tRabSumm.Rab_Summ = bSavze.Rab_Su_Grp NO-ERROR.
                    IF NOT AVAILABLE tRabSumm THEN 
                    DO:
                        FIND FIRST RabSumm NO-LOCK
                            WHERE RabSumm.Firma    = bSavze.Firma
                            AND   RabSumm.Rab_Summ = bSavze.Rab_Su_Grp NO-ERROR.
                        IF NOT AVAILABLE RabSumm THEN LEAVE.
                        CREATE  tRabSumm.
                        ASSIGN  
                            tRabSumm.Rab_Summ = bSavze.Rab_Su_Grp
                            tRabSumm.Bez      = RabSumm.Bez
                            tRabSumm.Auf_Rab  = 0
                            tRabSumm.Abh_Rab  = 0.
                    END.
                    LEAVE.
                END.
            END.
                
            IF LAST-OF ( bSavko.Aufnr ) THEN lLast = TRUE.
                
            RUN DRUCKEN.

        END.
    END.
    { vpr.i STOP }
END.

PROCEDURE ShellExecuteA EXTERNAL "shell32.dll" :
    DEFINE INPUT PARAMETER lphwnd       AS LONG.
    DEFINE INPUT PARAMETER lpOperation  AS CHARACTER.
    DEFINE INPUT PARAMETER lpFile       AS CHARACTER.
    DEFINE INPUT PARAMETER lpParameters AS CHARACTER.
    DEFINE INPUT PARAMETER lpDirectory  AS CHARACTER.
    DEFINE INPUT PARAMETER nShowCmd     AS LONG.
    DEFINE RETURN PARAMETER hInstance   AS LONG.
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


/* **********************  Internal Procedures  *********************** */

&IF DEFINED(EXCLUDE-ARTIKELZEILE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE ARTIKELZEILE Procedure 
PROCEDURE ARTIKELZEILE :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipRecid AS RECID            NO-UNDO.
    
    DEFINE VARIABLE cString  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE nRabWert AS DECIMAL   NO-UNDO.
    DEFINE VARIABLE xRabText AS CHARACTER NO-UNDO.
    
    FIND tSavze WHERE RECID(tSavze) = ipRecid      NO-LOCK.
    FIND Savze  WHERE RECID(Savze)  = tSavze.Zeile NO-LOCK.

    iArtZeile = iArtZeile + 1.    
    DO WHILE Savze.Artnr = 0:
        cString = Savze.Bez1.
        IF Savze.Bez2 <> '' THEN 
        DO:
            cString = cString
                + (IF cString = '' THEN '' ELSE CHR(10))
                + Savze.Bez2.
        END.
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'ArtikelZeile1'
            tDokument.iZeile  = iArtZeile
            tDokument.cFeld   = 'Beschreibung'
            tDokument.cInhalt = cString.
        RETURN.
    END.

    FIND Artst OF Savze NO-LOCK.
            
    FIND GGebinde NO-LOCK
        WHERE GGebinde.Firma  = cFirma
        AND   GGebinde.Geb_Cd = Savze.GGeb_Cd NO-ERROR.
    FIND VGebinde NO-LOCK
        WHERE VGebinde.Firma  = cFirma
        AND   VGebinde.Geb_Cd = Savze.VGeb_Cd NO-ERROR.
    FIND KGebinde NO-LOCK
        WHERE KGebinde.Firma  = cFirma
        AND   KGebinde.Geb_Cd = Savze.KGeb_Cd NO-ERROR.

    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Artnr' , STRING(Savze.Artnr,"999999") ).
    
    cString = Savze.Bez1.
    IF Savze.Bez2 <> '' THEN 
    DO:
        cString = cString
            + (IF cString = '' THEN '' ELSE CHR(10))
            + Savze.Bez2.
    END.
    IF Savze.Aktion THEN 
    DO:
        cString = cString
            + (IF cString = '' THEN '' ELSE CHR(10))
            + '\b ' + Savze.Aktion_Text + ' \b0'.
    END.
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', cString ).
    
    IF Savze.Jahr > 9 THEN 
    DO:
        cString = STRING(Savze.Jahr,"9999").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'JG', cString ).
    END.

    IF Savze.Alk_Gehalt <> 0 THEN 
    DO:
        cString = STRING(Savze.Alk_Gehalt,"zz9.9%").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Alk%', cString ).
    END.

    IF Savze.VGeb_Me <> 0 THEN 
    DO:
        cString = TRIM(STRING(Savze.VGeb_Me,'->>>')
            + 'x '
            + STRING(VGebinde.KBez,'x(10)')).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'VGeb_Menge', cString ).
    END.
    
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Menge'   , TRIM(STRING(Savze.MBest,'->>,>>9')) ).

    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'KGeb_Bez', KGebinde.Kbez ).
    
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis'   , STRING(Savze.Preis   ,'>,>>9.99') ).
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag'  , STRING(Savze.Bru_Betr,'->>>,>>9.99') ).
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'MC'      , STRING(Savze.WuCd    ,'z9') ).
    
        
    /*    IF Savze.Rab_Betr <> 0 THEN                                                                                          */
    /*    DO:                                                                                                                  */
    /*        iArtZeile = iArtZeile + 1.                                                                                       */
    /*        nRabWert  = ABSOLUTE(Savze.Rab_Wert).                                                                            */
    /*        IF Savze.Rab_Art = 3 THEN xRabText = cEpzText.                                                                   */
    /*        ELSE                                                                                                             */
    /*        DO:                                                                                                              */
    /*            IF Savze.Rab_Betr < 0 THEN xRabText = cZusText.                                                              */
    /*            IF Savze.Rab_Betr > 0 THEN xRabText = cRabText.                                                              */
    /*        END.                                                                                                             */
    /*        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', TRIM(xRabText) ).                        */
    /*                                                                                                                         */
    /*        IF  Savze.Rab_Art = 1    THEN cString = STRING(nRabWert,"->9.9%").                                               */
    /*        IF  Savze.Rab_Art = 2    OR                                                                                      */
    /*            Savze.Rab_Art = 3    THEN cString = STRING(nRabWert,"-9.99").                                                */
    /*        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', cString ).                                      */
    /*        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(- Savze.Rab_Betr,"->>>,>>9.99")) ).*/
    /*    END.                                                                                                                 */
    
    /*    DO WHILE TRUE:                                                                                                       */
    /*        IF Savze.Zus_Betr = 0 THEN LEAVE.                                                                                */
    /*                                                                                                                         */
    /*        iArtZeile = iArtZeile + 1.                                                                                       */
    /*        nRabWert   = ABSOLUTE(Savze.Zus_Wert).                                                                           */
    /*        IF Savze.Zus_Art = 3 THEN xRabText = cEpzText.                                                                   */
    /*        ELSE                                                                                                             */
    /*        DO:                                                                                                              */
    /*            IF Savze.Zus_Betr < 0 THEN xRabText = cRabText.                                                              */
    /*            IF Savze.Zus_Betr > 0 THEN xRabText = cZusText.                                                              */
    /*        END.                                                                                                             */
    /*        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', TRIM(xRabText) ).                        */
    /*                                                                                                                         */
    /*        IF Savze.Zus_Art = 1    THEN cString = STRING(nRabWert,"->9.9%").                                                */
    /*        IF Savze.Zus_Art = 2    OR                                                                                       */
    /*            Savze.Zus_Art = 3    THEN cString = STRING(nRabWert,"-9.99").                                                */
    /*        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', cString ).                                      */
    /*        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(+ Savze.Zus_Betr,"->>>,>>9.99")) ).*/
    /*        LEAVE.                                                                                                           */
    /*    END.                                                                                                                 */
    
    /*  ----  Summengruppen-Total  -------------------------------------------- */
        
    IF Savze.Rab_Su_Grp <> 0 THEN 
    DO:
        FIND FIRST TRabSumm WHERE TRabSumm.Rab_Summ = Savze.Rab_Su_Grp NO-ERROR.
        IF AVAILABLE TRabSumm THEN 
        DO:
            TRabSumm.Auf_Rab = TRabSumm.Auf_Rab + Savze.Auf_Rab.
            TRabSumm.Abh_Rab = TRabSumm.Abh_Rab + Savze.Abh_Rab.
        END.
    END.
            
    /*  ----  Warengruppen-Totale  -------------------------------------------- */
        
    FIND FIRST TUmsGrp WHERE TUmsGrp.Ums_Grp = Artst.Wg_Grp
        AND   TUmsGrp.MWst    = Savze.WuCd
        AND   TUmsGrp.Ansatz  = Savze.Mwst% NO-ERROR.
    IF NOT AVAILABLE TUmsGrp THEN 
    DO:
        FIND WarenGrp NO-LOCK USE-INDEX WarenGrp-k1
            WHERE WarenGrp.Firma  = cFirma
            AND   WarenGrp.Wgr    = Artst.Wg_Grp NO-ERROR.
        CREATE  TUmsGrp.
        ASSIGN  
            TUmsGrp.Ums_Grp = Artst.Wg_Grp
            TUmsGrp.Mwst    = Savze.WuCd
            tUmsGrp.lInkl   = Savze.Mwst_Inkl
            TUmsGrp.Ansatz  = Savze.MWST%.
        IF AVAILABLE WarenGrp THEN TUmsGrp.Bez = WarenGrp.Bez1.
        ELSE                       TUmsGrp.Bez = "??????????".
    END.
            
    TUmsGrp.Ums_Betr = TUmsGrp.Ums_Betr 
        + Savze.Net_Betr
        - Savze.Auf_Rab
        - Savze.Abh_Rab.
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-AUFTRAG_ERMITTELN) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE AUFTRAG_ERMITTELN Procedure 
PROCEDURE AUFTRAG_ERMITTELN :
    /*------------------------------------------------------------------------------*/
    /*  Purpose:     Super Override                                                 */
    /*  Parameters:                                                                 */
    /*  Notes:                                                                      */
    /*------------------------------------------------------------------------------*/

    DEFINE VARIABLE iBisKnr     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE iAufnr      AS INTEGER   NO-UNDO.
    DEFINE VARIABLE dLief_Datum AS DATE      NO-UNDO.

    DEFINE VARIABLE cWhere      AS CHARACTER NO-UNDO.    
    DEFINE VARIABLE hQuery      AS HANDLE    NO-UNDO.
    
    FIND FIRST tParam.
    
    EMPTY TEMP-TABLE sSavko.
    
    /*  Sammeln aller Aufträge  */
    
    CREATE QUERY hQuery.
    hQuery:SET-BUFFERS (BUFFER Savko:HANDLE).
    
    IF tParam.iVerband > 0 THEN 
    DO:
        FIND Savko NO-LOCK 
            WHERE Savko.Firma = tParam.cFirma
            AND   Savko.Aufnr = tParam.iAufnr.
        IF tParam.iVonKnr > 0 THEN 
        DO:
            cWhere = 'FOR EACH Savko NO-LOCK '
                + 'WHERE Savko.Firma      = &1 '
                + 'AND   Savko.Fak_Art    = &2 '
                + 'AND   Savko.Ku_Grp     = &3 '
                + 'AND   Savko.Lief_Datum = &4 '.
            cWhere = SUBSTITUTE(cWhere,
                QUOTER(Savko.Firma), Savko.Fak_Art, Savko.Ku_Grp, Savko.Lief_Datum).
        END.
        ELSE 
        DO:
            cWhere =
                'FOR EACH Savko NO-LOCK '
                + 'WHERE Savko.Firma      = &1 '
                + 'AND   Savko.Aufnr      = &2 '.
            cWhere = SUBSTITUTE(cWhere,
                QUOTER(Savko.Firma), Savko.Aufnr).
        END.
    END.

    hQuery:QUERY-PREPARE (cWhere).
    hQuery:QUERY-OPEN () NO-ERROR.
    hQuery:GET-FIRST  () NO-ERROR.
 
    DO WHILE NOT hQuery:QUERY-OFF-END:
        
        iFaknr = Savko.Faknr.

        CREATE  sSavko.
        ASSIGN  
            sSavko.cFirma   = Savko.Firma
            sSavko.iAufnr   = Savko.Aufnr
            sSavko.iFak_Knr = Savko.Fak_Knr
            sSavko.iKnr     = Savko.Knr
            sSavko.iSamm_Nr = 0
            sSavko.iRecid   = RECID(Savko)
            sSavko.iFaknr   = iFaknr.
        IF Savko.Fak_Datum = ? THEN sSavko.dFakDat = TODAY.
        ELSE                        sSavko.dFakDat = Savko.Fak_Datum.
        
        hQuery:GET-NEXT () NO-ERROR.
    END.

    hQuery:QUERY-CLOSE ().
    DELETE OBJECT hQuery NO-ERROR.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-AUSGABE_ARTIKELZEILE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE AUSGABE_ARTIKELZEILE Procedure 
PROCEDURE AUSGABE_ARTIKELZEILE :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cZellen AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cWerte  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE iPos    AS INTEGER   NO-UNDO.
    
    FOR EACH tDokument
        WHERE tDokument.cGruppe = 'ArtikelZeile1'
        BREAK
        BY tDokument.cGruppe
        BY tDokument.iZeile:
            
        IF FIRST-OF ( tDokument.cGruppe ) THEN 
        DO:
            iVPagePos = vpr_getPageVPos() + 20.
            RUN vpr_setPageVPos  ( iVPagePos ).
            RUN vpr_setGroupVPos ( 'ArtikelZeile1', iVPagePos ).
        END.
        IF FIRST-OF ( tDokument.iZeile ) THEN 
        DO:
            cZellen = ''.
            cWerte  = ''.
        END.
        IF tDokument.cFeld = 'Beschreibung' THEN 
        DO:
            tDokument.cInhalt = REPLACE(tDokument.cInhalt, CHR(10), ' \par ') NO-ERROR.                        
        END.

        cWerte  = cWerte
            + (IF cWerte = '' THEN '' ELSE CHR(01)) 
            + tDokument.cInhalt.
        cZellen = cZellen
            + (IF cZellen = '' THEN '' ELSE ',') 
            + tDokument.cFeld.

        IF NOT LAST-OF ( tDokument.iZeile ) THEN NEXT.
        
        RUN vpr_SetDelimiter (CHR(01)).
        RUN vpr_setGroupText ('ArtikelZeile1', cZellen, cWerte).
        iVPagePos = vpr_getPageVPos().
        iPos      = iVPagePos + vpr_getGroupHeight('ArtikelZeile1').

        IF iPos > iMaxPos THEN 
        DO:
            RUN VIPER_NEUE_SEITE.
            RUN DRUCKEN_ADRESSE.
            iVPagePos = vpr_getPageVPos() + 20.
            RUN vpr_setPageVPos ( iVPagePos ).
            RUN vpr_setGroupText ('ArtikelZeile1', cZellen, cWerte).
        END.
        RUN vpr_FlushGroup   ('ArtikelZeile1').
        iVPagePos = vpr_getPageVPos().

        IF LAST-OF ( tDokument.cGruppe ) THEN LEAVE.
            
        iVPagePos = vpr_getPageVPos().
        RUN vpr_setGroupVPos ( 'ArtikelZeile1', iVPagePos ).
    END.
    FOR EACH tDokument
        WHERE tDokument.cGruppe = 'ArtikelZeile1':
        DELETE  tDokument.
    END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-AUSGABE_GRUPPE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE AUSGABE_GRUPPE Procedure 
PROCEDURE AUSGABE_GRUPPE :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipGruppe    AS CHARACTER     NO-UNDO.

    DEFINE VARIABLE cZellen AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cWerte  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE iSpace  AS INTEGER   NO-UNDO.
    
    FIND FIRST tParam.
    
    iSpace = vpr_getPageVPos().
    FOR EACH tDokument NO-LOCK
        WHERE tDokument.cGruppe = ipGruppe
        BREAK BY tDokument.cGruppe
        BY tDokument.iZeile:
        IF FIRST-OF ( tDokument.iZeile ) THEN iSpace = iSpace + 40.
    END.
    IF iSpace > iMaxPos THEN 
    DO:
        RUN vpr_NewPage.
        RUN vpr_InitGroups('').
        /*        IF tParam.lCreatePDF THEN RUN vpr_initGraphObj.*/
        RUN vpr_initGraphObj.
        iSeite = iSeite + 1.
        RUN DRUCKEN_ADRESSE.
    END.
    
    iVPagePos = vpr_getPageVPos().
    CASE ipGruppe:
        WHEN 'Gebindeabrechnung' THEN 
            DO:
                iVPagePos = iVPagePos + 20.
                RUN vpr_setGroupVPos ( 'GebindeabrechnungTitel', iVPagePos ).
                RUN vpr_FlushGroup   ( 'GebindeabrechnungTitel').
                iVPagePos = vpr_getPageVPos().
            END.
        OTHERWISE 
        DO:
        END.
    END CASE.
    
    FOR EACH tDokument
        WHERE tDokument.cGruppe = ipGruppe
        BREAK BY tDokument.cGruppe
        BY tDokument.iZeile:
        IF FIRST-OF ( tDokument.cGruppe ) THEN 
        DO:
            IF  ipGruppe <> 'ADRESSE'   THEN 
            DO:
                iVPagePos = vpr_getPageVPos().
                RUN vpr_setGroupVPos ( ipGruppe, iVPagePos ).
            END.
        END.
        IF FIRST-OF ( tDokument.iZeile ) THEN 
        DO:
            cZellen = ''.
            cWerte  = ''.
        END.
        cWerte  = cWerte 
            + tDokument.cInhalt.
        cZellen = cZellen
            + tDokument.cFeld.
        IF NOT LAST-OF ( tDokument.iZeile ) THEN 
        DO:
            ASSIGN 
                cWerte  = cWerte  + CHR(01)
                cZellen = cZellen + ','.
            NEXT.
        END.
        RUN vpr_SetDelimiter (CHR(01)).
        RUN vpr_setGroupText (ipGruppe, cZellen, cWerte).
        RUN vpr_FlushGroup   (ipGruppe).
    END.
    
    FOR EACH tDokument
        WHERE tDokument.cGruppe = ipGruppe:
        DELETE  tDokument.
    END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN Procedure 
PROCEDURE DRUCKEN :
    /*------------------------------------------------------------------------------*/
    /*  Purpose:     Super Override                                                 */
    /*  Parameters:                                                                 */
    /*  Notes:                                                                      */
    /*------------------------------------------------------------------------------*/

    DEFINE VARIABLE cText     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE xString   AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cLAdresse AS CHARACTER NO-UNDO.
    DEFINE VARIABLE RText     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE WText     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE i1        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE nBetrag   AS DECIMAL   NO-UNDO.
    DEFINE VARIABLE nRabWert  AS DECIMAL   NO-UNDO.
    DEFINE VARIABLE iMwstCd   AS INTEGER   NO-UNDO.
    DEFINE VARIABLE nZeiTot   AS DECIMAL   DECIMALS 4 NO-UNDO.
    DEFINE VARIABLE lJa       AS LOG       NO-UNDO.
    DEFINE VARIABLE cPDFName  AS CHARACTER INIT '' NO-UNDO.
    DEFINE VARIABLE nPfli     AS DECIMAL   EXTENT 12 NO-UNDO.
    DEFINE VARIABLE nMwst     AS DECIMAL   EXTENT 12 NO-UNDO.
    
    FIND FIRST tParam.
    
    IF tParam.iVerband = 3 THEN cERPDokumente = DYNAMIC-FUNCTION ('getFehlwert':U, tParam.Firma, 'GEMIS_MNC_PDF'      ) NO-ERROR.
    ELSE                        cERPDokumente = DYNAMIC-FUNCTION ('getFehlwert':U, tParam.Firma, 'GEMIS_RECHNUNG_PDF' ) NO-ERROR.

    nFakBetr = 0.
    iSeite   = 0.

    FIND bDebst NO-LOCK
        WHERE bDebst.Firma = bSavko.Firma
        AND   bDebst.Knr   = bSavko.Fak_Knr.
    iBesrArt = bDebst.BESR_Art.
    
    FIND bAdresse NO-LOCK 
        WHERE bAdresse.Firma = AdFirma
        AND   bAdresse.Knr   = bSavko.Fak_Knr NO-ERROR.
    iSprcd = bAdresse.Sprcd.
    IF  iSprcd <> 1 AND
        iSprcd <> 4 THEN iSprcd = 1.

    IF iSeite = 0 THEN 
    DO:
        RUN VIPER_INIT.
        SESSION:PRINTER-NAME = tParam.Drucker.
    END.

    RUN DRUCKEN_KOPF.
    
    IF  bSavko.Knr <> bSavko.Fak_Knr AND
        bSavko.Fak_Knr > 0           THEN
    DO:
        iVPagePos = vpr_getPageVPos().
        RUN vpr_setGroupVPos ( 'FetteZeile', iVPagePos ).

        iArtZeile = 1.
        RUN VIPER_CREATE_DOKUMENT ( 'FetteZeile', iArtZeile, 'Bez_1_Fett'  , ' ' ).
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'FetteZeile', iArtZeile, 'Bez_1_Fett'  , cFormText[23] ).
        RUN AUSGABE_GRUPPE ( 'FetteZeile' ).
        
        FIND LAdresse NO-LOCK
            WHERE LAdresse.Firma = AdFirma
            AND   LAdresse.Knr   = bSavko.Knr.
        RUN VIPER_CREATE_DOKUMENT ( 'Zusatztext', iArtZeile, 'Bemerkung_1'  , LAdresse.Anzeig_br ).
/*        DO i1 = 1 TO 12:                                                                                   */
/*            IF LAdresse.Anschrift[i1] = '' THEN NEXT.                                                      */
/*            iArtZeile = iArtZeile + 1.                                                                     */
/*            RUN VIPER_CREATE_DOKUMENT ( 'Zusatztext', iArtZeile, 'Bemerkung_1'  , LAdresse.Anschrift[i1] ).*/
/*        END.                                                                                               */
        RUN AUSGABE_GRUPPE ( 'Zusatztext' ).
    END.

    iArtZeile = 0.
    iVPagePos = vpr_getPageVPos().
    RUN vpr_setPageVPos  ( iVPagePos ).
    RUN vpr_setGroupVPos ( 'ArtikelZeile1', iVPagePos + 50 ).
    
    FOR EACH tSavze NO-LOCK
        BY tSavze.Aufnr
        BY tSavze.Sort1
        BY tSavze.LagOrt
        BY tSavze.Sort2
        BY tSavze.Pos  :
             
        FIND Savze NO-LOCK WHERE RECID(Savze) = tSavze.Zeile.
        
        RUN ARTIKELZEILE ( RECID(tSavze) ).

        nFakBetr = nFakBetr + Savze.Net_Betr.
        RELEASE Savze.
    END.

    RUN AUSGABE_ARTIKELZEILE.

    iArtZeile = 1.
    RUN VIPER_CREATE_DOKUMENT ( 'FetteZeile', iArtZeile, 'Bez_1_Fett'  , ' ' ).
    iArtZeile = iArtZeile + 1.
    RUN VIPER_CREATE_DOKUMENT ( 'FetteZeile', iArtZeile, 'Bez_1_Fett' , TRIM(SUBSTRING(cFormText[03],01,40)) ).
    RUN VIPER_CREATE_DOKUMENT ( 'FetteZeile', iArtZeile, 'Betrag_Fett', TRIM(STRING(nFakBetr,'->>>,>>9.99')) ).
    iArtZeile = iArtZeile + 1.
    RUN VIPER_CREATE_DOKUMENT ( 'FetteZeile', iArtZeile, 'Bez_1_Fett'  , ' ' ).
    RUN AUSGABE_GRUPPE ( 'FetteZeile' ).

    /*  Auftragsrabatt  ----------------------------------------------------    */
    
    iArtZeile = 0.
    FOR EACH tRabSumm
        WHERE tRabSumm.Auf_Rab <> 0
        BY tRabSumm.Rab_Summ:
        Rundbetr = tRabSumm.Auf_Rab.
        nFakBetr = nFakBetr - Rundbetr.
        
        IF Rundbetr < 0 THEN RText = cZusText.
        ELSE                 RText = cRabText.
        xString   = RText
            + " "
            + tRabSumm.Bez.
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', xString ).
        FIND FIRST AufRabSu NO-LOCK USE-INDEX AufRabSu-k1
            WHERE AufRabSu.Firma    = bSavko.Firma
            AND   AufRabSu.Aufnr    = bSavko.Aufnr
            AND   AufRabSu.Rab_Summ = tRabSumm.Rab_Summ.
        nRabWert = ABSOLUT(AufRabSu.F_Wert).
        IF AufRabSu.F_Proz_Betr THEN WText = "%".
        ELSE                         WText = "Fr.".
        xString   = STRING(nRabWert,"z9.99-")
            + WText.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', xString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(- Rundbetr,'->>>,>>9.99')) ).
    END.

    /*  Abholrabatt  -------------------------------------------------------    */
    
    FOR EACH tRabSumm WHERE tRabSumm.Abh_Rab <> 0
        BY tRabSumm.Rab_Summ:
        Rundbetr = tRabSumm.Abh_Rab.
        nFakBetr = nFakBetr - Rundbetr.
        IF Rundbetr < 0 THEN RText = cZusText.
        ELSE                 RText = cRabText.
        xString   = RText
            + " "
            + tRabSumm.Bez.
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', xString ).
        FIND FIRST AufRabSu NO-LOCK USE-INDEX AufRabSu-k1
            WHERE AufRabSu.Firma    = bSavko.Firma
            AND   AufRabSu.Aufnr    = bSavko.Aufnr
            AND   AufRabSu.Rab_Summ = tRabSumm.Rab_Summ.
        nRabWert = ABSOLUT(AufRabSu.A_Wert).
        IF AufRabSu.A_Proz_Betr THEN WText = "%".
        ELSE                         WText = "Fr.".
        xString = STRING(nRabWert,"z9.99-")
            + WText.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', xString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(- Rundbetr,'->>>,>>9.99')) ).
    END.
    
    /*  Spezialpreis-Auftragsrabatte  ----------------------------------------  */
    
    FOR EACH tSpeRab WHERE tSpeRab.Auf_Betr <> 0
        BY tSpeRab.Rab_Grp:
        FIND Tabel USE-INDEX Tabel-k1
            WHERE Tabel.Firma  = cFirma
            AND   Tabel.RecArt = 'ARABGRP'
            AND   Tabel.CodeC  = ''
            AND   Tabel.CodeI  = tSpeRab.Rab_Grp
            AND   Tabel.Sprcd  = 1 NO-LOCK.
        Rundbetr = tSpeRab.Auf_Betr.
        nFakBetr = nFakBetr - Rundbetr.
        IF Rundbetr < 0 THEN RText = cZusText.
        ELSE                 RText = cRabText.
        xString   = RText
            + " "
            + Tabel.Bez1.
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', xString ).
        FIND FIRST AufSpRab USE-INDEX AufSpRab-k1
            WHERE AufSpRab.Firma    = bSavko.Firma
            AND   AufSpRab.Aufnr    = bSavko.Aufnr
            AND   AufSpRab.Rab_Grp  = tSpeRab.Rab_Grp NO-LOCK.
        nRabWert = ABSOLUT(AufSpRab.Auf_Wert).
        IF AufSpRab.Auf_Proz_Betr THEN WText = "%".
        ELSE                           WText = "Fr.".
        xString   = STRING(nRabWert,"z9.99-")
            + WText.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', xString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(- Rundbetr,'->>>,>>9.99')) ).
    END.
    
    IF iArtZeile > 0 THEN 
    DO:
        iArtZeile = iArtZeile + 1.
        xString   = TRIM(SUBSTRING(cFormText[05],01,40)).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', xString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(nFakBetr,'->>>,>>9.99')) ).
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', ' ' ).
    END.
    RUN AUSGABE_GRUPPE ('ArtikelZeile1').
    
    /*  Recycling-Gebuehren  -----------------------------------------------    */

    iArtZeile = 0.
    FOR EACH AufGKon NO-LOCK
        WHERE AufGKon.Firma    = bSavko.Firma
        AND   AufGKon.Aufnr    = bSavko.Aufnr
        AND   AufGKon.Gebuehr <> 0
        AND   AufGKon.Betrag  <> 0 :
        FIND GebKonto OF AufGKon NO-LOCK NO-ERROR.
        IF NOT AVAILABLE GebKonto THEN xString = TRIM(SUBSTRING(cFormText[06],01,40)).
        ELSE                           xString = GebKonto.Bez.
        iMwstCd   = AufGKon.MWST_Cd.
        nFakBetr  = nFakBetr + AufGKon.Betrag.
        FIND LAST MwstAns NO-LOCK
            WHERE MwstAns.Mwst_Cd = iMwstCd
            AND   MwstAns.Datum  <= dMwstDatum NO-ERROR.
        
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', xString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag'      , TRIM(STRING(AufGKon.Betrag,'->>>,>>9.99')) ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'MC'          , STRING(AufGKon.MWSt_Cd,'z9') ).
        
        FIND FIRST tUmsGrp
            WHERE tUmsGrp.Ums_Grp = 1000
            AND   tUmsGrp.Mwst    = iMwstCd
            AND   tUmsGrp.Ansatz  = MwstAns.Ansatz NO-ERROR.
        IF NOT AVAILABLE tUmsGrp THEN 
        DO:
            FIND WarenGrp USE-INDEX WarenGrp-k1
                WHERE WarenGrp.Firma = cFirma
                AND   WarenGrp.Wgr   = 1000 NO-LOCK NO-ERROR.
            CREATE  tUmsGrp.
            ASSIGN  
                tUmsGrp.Ums_Grp = 1000
                tUmsGrp.Mwst    = iMwstCd
                tUmsGrp.Ansatz  = MwstAns.Ansatz
                tUmsGrp.lInkl   = lDebIncl
                tUmsGrp.Bez     = (IF AVAILABLE WarenGrp THEN WarenGrp.Bez1 ELSE 'Recyclinggebühren').
        END.
        tUmsGrp.Ums_Betr = tUmsGrp.Ums_Betr + AufGKon.Betrag.
    END.
    IF iArtZeile > 0 THEN 
    DO:
        iArtZeile = iArtZeile + 1.
        cText     = TRIM(SUBSTRING(cFormText[06],01,40)).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', cText ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag'      , TRIM(STRING(nFakBetr,'->>>,>>9.99')) ).
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Beschreibung', '' ).
    END.
    RELEASE AufGKon.
    RUN AUSGABE_GRUPPE ('ArtikelZeile1').
    
    /*  Gebinde Aus- und Eingänge   ----------------------------------------    */

    FOR EACH AufGKon NO-LOCK
        WHERE AufGKon.Firma    = bSavko.Firma
        AND   AufGKon.Aufnr    = bSavko.Aufnr
        AND   AufGKon.Depot   <> 0
        AND   AufGKon.Betrag  <> 0 :

        FIND FIRST tGebKto WHERE tGebKto.Geb_Cd = AufGKon.Geb_Cd NO-ERROR.
        IF NOT AVAILABLE tGebKto THEN 
        DO:
            FIND GebKonto NO-LOCK
                WHERE GebKonto.Firma  = AufGKon.Firma
                AND   GebKonto.Geb_Cd = AufGKon.Geb_Cd.
            CREATE  tGebKto.
            ASSIGN  
                tGebKto.Sort_Cd = GebKonto.Sort_Cd
                tGebKto.Geb_Cd  = GebKonto.Geb_Cd
                tGebKto.Bez     = GebKonto.Bez
                tGebKto.Preis   = AufGKon.Depot
                tGebKto.MWST_Cd = AufGKon.MWSt_Cd.
        END.
        tGebKto.A_Anz    = tGebKto.A_Anz + AufGKon.Ausgang.
        tGebKto.A_Betrag = tGebKto.A_Anz * tGebKto.Preis.
        tGebKto.E_Anz    = tGebKto.E_Anz + AufGKon.Eingang.
        tGebKto.E_Betrag = tGebKto.E_Anz * tGebKto.Preis.
    END.
    RELEASE AufGKon.
    
    /*  Gebindelieferungen  ------------------------------------------------    */

    nBetrag   = 0.
    iArtZeile = 0.
    FOR EACH AufGKon NO-LOCK
        WHERE AufGKon.Firma    = bSavko.Firma
        AND   AufGKon.Aufnr    = bSavko.Aufnr
        AND   AufGKon.Depot   <> 0
        AND  (AufGKon.Eingang <> 0 OR AufGKon.Ausgang <> 0)
                  
        BREAK BY AufGKon.Firma
        BY AufGKon.Aufnr:

        iMwstCd = AufGKon.MWSt_Cd.
        FIND LAST MwstAns NO-LOCK
            WHERE MwstAns.Mwst_Cd = iMwstCd
            AND   MwstAns.Datum  <= dMwstDatum NO-ERROR.
        FIND FIRST tUmsGrp
            WHERE tUmsGrp.Ums_Grp = 1001
            AND   tUmsGrp.Mwst    = iMwstCd
            AND   tUmsGrp.Ansatz  = MwstAns.Ansatz NO-ERROR.
        IF NOT AVAILABLE tUmsGrp THEN 
        DO:
            FIND WarenGrp NO-LOCK USE-INDEX WarenGrp-k1
                WHERE WarenGrp.Firma = cFirma
                AND   WarenGrp.Wgr   = 1001 NO-ERROR.
            CREATE  tUmsGrp.
            ASSIGN  
                tUmsGrp.Ums_Grp = 1001
                tUmsGrp.Mwst    = iMwstCd
                tUmsGrp.Ansatz  = MwstAns.Ansatz
                tUmsGrp.lInkl   = lDebIncl
                tUmsGrp.Bez     = (IF AVAILABLE WarenGrp THEN WarenGrp.Bez1 ELSE 'Gebindesaldo').
        END.
        tUmsGrp.Ums_Betr = tUmsGrp.Ums_Betr + AufGKon.Betrag.
        
        FIND GebKonto NO-LOCK
            WHERE GebKonto.Firma  = cFirma
            AND   GebKonto.Geb_Cd = AufGKon.Geb_Cd.
        i1        = AufGKon.Ausgang - AufGKon.Eingang.
        Rundbetr  = AufGKon.Betrag.
        iMwstCd   = AufGKon.MWSt_Cd.
        nBetrag   = nBetrag   + Rundbetr.
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'Gebindetext' , GebKonto.Bez ).
        RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeGel'  , TRIM(STRING(AufGKon.Ausgang,"->>,>>9")) ).
        RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeRet'  , TRIM(STRING(AufGKon.Eingang,"->>,>>9")) ).
        RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeSaldo', TRIM(STRING(i1             ,"->>,>>9")) ).
        RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeBetr' , TRIM(STRING(Rundbetr       ,"->>,>>9.99")) ).
        RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'MC'          , TRIM(STRING(AufGKon.MWSt_Cd,"z9")) ).
    END.
    RELEASE AufGKon.
    RELEASE GebKonto.
    
    IF iArtZeile > 0 THEN RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile, 'GebindeTot', TRIM(STRING(nBetrag,"->>>,>>9.99")) ).

    nFakBetr = nFakBetr + nBetrag.
    IF iArtZeile > 0 THEN RUN AUSGABE_GRUPPE ('Gebindeabrechnung').
    
    /*  Mehrwertsteuer  ----------------------------------------------------    */

    nPfli     = 0.
    nMwst     = 0.
    i1        = 2.
    DO ii = 1 TO 11:
        IF bSavko.WPfl[ii] = 0 THEN NEXT.
        nPfli[ii] = bSavko.Wpfl[ii].
        nMwst[ii] = bSavko.Wust[ii].
        nFakBetr  = nFakBetr + nMwst[ii].
        i1        = i1       + 1.
    END.
    
    iVPagePos  = vpr_getPageVPos().
    IF (iVPagePos + (i1 * 40)) > iMaxPos THEN 
    DO:
        RUN VIPER_NEUE_SEITE.
        RUN DRUCKEN_ADRESSE.
    END.
    
    iArtZeile = 1.
    RUN VIPER_CREATE_DOKUMENT ( 'Mehrwertsteuer', 1,  'MwstBez' , ' ' ).
    DO ii = 1 TO 11:
        IF nPfli[ii] = 0 THEN NEXT.
        FIND LAST MWSTAns USE-INDEX MWSTAns-k1
            WHERE MWSTAns.MWST_Cd = ii
            AND   MWSTAns.Datum  <= dMwstDatum NO-LOCK.
        IF nMwst[ii] = 0 THEN nMwst[ii] = nPfli[ii] * MWSTAns.Ansatz / (100 + MWSTAns.Ansatz).
        cText = SUBSTITUTE(cFormtext[10 + ii], TRIM(STRING(MWSTAns.Ansatz,'>>9.9'))).
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'Mehrwertsteuer', iArtZeile,  'MwstBez' , cText ).
        RUN VIPER_CREATE_DOKUMENT ( 'Mehrwertsteuer', iArtZeile,  'MwstPfl' , TRIM(STRING(nPfli[ii],"->>,>>9.99")) ).
        RUN VIPER_CREATE_DOKUMENT ( 'Mehrwertsteuer', iArtZeile,  'MwstBetr', TRIM(STRING(nMwst[ii],"->>>,>>9.99")) ).
        RUN VIPER_CREATE_DOKUMENT ( 'Mehrwertsteuer', iArtZeile,  'MwstCd'  , TRIM(STRING(ii       ,"->>,>>9")) ).
    END.
    iArtZeile = iArtZeile + 1.
    RUN VIPER_CREATE_DOKUMENT ( 'Mehrwertsteuer', iArtZeile,  'MwstBez' , ' ' ).
    RUN AUSGABE_GRUPPE ( 'Mehrwertsteuer' ).
    
    /*  Rechnungsbetrag  ---------------------------------------------------    */

    Rundbetr = nFakBetr.
    Rundcode = 1.
    RUN RUNDEN ( Rundcode, INPUT-OUTPUT Rundbetr ).
    nFakBetr = Rundbetr.
    
    iArtZeile = 1.
    RUN VIPER_CREATE_DOKUMENT ( 'RechnungsTotal', iArtZeile,  'EndBetrag', TRIM(STRING(nFakBetr,"->>>,>>9.99")) ).
    RUN AUSGABE_GRUPPE ( 'RechnungsTotal' ).

    /*  Zahlungskondition  -------------------------------------------------    */

    FIND Kondi USE-INDEX Kondi-k1
        WHERE Kondi.Kond  = bSavko.Kond
        AND   Kondi.Sprcd = iSprcd NO-LOCK NO-ERROR.
    IF AVAILABLE Kondi THEN 
    DO:
        iArtZeile = 1.
        RUN VIPER_CREATE_DOKUMENT ( 'Kondition', iArtZeile,  'Zahkond', ' ' ).
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'Kondition', iArtZeile,  'Zahkond', Kondi.KoText ).
    END.
    nFakBetr = nFakBetr - bSavko.Bar_Betr - bSavko.Bar_Skonto.
    
    IF nFakBetr = 0 THEN Rundbetr  = -1.
    ELSE                 Rundbetr  = nFakBetr.
    IF  AVAILABLE Kondi       AND
        Kondi.Skonto[01] <> 0 THEN Rundbetr = 0.

    iArtZeile = 1.        
    RUN vpr_setCellText('Danke', 'Fusstext', cFormtext[07] ).
    RUN vpr_flushGroup ('Fusstext').

    IF iLauf < iAnzDok THEN RETURN.
    
    /*  BESR DRUCKEN  ----------------------------  */

    CASE bSavko.Frw:
        WHEN 'CHF' THEN 
            iBESRArt = 1.
        WHEN 'EUR' THEN 
            iBESRArt = 2.
    END CASE.
    FIND Bankst NO-LOCK 
        WHERE Bankst.Bank = iBESRArt NO-ERROR.
    IF NOT AVAILABLE Bankst THEN FIND FIRST Bankst NO-ERROR.
    IF  AVAILABLE Bankst     AND 
        Bankst.QR-IBAN <> '' THEN 
    DO:
        RUN vpr_newPage.
        RUN DRUCKEN_QRCODE.
    END.
    ELSE 
    DO:
        RUN DRUCKEN_BESR ( 'BESR' ).
    END.
     
    /*  ------------------------------------------------------  */
    /*  Druckausgabe                                            */    
    /*  ------------------------------------------------------  */
    
    RUN vpr_EndDoc.
    cFileName = SUBSTITUTE('&1-&2_&3.vpr',
        STRING(bSavko.Knr  ,'999999'),
        STRING(bSavko.Faknr,'9999999'),
        tParam.cDokument ).
    cvpr_Dokument = SUBSTITUTE(cERPDokumente,
        cFileName ) .
    RUN vpr_saveDoc ( cvpr_Dokument ).

    DO WHILE tParam.lDokDruck:
        SESSION:PRINTER-NAME = tParam.Drucker NO-ERROR.
        IF SESSION:PRINTER-NAME <> tParam.Drucker THEN 
        DO:
            RUN vpr_printerDialog ( OUTPUT lJa ).
            IF NOT lJa THEN LEAVE.
        END.
        RUN vpr_printDoc (0, 0).
        RUN vpr_resetDoc.
        
        LEAVE.
    END.
    
    IF tParam.lCreatePDF THEN 
    DO:
        cPDFName = REPLACE(cvpr_Dokument, '.vpr', '.pdf').
        RUN vpr_openDoc  ( cvpr_Dokument ).
        RUN vpr_printPDF ( 0, 0, INPUT-OUTPUT cPDFName ).
    END.

    IF tParam.lOpenPDF THEN 
    DO:    
        DEFINE VARIABLE o-i AS i NO-UNDO.
        FILE-INFO:FILE-NAME = cPDFName.
        cPDFName = FILE-INFO:FULL-PATHNAME.
        RUN ShellExecuteA (0,
            "open",
            cPDFName,
            "",
            "",
            0,
            OUTPUT o-i).
    END.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN_ADRESSE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN_ADRESSE Procedure 
PROCEDURE DRUCKEN_ADRESSE :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cZellen AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cWerte  AS CHARACTER NO-UNDO.
    
    FIND FIRST tParam.

    /*    FIND FIRST tDokument                           */
    /*        WHERE tDokument.cGruppe = 'KOPF'           */
    /*        AND   tDokument.iZeile  = 1                */
    /*        AND   tDokument.cFeld   = 'Seite' NO-ERROR.*/
    /*    IF NOT AVAILABLE tDokument THEN                */
    /*    DO:                                            */
    /*        CREATE  tDokument.                         */
    /*        ASSIGN                                     */
    /*            tDokument.cGruppe = 'KOPF'             */
    /*            tDokument.iZeile  = 1                  */
    /*            tDokument.cFeld   = 'Seite'.           */
    /*    END.                                           */
    /*    tDokument.cInhalt = STRING(iSeite,'z9').       */

    cZellen = ''.
    cWerte  = ''.
    FOR EACH tDokument
        WHERE tDokument.cGruppe = 'Kopf'
        BREAK BY tDokument.cGruppe
        BY tDokument.cFeld:
        cWerte  = cWerte 
            + tDokument.cInhalt.
        cZellen = cZellen
            + tDokument.cFeld.
        IF NOT LAST-OF ( tDokument.cGruppe ) THEN
            ASSIGN
                cWerte  = cWerte  + CHR(01)
                cZellen = cZellen + ','.
    END.

    RUN vpr_SetDelimiter (CHR(01)).
    RUN vpr_setGroupText ('Kopf', cZellen, cWerte).
    RUN vpr_FlushGroup   ('Kopf').
    
    IF iSeite = 1 THEN 
    DO:
        cZellen = ''.
        cWerte  = ''.
        FOR EACH tDokument
            WHERE tDokument.cGruppe = 'KopfDetail'
            BREAK
            BY tDokument.cGruppe
            BY tDokument.cFeld:
            cWerte  = cWerte 
                + tDokument.cInhalt.
            cZellen = cZellen
                + tDokument.cFeld.
            IF NOT LAST-OF ( tDokument.cGruppe ) THEN
                ASSIGN
                    cWerte  = cWerte  + CHR(01)
                    cZellen = cZellen + ','.
        END.
        RUN vpr_SetDelimiter (CHR(01)).
        RUN vpr_setGroupText ('KopfDetail', cZellen, cWerte).
        RUN vpr_FlushGroup   ('KopfDetail').
    END.
    RUN vpr_FlushGroup   ('Ueberschrift').
    
    iVPagePos = vpr_getGroupVPos('Ueberschrift') + vpr_getGroupHeight('Ueberschrift').
    RUN vpr_setPageVPos  ( iVPagePos ).

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF
&IF DEFINED(EXCLUDE-DRUCKEN_KOPF) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN_KOPF Procedure 
PROCEDURE DRUCKEN_KOPF :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cText   AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cString AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii      AS INTEGER   NO-UNDO.
    DEFINE VARIABLE i1      AS INTEGER   NO-UNDO.
    
    FIND FIRST tParam.
    iFaknr = bSavko.Faknr.

    RUN VIPER_NEUE_SEITE.

    IF iSeite = 1 THEN 
    DO:
        REPEAT WHILE bSavko.Faknr = 0 TRANSACTION:
            iFaknr = DYNAMIC-FUNCTION('createFaknr', bSavko.Firma ) NO-ERROR.
            IF RETURN-VALUE <> '' THEN NEXT.
            FIND Savko WHERE RECID(Savko) = RECID(bSavko).
            Savko.Faknr = iFaknr.
            RELEASE Savko.
            LEAVE.
        END.
        
        FIND bSteuer NO-LOCK WHERE bSteuer.Firma = cFirma.
       
        IF bSavko.Adresse[05] <> '' THEN 
        DO:
            i1 = 6.
            DO ii = 1 TO 5:
                CREATE  tDokument.
                ASSIGN  
                    tDokument.cGruppe = 'KOPF'
                    tDokument.iZeile  = 1
                    tDokument.cFeld   = 'Adresse_' + STRING((6 + ii),'99')
                    tDokument.cInhalt = bSavko.Adresse[ii].
                i1 = i1 + 1.
                cBesrKopf[i1] = bSavko.Adresse[ii].
            END.
        END.
        ELSE 
        DO:
            DO ii = 5 TO 11:
                CREATE  tDokument.
                ASSIGN  
                    tDokument.cGruppe = 'KOPF'
                    tDokument.iZeile  = 1
                    tDokument.cFeld   = 'Adresse_' + STRING(ii,'99')
                    tDokument.cInhalt = bAdresse.Anschrift[ii].
            END.
        END.
        
        cString = (IF bSavko.Auf_Tot >= 0
            THEN TRIM(SUBSTRING(cFormText[01],01,40))
            ELSE TRIM(SUBSTRING(cFormText[01],41,40))).
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPF'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Dokument'
            tDokument.cInhalt = cString.
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPF'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Faknr'
            tDokument.cInhalt = TRIM(STRING(iFaknr,'>>>>>>9')).
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KopfDetail'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Aufnr'
            tDokument.cInhalt = STRING(bSavko.Aufnr,'999999').
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KopfDetail'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Knr'
            tDokument.cInhalt = TRIM(STRING(bSavko.Fak_Knr,'zzzzz9')).
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KopfDetail'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Fak_Datum'
            tDokument.cInhalt = STRING(bSavko.Fak_Datum,'99.99.9999').
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KopfDetail'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Knr'
            tDokument.cInhalt = STRING(bSavko.Knr,'999999').
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KopfDetail'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Ort_Datum'
            tDokument.cInhalt = TRIM(SUBSTRING(cFormText[02],01,40))
                              + ' '
                              + STRING(bSavko.Fak_Datum,'99.99.9999').

    END.
    
    RUN DRUCKEN_ADRESSE.
    
    IF iSeite <> 1 THEN RETURN.
    
    cText = ''.
    /*    IF bSavko.Abh_Text <> '' THEN                            */
    /*    DO:                                                      */
    /*        cText = bSavko.Abh_Text.                             */
    /*    END.                                                     */
    /*    IF bSavko.Auf_Text <> '' THEN                            */
    /*    DO:                                                      */
    /*        cText = cText                                        */
    /*            + (IF cText <> '' THEN CHR(10) + CHR(10) ELSE '')*/
    /*            + bSavko.Auf_Text.                               */
    /*    END.                                                     */
    IF cText = '' THEN RETURN.
    
/*    CREATE  tDokument.                                */
/*    ASSIGN                                            */
/*        tDokument.cGruppe = 'ZusatzText'              */
/*        tDokument.iZeile  = 1                         */
/*        tDokument.cFeld   = 'Bemerkung_1'             */
/*        tDokument.cInhalt = cText.                    */
/*                                                      */
/*    iVPagePos = vpr_getPageVPos() + 100.              */
/*    RUN vpr_setGroupVPos ( 'ZusatzText' , iVPagePos ).*/
/*    RUN AUSGABE_GRUPPE ( 'ZusatzText' ).              */
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN_QRCODE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN_QRCODE Procedure 
PROCEDURE DRUCKEN_QRCODE :
    /*------------------------------------------------------------------------------*/
    /*  Purpose:                                                                    */
    /*  Parameters:  <none>                                                         */
    /*  Notes:                                                                      */
    /*------------------------------------------------------------------------------*/
    
    DEFINE VARIABLE cFileName     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cString       AS CHARACTER NO-UNDO.
    DEFINE VARIABLE hSavko        AS HANDLE    NO-UNDO.
    DEFINE VARIABLE cBesrTemplate AS CHARACTER NO-UNDO INIT 'viper/realwines/BESR_QR.vfr'.
    DEFINE VARIABLE cWerbung      AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cConString    AS CHARACTER NO-UNDO.
    DEFINE VARIABLE i1            AS INTEGER   NO-UNDO.

    FIND FIRST tSavko.
    hSavko = TEMP-TABLE tSavko:DEFAULT-BUFFER-HANDLE.
    
    FIND FIRST tParam.
    cPathQRCodes = DYNAMIC-FUNCTION ('getFehlwert':U, tParam.Firma, 'GEMIS_QRCODE')   NO-ERROR.
    cWerbung     = DYNAMIC-FUNCTION ('getFehlwert':U, tParam.Firma, 'WERBUNG_QRCODE') NO-ERROR.
    
    FIND FIRST ViperDoc NO-LOCK
        WHERE ViperDoc.Firma    = tSavko.Firma
        AND   ViperDoc.Benutzer = ''
        AND   ViperDoc.Formular = 'BESR_QR'
        AND   ViperDoc.DokArt   = 0 NO-ERROR.
    IF NOT AVAILABLE ViperDoc THEN RETURN.
    
    RUN vpr_LoadVFR         (cBesrTemplate).
    RUN vpr_ActivateReport  ('BESR_QR').
    RUN vpr_SelectPrinter   (tParam.Drucker).
    RUN vpr_setPrinterAttrib('duplex=1').
    RUN vpr_SetPrinterAttrib('copies=1').
    RUN vpr_SetDocAttrib    ('PAPERSIZE=A4').
    RUN vpr_SetPreviewMode  ('Direct').
    RUN vpr_InitGroups      ("").
    RUN vpr_initGraphObj.
    RUN vpr_SetCurrentPageProperties("Papertray", ViperDoc.Schacht_BESR).

    cFileName = SUBSTITUTE('&1&2_&3', cPathQRCodes, 'QR_CODE', STRING(bSavko.Aufnr,'9999999')).

    RUN 'SwissQR/SwissQRCode.p' ( hSavko, cFileName ).
    
    cFilename = cFileName + '.jpg'.
    IF SEARCH(cFileName) <> ? THEN 
    DO:
        cFileName = 'FILENAME=' + cFileName.
        RUN vpr_setGraphObjAttrib ( 'QRCode', 'QRCODE', cFileName ).
    END.
    /*    FILE-INFO:FILE-NAME = cFileName.    */
    /*    cFileName = FILE-INFO:FULL-PATHNAME.*/

    cWerbung = SUBSTITUTE(cPathWerbung, tParam.cInstall).
    cWerbung = SUBSTITUTE('&1Werbung_&2.jpg', cWerbung, tSavko.Firma).

    IF SEARCH(cWerbung) <> ? THEN 
    DO:
        cWerbung = SUBSTITUTE('FILENAME=&1', cWerbung).
        RUN vpr_setGraphObjAttrib ( 'Werbung', 'QRCODE', cWerbung ).
    END.
    
    RUN vpr_InitGraphObj.
    RUN vpr_flushGroup('QRCODE').

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-FUELLEN_tAufze) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE FUELLEN_tAufze Procedure 
PROCEDURE FUELLEN_tSavze :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipAufnr     AS INTEGER          NO-UNDO.

    DEFINE VARIABLE minPos     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE maxPos     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE jPlatz     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE cLagOrt    AS CHARACTER NO-UNDO.
    DEFINE VARIABLE iRuestArt  AS INTEGER   NO-UNDO.
    DEFINE VARIABLE iPlusMinus AS INTEGER   NO-UNDO.
    DEFINE VARIABLE lArtikel   AS LOG       NO-UNDO.
    DEFINE VARIABLE cSort      AS CHARACTER NO-UNDO.

    EMPTY TEMP-TABLE tSavze.
    
    FIND Steuer NO-LOCK
        WHERE Steuer.Firma = cFirma NO-ERROR.
    IF AVAILABLE Steuer THEN iRuestArt = Steuer.RuestArt.
    
    ASSIGN  
        minPos     = 0
        maxPos     = 9999
        iPlusMinus = 0.
            
    /*  Kommentar zu Beginn eines Auftrages     */
    lArtikel = FALSE.
    FOR EACH Savze NO-LOCK
        WHERE Savze.Firma = cFirma
        AND   Savze.Aufnr = ipAufnr
        AND   Savze.Pos   > minPos:
        IF Savze.Artnr > 0 THEN 
        DO:
            lArtikel = TRUE.
            LEAVE.
        END.
        
        minPos = Savze.Pos.
        CREATE  tSavze.
        ASSIGN  
            tSavze.Aufnr  = Savze.Aufnr
            tSavze.Artnr  = Savze.Artnr
            tSavze.Inhalt = Savze.Inhalt
            tSavze.Jahr   = Savze.Jahr
            tSavze.Pos    = Savze.Pos
            tSavze.Zeile  = RECID(Savze)
            tSavze.Aktion = Savze.Aktion
            tSavze.Preis  = Savze.Preis
            tSavze.MGeli  = Savze.MGeli
            tSavze.MRuek  = Savze.MRuek.
                
        ASSIGN  
            tSavze.Sort1 = ''
            tSavze.Sort2 = ''
            tSavze.Sort3 = STRING(tSavze.Artnr ,'999999')
                             + STRING(tSavze.Inhalt,'9999')
                             + STRING(tSavze.Jahr  ,'9999')
                             + STRING(iPlusMinus   ,'9')
                             + STRING(tSavze.Pos   ,'99999').
        tSavze.LagOrt = ''.
    END.
    
    /*  Kommentar am Ende eines Auftrages       */
    IF lArtikel THEN 
    DO:
        FOR EACH Savze NO-LOCK
            WHERE Savze.Firma = cFirma
            AND   Savze.Aufnr = ipAufnr
            BY Savze.Pos DESCENDING:
            IF Savze.Artnr > 0 THEN LEAVE.
            
            maxPos = Savze.Pos.
            CREATE  tSavze.
            ASSIGN  
                tSavze.Aufnr  = Savze.Aufnr
                tSavze.Artnr  = Savze.Artnr
                tSavze.Inhalt = Savze.Inhalt
                tSavze.Jahr   = Savze.Jahr
                tSavze.Pos    = Savze.Pos
                tSavze.Zeile  = RECID(Savze)
                tSavze.Aktion = Savze.Aktion
                tSavze.Preis  = Savze.Preis
                tSavze.MGeli  = Savze.MGeli
                tSavze.MRuek  = Savze.MRuek.
                    
            ASSIGN  
                tSavze.Sort1 = 'ZZZ'
                tSavze.Sort2 = ''
                tSavze.Sort3 = STRING(tSavze.Artnr ,'999999')
                                 + STRING(tSavze.Inhalt,'9999')
                                 + STRING(tSavze.Jahr  ,'9999')
                                 + STRING(iPlusMinus   ,'9')
                                 + STRING(tSavze.Pos   ,'99999').
            tSavze.LagOrt = ''.
        END.
    END.
    
    /*  Artikelzeilen nach WarenGruppe/ProdGruppen/Artikelgruppen   */
    cLagOrt = ''.
    cSort   = ''.
    FOR EACH Savze NO-LOCK
        WHERE Savze.Firma = cFirma
        AND   Savze.Aufnr = ipAufnr
        AND   Savze.Pos   > minPos
        AND   Savze.Pos   < MaxPos
        BY Savze.Pos DESCENDING:
            
        IF Savze.Artnr > 0 THEN 
        DO:
            FIND Artst NO-LOCK
                WHERE Artst.Firma  = Savze.Firma
                AND   Artst.Artnr  = Savze.Artnr
                AND   Artst.Inhalt = Savze.Inhalt
                AND   Artst.Jahr   = Savze.Jahr NO-ERROR.
            IF AVAILABLE Artst THEN cSort = STRING(Artst.Wg_Grp  ,'9999')
                    + STRING(Artst.Prod_Grp,'9999')
                    + STRING(Artst.Art_Grp ,'9999').
        END.
        iPlusMinus = (IF Savze.MGeli < 0 THEN 1 ELSE 0).
        CREATE  tSavze.
        ASSIGN  
            tSavze.Aufnr  = Savze.Aufnr
            tSavze.Artnr  = Savze.Artnr
            tSavze.Inhalt = Savze.Inhalt
            tSavze.Jahr   = Savze.Jahr
            tSavze.Pos    = Savze.Pos
            tSavze.Zeile  = RECID(Savze)
            tSavze.Aktion = Savze.Aktion
            tSavze.Preis  = Savze.Preis
            tSavze.MGeli  = Savze.MGeli
            tSavze.MRuek  = Savze.MRuek.
                
        ASSIGN  
            tSavze.Sort1 = cSort
            tSavze.Sort2 = ''
            tSavze.Sort3 = STRING(tSavze.Artnr ,'999999')
                             + STRING(tSavze.Inhalt,'9999')
                             + STRING(tSavze.Jahr  ,'9999')
                             + STRING(iPlusMinus   ,'9')
                             + STRING(tSavze.Pos   ,'99999').
        tSavze.LagOrt = cLagort.
    END.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-PRUEFZIFFER) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE PRUEFZIFFER Procedure 
PROCEDURE PRUEFZIFFER :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    /* ------------------------------------------------------------------------- */
    /*  Prufziffer MODULO 10, Rekursiv (27 Stellig Ref.-Nr.)                     */
    /* ------------------------------------------------------------------------- */
    /*                                                                           */
    /*  Uebergabe Variable:  1.  String Betrag              (12-stellig)         */
    /*                       2.  String Referenz            (27-stellig)         */
    /*                       3.  String Teilnehmernummer    ( 9-stellig)         */
    /*                                                                           */
    /*  Erstellung der VESR-Codierzeile                                          */
    /*                                                                           */
    /*---------------------------------------------------------------------------*/

    DEFINE INPUT-OUTPUT PARAMETER PZBetrag     AS CHARACTER FORMAT "x(13)".
    DEFINE INPUT-OUTPUT PARAMETER PZReferenz   AS CHARACTER FORMAT "x(27)".
    DEFINE INPUT-OUTPUT PARAMETER PZTNummer    AS CHARACTER FORMAT "x(09)".
    DEFINE OUTPUT       PARAMETER VSZeile      AS CHARACTER FORMAT "x(58)".
    
    DEFINE VARIABLE l1     AS INTEGER.
    DEFINE VARIABLE l2     AS INTEGER.
    DEFINE VARIABLE l3     AS INTEGER.
    DEFINE VARIABLE PZ     AS INTEGER.
    DEFINE VARIABLE x1     AS INTEGER.
    DEFINE VARIABLE x2     AS INTEGER.
    DEFINE VARIABLE x3     AS INTEGER.
    DEFINE VARIABLE VMOD10 AS CHARACTER FORMAT "x(11)" EXTENT 11.

    VMOD10[01] = "09468271350".
    VMOD10[02] = "94682713509".
    VMOD10[03] = "46827135098".
    VMOD10[04] = "68271350947".
    VMOD10[05] = "82713509466".
    VMOD10[06] = "27135094685".
    VMOD10[07] = "71350946824".
    VMOD10[08] = "13509468273".
    VMOD10[09] = "35094682712".
    VMOD10[10] = "50946827131".

    l1 = 12.
    l2 = 26.
    l3 = 08.

    DO WHILE SUBSTRING(PZBetrag,01,01) <> " ":          /*   Mit Betrag  */
        x2 = 1.
        x1 = INT(SUBSTRING(PZBetrag  ,01    ,01)).
        x2 = INT(SUBSTRING(VMOD10[x2],x1 + 1,01)).

        DO x3 = 2 TO 12:
            x1 = INT(SUBSTRING(PZBetrag      ,x3    ,01)).
            x2 = INT(SUBSTRING(VMOD10[x2 + 1],x1 + 1,01)).
        END.

        PZ = INT(SUBSTRING(VMOD10[x2 + 1],11,1)).
        SUBSTRING(PZBetrag,13) = STRING(PZ,"9").
        LEAVE.
    END.

    DO WHILE SUBSTRING(PZBetrag,01,01) = " ":            /*  Ohne Betrag */
        x2 = 11.
        x1 = INT(SUBSTRING(PZBetrag  ,01    ,01)).
        x2 = INT(SUBSTRING(VMOD10[x2],x1 + 1,01)).

        DO x3 = 12 TO 12:
            x1 = INT(SUBSTRING(PZBetrag      ,x3    ,01)).
            x2 = INT(SUBSTRING(VMOD10[x2 + 1],x1 + 1,01)).
        END.

        PZ = INT(SUBSTRING(VMOD10[x2 + 1],11,1)).
        SUBSTRING(PZBetrag,13) = STRING(PZ,"9").
        LEAVE.
    END.

    DO WHILE l2 = 26:
        x2 = 1.
        x1 = INT(SUBSTRING(PZReferenz,01    ,01)).
        x2 = INT(SUBSTRING(VMOD10[x2],x1 + 1,01)).

        DO x3 = 2 TO 26:
            x1 = INT(SUBSTRING(PZReferenz    ,x3    ,01)).
            x2 = INT(SUBSTRING(VMOD10[x2 + 1],x1 + 1,01)).
        END.

        PZ = INT(SUBSTRING(VMOD10[x2 + 1],11,1)).
        SUBSTRING(PZReferenz,27) = STRING(PZ,"9").
        LEAVE.
    END.

    DO WHILE l3 = 08:
        x2 = 1.
        x1 = INT(SUBSTRING(PZTNummer ,01    ,01)).
        x2 = INT(SUBSTRING(VMOD10[x2],x1 + 1,01)).

        DO x3 = 2 TO 08:
            x1 = INT(SUBSTRING(PZTNummer     ,x3    ,01)).
            x2 = INT(SUBSTRING(VMOD10[x2 + 1],x1 + 1,01)).
        END.

        PZ = INT(SUBSTRING(VMOD10[x2 + 1],11,1)).
        SUBSTRING(PZTNummer,09) = STRING(PZ,"9").
        LEAVE.
    END.

    VSZeile = "".
    SUBSTRING(VSZeile,01) = PZBetrag.
    SUBSTRING(VSZeile,14) = ">".
    SUBSTRING(VSZeile,15) = PZReferenz.
    SUBSTRING(VSZeile,42) = "+ ".
    SUBSTRING(VSZeile,44) = PZTNummer.
    SUBSTRING(VSZeile,53) = ">".
/*
SUBSTRING(VSZeile,58) = "H".
*/
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-VIPER_CREATE_DOKUMENT) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE VIPER_CREATE_DOKUMENT Procedure 
PROCEDURE VIPER_CREATE_DOKUMENT :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipGruppe    AS CHARACTER         NO-UNDO.
    DEFINE INPUT PARAMETER ipZeile     AS INTEGER          NO-UNDO.
    DEFINE INPUT PARAMETER ipFeld      AS CHARACTER         NO-UNDO.
    DEFINE INPUT PARAMETER ipInhalt    AS CHARACTER         NO-UNDO.
    
    CREATE  tDokument.
    ASSIGN  
        tDokument.cGruppe = ipGruppe
        tDokument.iZeile  = ipZeile
        tDokument.cFeld   = ipFeld
        tDokument.cInhalt = ipInhalt.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-VIPER_INIT) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE VIPER_INIT Procedure 
PROCEDURE VIPER_INIT :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cTemplate AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cDokument AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cZellen   AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cZelle    AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cGruppe   AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE cString   AS CHARACTER NO-UNDO.
    
    FIND FIRST tParam.

    IF iLauf = 1 THEN 
    DO:
        cDokument = 'viper/' + tParam.cInstall  + '/' + SUBSTITUTE(tParam.cDokument + '_&1_&2_&3', STRING(tParam.iVerband,'99'), STRING(iSprcd,'99'), bSavko.Frw)  + '.vfr'.

        RUN vpr_ResetDoc.
        RUN vpr_LoadVFR         (cDokument).
        RUN vpr_ActivateReport  (tParam.cDokument).
        RUN vpr_SelectPrinter   (tParam.Drucker).
        RUN vpr_setPrinterAttrib('duplex=1').
        RUN vpr_SetPrinterAttrib('copies=1').
        RUN vpr_ResetDoc.
        RUN vpr_SetDocAttrib    ('PAPERSIZE=A4').
        RUN vpr_SetPreviewMode  ('Direct').
        RUN vpr_setDocTitle     (tParam.cDokument).
        IF tParam.Schacht_Original > 0 THEN RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Original ).
    END.
    ELSE 
    DO:
        RUN vpr_NewPage.
        IF tParam.Schacht_Kopie    > 0 THEN RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Kopie    ).
    END.
    RUN vpr_InitGroups("").
    RUN vpr_InitGraphObj.
    
    RUN vpr_SetGroupAttrib ("Kopf"        , "Fixed=true").
    RUN vpr_SetGroupAttrib ("KopfDetail"  , "Fixed=true").
    RUN vpr_SetGroupAttrib ("Ueberschrift", "Fixed=true").
    RUN vpr_SetGroupAttrib ("Fusstext"    , "Fixed=true").
    
    iMaxPos = 2600.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-VIPER_NEUE_SEITE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE VIPER_NEUE_SEITE Procedure 
PROCEDURE VIPER_NEUE_SEITE :
    /*------------------------------------------------------------------------------
          Purpose:     
          Parameters:  <none>
          Notes:       
        ------------------------------------------------------------------------------*/

    DEFINE VARIABLE iPos AS INTEGER NO-UNDO.
    
    FIND FIRST tParam.

    DO WHILE TRUE:
        IF iSeite = 0 THEN 
        DO:
            RUN vpr_InitGroups('').
            RUN vpr_initGraphObj.
            iSeite = iSeite + 1.
            LEAVE.
        END.
        
        RUN vpr_NewPage.
        RUN vpr_InitGroups('').
        IF iLauf = 1       THEN RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Original ).
        ELSE                    RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Kopie    ).
        RUN vpr_InitGraphObj.
        iSeite = iSeite + 1.
        LEAVE.
    END.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF