GeMIS_WEB/GUI/TRIGGERS/t-artbez-write.p

TRIGGER PROCEDURE FOR WRITE OF Artbez
    NEW BUFFER NArtbez
    OLD BUFFER OArtbez.

    DEF VAR cDiff       AS CHAR                     NO-UNDO.
    DEF VAR cFeld       AS CHAR                     NO-UNDO.
    DEF VAR kk          AS INT                      NO-UNDO.
    DEF VAR kx          AS INT                      NO-UNDO.
    DEF VAR cWort       AS CHAR                     NO-UNDO.

    DISABLE TRIGGERS FOR LOAD OF Artst.
    DISABLE TRIGGERS FOR LOAD OF ArtLief.
 
    BUFFER-COMPARE NArtbez EXCEPT WortIndex
                                  Zustext_Druck
                                  Bez2_Druck
                   TO OArtbez
                   SAVE RESULT IN cDiff.
    IF cDiff = '' THEN RETURN.

    cWort = ''.
    RUN BEREINIGEN ( 0, NArtbez.Bez1 ).
    RUN BEREINIGEN ( 0, NArtbez.Bez2 ).
    DO kk = 1 TO 10:
        cFeld = NArtbez.Zustext[kk].
        IF cFeld = '' THEN NEXT.
        RUN BEREINIGEN ( 0, cFeld ).
    END.
    
    FIND Artst NO-LOCK OF NArtbez NO-ERROR.
    IF AVAILABLE Artst THEN DO:
        RUN BEREINIGEN ( 0, Artst.Suchbe ).
        RUN BEREINIGEN ( 0, Artst.Strichcode ).
        RUN BEREINIGEN ( 0, TRIM(STRING(Artst.Artnr,'>>>>>9')) ).
        IF Artst.Inhalt > 0 THEN RUN BEREINIGEN ( 0, 'Inhalt=' + TRIM(STRING(Artst.Inhalt,'>>>>>9')) ).
        IF Artst.Jahr   > 0 THEN RUN BEREINIGEN ( 0, 'Jahr=' + TRIM(STRING(Artst.Jahr  ,'>>>>>9')) ).
        IF Artst.FremdNr <> '' THEN DO:
            RUN BEREINIGEN ( 0, STRING(Artst.FremdNr,'XXXXXX XXXX XXXX')).
            RUN BEREINIGEN ( 0, TRIM(STRING(INTEGER(SUBSTRING(Artst.FremdNr,01,06)),'>>>>>9'))).
        END.
        FIND KGebinde NO-LOCK
                WHERE KGebinde.Firma  = Artst.Firma
                AND   KGebinde.Geb_Cd = Artst.KGeb_Cd NO-ERROR.
        IF AVAILABLE KGebinde THEN RUN BEREINIGEN ( 0, KGebinde.KBez ).
    END.
        
    FOR EACH ArtLief NO-LOCK
            WHERE ArtLief.Firma  = NArtbez.Firma
            AND   ArtLief.Artnr  = NArtbez.Artnr
            AND   ArtLief.Inhalt = NArtbez.Inhalt
            AND   ArtLief.Jahr   = NArtbez.Jahr :
        RUN BEREINIGEN ( 0, ArtLief.S_Artnr         ).
        RUN BEREINIGEN ( 0, ArtLief.Strichcode_VGeb ).
        RUN BEREINIGEN ( 0, ArtLief.Strichcode_KGeb ).
        /*
        RUN BEREINIGEN ( 0, ArtLief.S_Bez1  ).
        RUN BEREINIGEN ( 0, ArtLief.S_Bez2  ).
        */
        cFeld = 'XLIEFSTX' + STRING(ArtLief.Knr,'999999').
        RUN BEREINIGEN ( 0, cFeld  ).
    END.
    
    NArtbez.WortIndex = cWort.
    RELEASE KGebinde.
    RELEASE Artst.
    RELEASE ArtLief.
    RETURN.

PROCEDURE BEREINIGEN:

    DEF INPUT PARAMETER ipArt    AS INT             NO-UNDO.
    DEF INPUT PARAMETER ipString AS CHAR            NO-UNDO.

    DEF VAR wString     AS CHAR                     NO-UNDO.
    DEF VAR xString     AS CHAR                     NO-UNDO.
    DEF VAR yy          AS INT                      NO-UNDO.

    IF ipString = '' THEN RETURN.

    wString = ipString.
    
    IF ipArt = 1 THEN DO:
        wString = REPLACE(wString, ' ', '').
        wString = REPLACE(wString, '.', '').
        wString = REPLACE(wString, '/', '').
        wString = REPLACE(wString, '-', '').
    END.

    wString = REPLACE(wString, '*' , '' ).
    wString = REPLACE(wString, '&' , ' ').
    wString = REPLACE(wString, '+' , '' ).
    wString = REPLACE(wString, '(' , '' ).
    wString = REPLACE(wString, ')' , '' ).
    wString = REPLACE(wString, '!' , '' ).
    wString = REPLACE(wString, '|' , '' ).
    wString = REPLACE(wString, '^' , '' ).
    wString = REPLACE(wString, ';' , '' ).
    wString = REPLACE(wString, "'" , '' ).
    wString = REPLACE(wString, ',' , '' ).
    wString = REPLACE(wString, '  ', ' ').
    wString = REPLACE(wString, '-' , ' ').
    wString = TRIM(wString).

    IF wString = '' THEN RETURN.

    DO yy = 1 TO NUM-ENTRIES(wString, ' '):
        xString = ENTRY(yy, wString, ' ').
        IF LOOKUP(xString, cWort, ' ') > 0 THEN NEXT.
        cWort = cWort + (IF cWort = '' THEN '' ELSE ' ')
                      + xString.
    END.

END PROCEDURE.