GeMIS_WEB/GUI/TRIGGERS/t-debst-write.p

TRIGGER PROCEDURE FOR WRITE OF Debst
    NEW BUFFER NDebst
    OLD BUFFER ODebst.

    DEF VAR hBuffer     AS HANDLE                   NO-UNDO.
    DEF VAR wi          AS INT                      NO-UNDO.

    IF NDebst.Vertr <> ODebst.Vertr THEN DO:
        FOR EACH KuBes USE-INDEX KuBes-k2
                WHERE KuBes.Firma  = ODebst.Firma
                AND   KuBes.Knr    = ODebst.Knr
                AND   KuBes.Vertr  = ODebst.Vertr:
            ASSIGN  KuBes.Vertr = NDebst.Vertr.
        END.
    END.
    
    DISABLE TRIGGERS FOR LOAD OF Adresse.
    
    FIND Steuer NO-LOCK
            WHERE Steuer.Firma = NDebst.Firma NO-ERROR.
    IF NOT AVAILABLE Steuer THEN RETURN.
    
    FIND Adresse USE-INDEX Adresse-k1
            WHERE Adresse.Firma = Steuer.AdFirma
            AND   Adresse.Knr   = NDebst.Knr NO-ERROR.
    IF NOT AVAILABLE Adresse THEN RETURN.
    
    wi = INDEX(Adresse.WortIndex, 'XDEBSTX').
    IF NDebst.Aktiv THEN DO:
        IF wi > 0 THEN RETURN.
        Adresse.WortIndex = Adresse.WortIndex + ' XDEBSTX'.
        RETURN.
    END.
    IF wi = 0 THEN RETURN.
    Adresse.WortIndex = REPLACE(Adresse.WortIndex, 'XDEBSTX', ' ').
    Adresse.WortIndex = REPLACE(Adresse.WortIndex, '  ',      ' ').
    RETURN.