GeMIS_WEB/GUI/Tools/LoeschenVerbuchteAuftraege.p

    /*------------------------------------------------------------------------------*/
    /*  Purpose:     Super Override                                                 */
    /*  Parameters:                                                                 */
    /*  Notes:                                                                      */
    /*------------------------------------------------------------------------------*/

    DEFINE VARIABLE ii      AS INTEGER   NO-UNDO.
    DEFINE VARIABLE Firma   AS CHARACTER NO-UNDO INIT '1000'.

    DISABLE TRIGGERS FOR LOAD OF Aufko   .
    DISABLE TRIGGERS FOR LOAD OF Aufze   .
    DISABLE TRIGGERS FOR LOAD OF AufLot  .
    DISABLE TRIGGERS FOR LOAD OF RuestAuf.

    FOR EACH Aufko USE-INDEX Aufko-k1
        WHERE Aufko.Firma    = Firma
        AND   Aufko.Fak_Datum <= 12/31/2023 TRANSACTION:

        FIND Debst NO-LOCK
            WHERE Debst.Firma = Aufko.Firma
            AND   Debst.Knr   = Aufko.Fak_Knr NO-ERROR.
        IF NOT AVAILABLE Debst THEN 
        DO:
            FIND Debst NO-LOCK
                WHERE Debst.Firma = Aufko.Firma
                AND   Debst.Knr   = Aufko.Knr NO-ERROR.
        END.

        FOR EACH Aufze OF Aufko:
            CREATE  Savze.
            BUFFER-COPY Aufze TO Savze
                ASSIGN  Savze.Verbucht = TRUE.
            DELETE  Aufze.
        END.

        FOR EACH AufGKon OF Aufko:

            DO WHILE TRUE:
                IF AufGKon.Depot = 0 THEN LEAVE.

                FIND LAST GebKontr NO-LOCK
                    WHERE GebKontr.Firma = Aufko.Firma
                    AND   GebKontr.Knr   = Aufko.Knr NO-ERROR.
                IF AVAILABLE GebKontr THEN ii = GebKontr.Trnr + 1.
                ELSE                       ii = 1.

                FIND FIRST Wust NO-LOCK USE-INDEX Wust-k2
                    WHERE Wust.Wucd  = AufGKon.MWST_Cd
                    AND   Wust.CodeA < 13
                    AND   Wust.CodeK < 13 NO-ERROR.
                FIND LAST MWSTAns NO-LOCK USE-INDEX MWSTAns-k1
                    WHERE MWSTAns.MWST_Cd = AufGKon.MWST_Cd
                    AND   MWSTAns.Datum  <= Aufko.Lief_Datum NO-ERROR.

                CREATE  GebKontr.
                ASSIGN  
                    GebKontr.Firma        = Aufko.Firma
                    GebKontr.Knr          = Aufko.Knr
                    GebKontr.Trnr         = ii
                    GebKontr.Geb_Cd       = AufGKon.Geb_Cd
                    GebKontr.Datum        = Aufko.Fak_Datum
                    GebKontr.Doknr        = Aufko.Faknr
                    GebKontr.Preis        = AufGKon.Depot
                    GebKontr.Eingang      = AufGKon.Eingang
                    GebKontr.Ausgang      = AufGKon.Ausgang
                    GebKontr.MWST_Cd      = AufGKon.MWST_Cd
                    GebKontr.lAbgerechnet = (IF AVAILABLE Debst THEN Debst.Geb_Rg ELSE TRUE).
                    
                IF AVAILABLE MWSTAns THEN GebKontr.MWST_%     = MWSTAns.Ansatz.
                IF AVAILABLE Wust    THEN GebKontr.MWST_Inkl  = Wust.Incl.
                LEAVE.
            END.

            CREATE  SavGKon.
            BUFFER-COPY AufGKon TO SavGKon.
            DELETE AufGKon.
        END.

        FOR EACH AufRabSu OF Aufko:
            CREATE  SavRabSu.
            BUFFER-COPY AufRabSu TO SavRabSu.
            DELETE AufRabSu.
        END.

        FOR EACH AufGebKo OF Aufko:
            IF AufGebKo.Menge <> 0 THEN 
            DO:
                CREATE  SavGebKo.
                BUFFER-COPY AufGebKo TO SavGebKo.
            END.
            DELETE AufGebKo.
        END.
        FOR EACH AufLot OF Aufko:
            CREATE  SavLot.
            BUFFER-COPY AufLot TO SavLot.
            DELETE AufLot.
        END.
        FOR EACH RuestAuf OF Aufko:
            CREATE  RuestSav.
            BUFFER-COPY RuestAuf TO RuestSav.
            DELETE RuestAuf.
        END.

        FOR EACH AufSpRab USE-INDEX AufSpRab-k1
            WHERE AufSpRab.Firma = Aufko.Firma
            AND   AufSpRab.Aufnr = Aufko.Aufnr:
            CREATE  SavSpRab.
            BUFFER-COPY AufSpRab TO SavSpRab.
            DELETE AufSpRab.
        END.

        CREATE  Savko.
        BUFFER-COPY Aufko TO Savko
            ASSIGN
                Savko.Verbucht = TRUE
                Savko.Fak_Art  = 05
                .
        DELETE Aufko.

    END.

    RELEASE Aufko   .
    RELEASE Aufze   .
    RELEASE AufGKon .
    RELEASE AufRabSu.
    RELEASE AufGebKo.
    RELEASE AufSpRab.

    RELEASE Savko   .
    RELEASE Savze   .
    RELEASE SavGKon .
    RELEASE SavRabSu.
    RELEASE SavGebKo.
    RELEASE SavSpRab.