GeMIS_WEB/GUI/DruckProgramme/Huber/Lieferschein.p

&ANALYZE-SUSPEND _VERSION-NUMBER AB_v10r12
&ANALYZE-RESUME
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _DEFINITIONS Procedure 
/*------------------------------------------------------------------------
    File        : 
    Purpose     :

    Syntax      :

    Description :

    Author(s)   :
    Created     :
    Notes       :
  ----------------------------------------------------------------------*/
/*          This .W file was created with the Progress AppBuilder.      */
/*----------------------------------------------------------------------*/

/* ***************************  Definitions  ************************** */

DEFINE INPUT  PARAMETER iphParam   AS HANDLE           NO-UNDO.
DEFINE OUTPUT PARAMETER opcResult  AS CHARACTER        NO-UNDO.

DEFINE VARIABLE iSeite        AS INTEGER   NO-UNDO.
DEFINE VARIABLE iAnzDok       AS INTEGER   NO-UNDO.
DEFINE VARIABLE iLauf         AS INTEGER   NO-UNDO.
DEFINE VARIABLE lFirst        AS LOG       INIT FALSE NO-UNDO.
DEFINE VARIABLE lLast         AS LOG       INIT FALSE NO-UNDO.
DEFINE VARIABLE lPreis        AS LOG       NO-UNDO.

DEFINE VARIABLE cFirma        AS CHARACTER NO-UNDO.
DEFINE VARIABLE AdFirma       AS CHARACTER NO-UNDO.
DEFINE VARIABLE nFakBetr      AS DECIMAL   NO-UNDO.
DEFINE VARIABLE dFakDatum     AS DATE      NO-UNDO.
DEFINE VARIABLE iFaknr        AS INTEGER   NO-UNDO.
DEFINE VARIABLE iSprcd        AS INTEGER   NO-UNDO.
DEFINE VARIABLE nTotale       AS DECIMAL   EXTENT 15 NO-UNDO.
DEFINE VARIABLE cFormtext     AS CHARACTER EXTENT 30 NO-UNDO.
DEFINE VARIABLE cRabText      AS CHARACTER NO-UNDO.
DEFINE VARIABLE cZusText      AS CHARACTER NO-UNDO.
DEFINE VARIABLE cEpzText      AS CHARACTER NO-UNDO.
DEFINE VARIABLE cBesrKopf     AS CHARACTER EXTENT 12 NO-UNDO.
DEFINE VARIABLE lDebIncl      AS LOG       NO-UNDO.
DEFINE VARIABLE Rundbetr      AS DECIMAL   DECIMALS 4 NO-UNDO.
DEFINE VARIABLE RundCode      AS INTEGER   INIT 1 NO-UNDO.
DEFINE VARIABLE htTabTexte    AS HANDLE    NO-UNDO.
DEFINE VARIABLE hAufko        AS HANDLE    NO-UNDO.

DEFINE VARIABLE iMaxPos       AS INTEGER   INIT 2650 NO-UNDO.
DEFINE VARIABLE cvpr_Dokument AS CHARACTER NO-UNDO.
DEFINE VARIABLE iArtZeile     AS INTEGER   NO-UNDO.
DEFINE VARIABLE iVPagePos     AS INTEGER   NO-UNDO.
DEFINE VARIABLE iVGroupPos    AS INTEGER   NO-UNDO.

DEFINE BUFFER bAufko   FOR Aufko   .
DEFINE BUFFER bAufze   FOR Aufze   .
DEFINE BUFFER FDebst   FOR Debst   .       /*  Fakturaadresse  */
DEFINE BUFFER LDebst   FOR Debst   .       /*  Lieferadresse   */
DEFINE BUFFER LAdresse FOR Adresse .
DEFINE BUFFER bAdresse FOR Adresse .
DEFINE BUFFER bWust    FOR Wust    .
DEFINE BUFFER bSteuer  FOR Steuer  .

{ incl/ttsendmail.i   }
{ incl/properties.i   }
{ incl/ttdruckparam.i }

DEFINE TEMP-TABLE tDokument
    FIELD cGruppe AS CHARACTER
    FIELD iZeile  AS INTEGER
    FIELD cFeld   AS CHARACTER
    FIELD cInhalt AS CHARACTER
    
    INDEX tDokument-k1 IS PRIMARY
    cGruppe
    iZeile
    cFeld
    .
DEFINE TEMP-TABLE tTotale
    FIELD nMwstPfl AS DECIMAL EXTENT 12
    FIELD nMwstBet AS DECIMAL EXTENT 12
    FIELD nSammTot AS DECIMAL
    FIELD nSkBer   AS DECIMAL
    FIELD nWW      AS DECIMAL
    .
DEFINE TEMP-TABLE sAufko
    FIELD cFirma   AS CHARACTER
    FIELD iAufnr   AS INTEGER
    FIELD iFak_Knr AS INTEGER
    FIELD iKnr     AS INTEGER
    FIELD iSamm_Nr AS INTEGER
    FIELD iRecid   AS RECID
    FIELD iFaknr   AS INTEGER
    FIELD lMail    AS LOGICAL
    FIELD rAdresse AS RECID 
    FIELD rDebst   AS RECID 
    .
DEFINE TEMP-TABLE tAufko LIKE Aufko
    FIELD iRecid AS RECID
    .
DEFINE TEMP-TABLE tAufze
    FIELD Aufnr  AS INTEGER
    FIELD Sort1  AS CHARACTER
    FIELD Sort2  AS CHARACTER
    FIELD Sort3  AS CHARACTER
    FIELD Artnr  AS INTEGER
    FIELD Inhalt AS INTEGER
    FIELD Jahr   AS INTEGER
    FIELD Pos    AS INTEGER
    FIELD Zeile  AS RECID
    FIELD Preis  AS DECIMAL   DECIMALS 4
    FIELD Aktion AS LOG
    FIELD LagOrt AS CHARACTER
    FIELD MGeli  AS DECIMAL
    FIELD MRuek  AS DECIMAL
    
    INDEX tAufze-k1 IS PRIMARY
    Aufnr
    Sort1
    Sort2
    Sort3
    .
DEFINE TEMP-TABLE tRueckst LIKE tAufze
    .

DEFINE TEMP-TABLE tSpeRab
    FIELD Rab_Grp  AS INTEGER
    FIELD Auf_Betr AS DECIMAL DECIMALS 4
    .
DEFINE TEMP-TABLE tGebKto
    FIELD Sort_Cd  AS CHARACTER
    FIELD Geb_Cd   AS CHARACTER
    FIELD Bez      AS CHARACTER
    FIELD Preis    AS DECIMAL
    FIELD A_Anz    AS DECIMAL
    FIELD A_Betrag AS DECIMAL
    FIELD E_Anz    AS DECIMAL
    FIELD E_Betrag AS DECIMAL
    FIELD MWST_Art AS INTEGER
    FIELD MWST_Cd  AS INTEGER
    .
DEFINE TEMP-TABLE tRabSumm
    FIELD Rab_Summ  AS INTEGER
    FIELD Bez       AS CHARACTER
    FIELD F_Rab_Art AS INTEGER
    FIELD F_Wert    AS DECIMAL   DECIMALS 4
    FIELD A_Rab_Art AS INTEGER
    FIELD A_Wert    AS DECIMAL   DECIMALS 4
    FIELD Auf_Rab   AS DECIMAL   DECIMALS 4
    FIELD Abh_Rab   AS DECIMAL   DECIMALS 4
    .
DEFINE TEMP-TABLE tUmsGrp
    FIELD Ums_Grp  AS INTEGER
    FIELD Mwst     AS INTEGER
    FIELD Ansatz   AS DECIMAL
    FIELD Bez      AS CHARACTER
    FIELD Ums_Betr AS DECIMAL   DECIMALS 4
    .
DEFINE TEMP-TABLE tTabTexte
    FIELD cRecArt AS CHARACTER
    FIELD iZeile  AS INTEGER
    FIELD cFeld1  AS CHARACTER
    FIELD cFeld2  AS CHARACTER
    FIELD cFeld3  AS CHARACTER
    FIELD iFeld1  AS INTEGER
    FIELD iFeld2  AS INTEGER
    FIELD iFeld3  AS INTEGER
    
    INDEX tTabTexte-k1 IS PRIMARY
    cRecArt
    iZeile.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ANALYZE-SUSPEND _UIB-PREPROCESSOR-BLOCK 

/* ********************  Preprocessor Definitions  ******************** */

&Scoped-define PROCEDURE-TYPE Procedure
&Scoped-define DB-AWARE no



/* _UIB-PREPROCESSOR-BLOCK-END */
&ANALYZE-RESUME

/* ************************  Function Prototypes ********************** */


&IF DEFINED(EXCLUDE-generateLSMail) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _FUNCTION-FORWARD generateLSMail Procedure
FUNCTION generateLSMail RETURNS LOGICAL 
    (iprsAufko AS RECID) FORWARD.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ENDIF



/* *********************** Procedure Settings ************************ */

&ANALYZE-SUSPEND _PROCEDURE-SETTINGS
/* Settings for THIS-PROCEDURE
   Type: Procedure
   Allow: 
   Frames: 0
   Add Fields to: Neither
   Other Settings: CODE-ONLY COMPILE
 */
&ANALYZE-RESUME _END-PROCEDURE-SETTINGS

/* *************************  Create Window  ************************** */

&ANALYZE-SUSPEND _CREATE-WINDOW
/* DESIGN Window definition (used by the UIB) 
  CREATE WINDOW Procedure ASSIGN
         HEIGHT             = 15
         WIDTH              = 60.
/* END WINDOW DEFINITION */
                                                                        */
&ANALYZE-RESUME

 


&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _MAIN-BLOCK Procedure 


/* ***************************  Main Block  *************************** */

opcResult = ''.

CREATE tParam.
htParam:BUFFER-COPY(iphParam).
IF tParam.lSendMail THEN
    ASSIGN
        tParam.lDokDruck  = FALSE
        tParam.lCreatePDF = TRUE
        tParam.lOpenPDF   = FALSE.
    
ASSIGN  
    cFirma  = tParam.cFirma
    iAnzDok = tParam.Anzahl
    lPreis  = tParam.lPreis.
            
FIND bSteuer NO-LOCK WHERE bSteuer.Firma = cFirma.
AdFirma = bSteuer.AdFirma.

RUN AUFTRAG_ERMITTELN.
IF opcResult <> '' THEN RETURN 'Kein Auftrag'.
    
FOR EACH sAufko
    BY sAufko.iKnr:

    FIND bAdresse NO-LOCK
        WHERE bAdresse.Firma = AdFirma
        AND   bAdresse.Knr   = sAufko.iKnr.
    iSprcd = bAdresse.Sprcd.
    RUN GET_FORMTEXT ( tParam.cInstall, tParam.cDokument, iSprcd,
        OUTPUT cFormText ) NO-ERROR.
    cRabText =   TRIM(SUBSTRING(cFormText[21],01,20)).
    cZusText =   TRIM(SUBSTRING(cFormText[21],21,20)).
    cEpzText =   TRIM(SUBSTRING(cFormText[21],41,20)).
    RELEASE bAdresse.

    { vpr.i INIT  }
{ vpr.i START }

    DO iLauf = 1 TO iAnzDok:

        dFakDatum = TODAY.
        iSeite    = 0.
        iFaknr    = sAufko.iFaknr.
        lFirst    = TRUE.
        lLast     = FALSE.
                    
        EMPTY TEMP-TABLE tUmsGrp    .
        EMPTY TEMP-TABLE tTotale    .
            
        CREATE  tTotale.

        FOR EACH bAufko NO-LOCK
            WHERE bAufko.Firma      = sAufko.cFirma
            AND   bAufko.Aufnr      = sAufko.iAufnr
                    
            BREAK BY bAufko.Firma
            BY bAufko.Aufnr :

            EMPTY TEMP-TABLE tAufze     .
            EMPTY TEMP-TABLE tGebKto    .
            EMPTY TEMP-TABLE tRabSumm   .
            EMPTY TEMP-TABLE tSpeRab    .
            EMPTY TEMP-TABLE tTabTexte  .
            EMPTY TEMP-TABLE tRueckst   .
                
            FIND bAdresse NO-LOCK USE-INDEX Adresse-k1
                WHERE bAdresse.Firma = AdFirma
                AND   bAdresse.Knr   = bAufko.Knr NO-ERROR.
            FIND LDebst NO-LOCK USE-INDEX Debst-k1
                WHERE LDebst.Firma  = cFirma
                AND   LDebst.Knr    = bAufko.Knr NO-ERROR.
            FIND FDebst NO-LOCK USE-INDEX Debst-k1
                WHERE FDebst.Firma  = cFirma
                AND   FDebst.Knr    = bAufko.Fak_Knr NO-ERROR.
            FIND bWust NO-LOCK USE-INDEX Wust-k1
                WHERE bWust.CodeK    = LDebst.MWST
                AND   bWust.CodeA    = 99 NO-ERROR.
            
            lDebIncl  = FALSE.
            IF AVAILABLE bWust THEN lDebIncl = bWust.Incl.
            dFakDatum  = (IF bAufko.Lief_Datum < TODAY THEN TODAY ELSE bAufko.Lief_Datum).
            hAufko     = BUFFER bAufko:HANDLE.
            htTabTexte = TEMP-TABLE tTabTexte:DEFAULT-BUFFER-HANDLE.
            
            ASSIGN  
                sAufko.lMail    = (IF lDebIncl THEN FALSE ELSE TRUE)
                sAufko.rAdresse = RECID(bAdresse)
                sAufko.rDebst   = RECID(LDebst).
                
            /*  Texte und Werte aus Tabelle 'Tabel' laden für RecArt */
            /*  FAKART, AUFSTATUS, LIEFART, FAHRER, WISO, ABLAD      */
                
            RUN CREATE_TABTEXTE ( hAufko, INPUT-OUTPUT htTabTexte ) NO-ERROR.
                
            RUN FUELLEN_tAufze ( bAufko.Aufnr ) NO-ERROR.

            FOR EACH tAufze
                WHERE tAufze.Artnr > 0:
                
                FIND bAufze NO-LOCK WHERE RECID(bAufze) = tAufze.Zeile.
                    
                /*  Spezial-Auftragsrabatt pro Lieferschein bilden  */
                
                IF bAufze.Auf_Sp_Grp > 0 THEN 
                DO:
                    FIND FIRST tSpeRab
                        WHERE tSpeRab.Rab_Grp = bAufze.Auf_Sp_Grp NO-ERROR.
                    IF NOT AVAILABLE tSpeRab THEN 
                    DO:
                        CREATE  tSpeRab.
                        ASSIGN  
                            tSpeRab.Rab_Grp = bAufze.Auf_Sp_Grp.
                    END.
                    tSpeRab.Auf_Betr = tSpeRab.Auf_Betr + bAufze.Auf_Sp_Rab.
                END.
                    
                /*  Summengruppen-Totale pro Lieferschein bilden  */
                    
                DO WHILE bAufze.Rab_Su_Grp > 0:
                    FIND FIRST tRabSumm
                        WHERE tRabSumm.Rab_Summ = bAufze.Rab_Su_Grp NO-ERROR.
                    IF NOT AVAILABLE tRabSumm THEN 
                    DO:
                        FIND FIRST RabSumm NO-LOCK
                            WHERE RabSumm.Firma    = bAufze.Firma
                            AND   RabSumm.Rab_Summ = bAufze.Rab_Su_Grp NO-ERROR.
                        IF NOT AVAILABLE RabSumm THEN LEAVE.
                        CREATE  tRabSumm.
                        ASSIGN  
                            tRabSumm.Rab_Summ = bAufze.Rab_Su_Grp
                            tRabSumm.Bez      = RabSumm.Bez
                            tRabSumm.Auf_Rab  = 0
                            tRabSumm.Abh_Rab  = 0.
                    END.
                    LEAVE.
                END.
            END.
                
            IF LAST-OF ( bAufko.Aufnr ) THEN lLast = TRUE.
                
            RUN DRUCKEN.
            
            /*  Auftragskopf mutieren       */
                
            REPEAT TRANSACTION:
                IF iLauf < iAnzDok THEN LEAVE.
                RUN AUFTRAG_GEDRUCKT ( bAufko.Aufnr ).
                
                IF sAufko.lMail THEN 
                DO:
                    DYNAMIC-FUNCTION ('generateLSMail':U, RECID(sAufko)) NO-ERROR.
                END.
                
                LEAVE.
            END.
        END.
    END.
    { vpr.i STOP }
END.

PROCEDURE ShellExecuteA EXTERNAL "shell32.dll" :
    DEFINE INPUT PARAMETER lphwnd       AS LONG.
    DEFINE INPUT PARAMETER lpOperation  AS CHARACTER.
    DEFINE INPUT PARAMETER lpFile       AS CHARACTER.
    DEFINE INPUT PARAMETER lpParameters AS CHARACTER.
    DEFINE INPUT PARAMETER lpDirectory  AS CHARACTER.
    DEFINE INPUT PARAMETER nShowCmd     AS LONG.
    DEFINE RETURN PARAMETER hInstance   AS LONG.
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&IF DEFINED(EXCLUDE-GETMAILBODY) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE GETMAILBODY Procedure
PROCEDURE GETMAILBODY:
    /*------------------------------------------------------------------------------
     Purpose:
     Notes:
    ------------------------------------------------------------------------------*/

    DEFINE INPUT  PARAMETER ipiSprcd   AS CHARACTER             NO-UNDO.
    DEFINE OUTPUT PARAMETER opcBody    AS CHARACTER             NO-UNDO.

    DEFINE VARIABLE cBodyDatei AS CHARACTER NO-UNDO INIT ?.
    DEFINE VARIABLE cBody      AS CHARACTER NO-UNDO INIT ''.
    DEFINE VARIABLE lBody      AS LONGCHAR  NO-UNDO.
    
    FIND FIRST tParam.

    DO WHILE cBodyDatei = ?:
        cBodyDatei = SUBSTITUTE('druckprogramme/&1/Mail-Lieferschein-&2.html', tParam.cInstall, ipiSprcd).
        cBodyDatei = SEARCH(cBodyDatei).
        LEAVE.
    END.

    IF cBodydatei = ? THEN cBody = ''.
    ELSE 
    DO:
        FILE-INFO:FILE-NAME = cBodyDatei.
        cBodyDatei = FILE-INFO:FULL-PATHNAME.
        COPY-LOB FILE cBodydatei TO lBody NO-CONVERT.
        cBody = lBody.
    END.

    opcBody = cBody.

END PROCEDURE.
    
/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ENDIF


/* **********************  Internal Procedures  *********************** */

&IF DEFINED(EXCLUDE-ARTIKELZEILE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE ARTIKELZEILE Procedure 
PROCEDURE ARTIKELZEILE :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipRecid AS RECID            NO-UNDO.
    
    DEFINE VARIABLE cString  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE nRabWert AS DECIMAL   NO-UNDO.
    DEFINE VARIABLE xRabText AS CHARACTER NO-UNDO.
    
    FIND tAufze WHERE RECID(tAufze) = ipRecid      NO-LOCK.
    FIND Aufze  WHERE RECID(Aufze)  = tAufze.Zeile NO-LOCK.

    iArtZeile = iArtZeile + 1.    
    DO WHILE Aufze.Artnr = 0:
        cString = Aufze.Bez1.
        IF Aufze.Bez1 <> '' THEN 
        DO:
            cString = cString
                + (IF cString = '' THEN '' ELSE CHR(10))
                + Aufze.Bez2.
        END.
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'ArtikelZeile1'
            tDokument.iZeile  = iArtZeile
            tDokument.cFeld   = 'Bez1'
            tDokument.cInhalt = cString.
        RETURN.
    END.

    FIND Artst OF Aufze NO-LOCK.
            
    FIND GGebinde NO-LOCK
        WHERE GGebinde.Firma  = cFirma
        AND   GGebinde.Geb_Cd = Aufze.GGeb_Cd NO-ERROR.
    FIND VGebinde NO-LOCK
        WHERE VGebinde.Firma  = cFirma
        AND   VGebinde.Geb_Cd = Aufze.VGeb_Cd NO-ERROR.
    FIND KGebinde NO-LOCK
        WHERE KGebinde.Firma  = cFirma
        AND   KGebinde.Geb_Cd = Aufze.KGeb_Cd NO-ERROR.

    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'KGebinde', KGebinde.Kbez ).
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Artnr'   , STRING(Aufze.Artnr   ,"999999") ).
    
    IF Aufze.VGeb_Me <> 0 THEN 
    DO:
        cString = STRING(Aufze.VGeb_Me,'->>>>')
            + 'x '
            + VGebinde.KBez.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'VGebinde', cString ).
    END.
    
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Menge', STRING(Aufze.MGeli,'->>,>>9') ).
    
    cString = Aufze.Bez1.
    IF Aufze.Bez2 <> '' THEN 
    DO:
        cString = cString
            + (IF cString = '' THEN '' ELSE CHR(10))
            + Aufze.Bez2.
    END.
    IF Aufze.Aktion THEN 
    DO:
        cString = cString
            + (IF cString = '' THEN '' ELSE CHR(10))
            + Aufze.Aktion_Text.
    END.
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1', cString ).
    
    IF Aufze.Jahr > 9 THEN 
    DO:
        cString = STRING(Aufze.Jahr,"9999").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'JG', cString ).
    END.
    
    IF Aufze.Alk_Gehalt <> 0 THEN 
    DO:
        cString = STRING(Aufze.Alk_Gehalt,"zz9.9%").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Alk%', cString ).
    END.
    DO WHILE lPreis :
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis' , STRING(Aufze.Preis   ,'>>>,>>9.99') ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', STRING(Aufze.Bru_Betr,'->>>,>>9.99') ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'MC'    , STRING(Aufze.WuCd    ,'z9') ).
        
        IF Aufze.Rab_Betr = 0 THEN LEAVE.

        iArtZeile = iArtZeile + 1.        
        nRabWert  = ABSOLUTE(Aufze.Rab_Wert).
        IF Aufze.Rab_Art = 3 THEN xRabText = cEpzText.
        ELSE 
        DO:
            IF Aufze.Rab_Betr < 0 THEN xRabText = cZusText.
            IF Aufze.Rab_Betr > 0 THEN xRabText = cRabText.
        END.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1', TRIM(xRabText) ).
        
        IF Aufze.Rab_Art = 1    THEN cString = STRING(nRabWert,"->9.9%").
        IF Aufze.Rab_Art = 2    OR
            Aufze.Rab_Art = 3    THEN cString = STRING(nRabWert,"-9.99").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', cString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(- Aufze.Rab_Betr,"->>>,>>9.99")) ).
        LEAVE.
    END.
    
    DO WHILE lPreis:    
        IF Aufze.Zus_Betr = 0 THEN LEAVE.
        
        iArtZeile = iArtZeile + 1.        
        nRabWert   = ABSOLUTE(Aufze.Zus_Wert).
        IF Aufze.Zus_Art = 3 THEN xRabText = cEpzText.
        ELSE 
        DO:
            IF Aufze.Zus_Betr < 0 THEN xRabText = cRabText.
            IF Aufze.Zus_Betr > 0 THEN xRabText = cZusText.
        END.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1', TRIM(xRabText) ).
        
        IF Aufze.Zus_Art = 1    THEN cString = STRING(nRabWert,"->9.9%").
        IF Aufze.Zus_Art = 2    OR
            Aufze.Zus_Art = 3    THEN cString = STRING(nRabWert,"-9.99").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Preis', cString ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(+ Aufze.Zus_Betr,"->>>,>>9.99")) ).
        LEAVE.
    END.
    
    /*  ----  Summengruppen-Total  -------------------------------------------- */
        
    IF Aufze.Rab_Su_Grp <> 0 THEN 
    DO:
        FIND FIRST tRabSumm WHERE tRabSumm.Rab_Summ = Aufze.Rab_Su_Grp NO-ERROR.
        IF AVAILABLE tRabSumm THEN 
        DO:
            tRabSumm.Auf_Rab = tRabSumm.Auf_Rab + Aufze.Auf_Rab.
            tRabSumm.Abh_Rab = tRabSumm.Abh_Rab + Aufze.Abh_Rab.
        END.
    END.
            
    /*  ----  Warengruppen-Totale  -------------------------------------------- */
        
    FIND FIRST TUmsGrp WHERE TUmsGrp.Ums_Grp = Artst.Wg_Grp
        AND   TUmsGrp.MWst    = Aufze.WuCd
        AND   TUmsGrp.Ansatz  = Aufze.Mwst% NO-ERROR.
    IF NOT AVAILABLE TUmsGrp THEN 
    DO:
        FIND WarenGrp NO-LOCK USE-INDEX WarenGrp-k1
            WHERE WarenGrp.Firma  = cFirma
            AND   WarenGrp.Wgr    = Artst.Wg_Grp NO-ERROR.
        CREATE  TUmsGrp.
        ASSIGN  
            TUmsGrp.Ums_Grp = Artst.Wg_Grp
            TUmsGrp.Mwst    = Aufze.WuCd
            TUmsGrp.Ansatz  = Aufze.MWST%.
        IF AVAILABLE WarenGrp THEN TUmsGrp.Bez = WarenGrp.Bez1.
        ELSE                       TUmsGrp.Bez = "??????????".
    END.
            
    TUmsGrp.Ums_Betr = TUmsGrp.Ums_Betr 
        + Aufze.Net_Betr
        - Aufze.Auf_Rab
        - Aufze.Abh_Rab.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-AUFTRAG_ERMITTELN) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE AUFTRAG_ERMITTELN Procedure 
PROCEDURE AUFTRAG_ERMITTELN :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE iAufnr AS INTEGER NO-UNDO.

    FIND FIRST tParam.
    
    EMPTY TEMP-TABLE sAufko.
    
    /*  Sammeln aller Aufträge pro Sammelnummer  */

    FOR EACH Aufko NO-LOCK USE-INDEX Aufko-k5
        WHERE Aufko.Firma       = tParam.cFirma
        AND   Aufko.Aufnr       = tParam.iAufnr :
            
        CREATE  sAufko.
        ASSIGN  
            sAufko.cFirma   = Aufko.Firma
            sAufko.iAufnr   = Aufko.Aufnr
            sAufko.iFak_Knr = Aufko.Fak_Knr
            sAufko.iKnr     = Aufko.Knr
            sAufko.iSamm_Nr = 0
            sAufko.iRecid   = RECID(Aufko)
            sAufko.iFaknr   = 0.
    END.
    
    /*  Alle Auftragstotale aller Lieferscheine neu rechnen     */
    
    FOR EACH sAufko:
        FOR EACH bAufko NO-LOCK
            WHERE bAufko.Firma = sAufko.cFirma
            AND   bAufko.Aufnr = sAufko.iAufnr :
            DYNAMIC-FUNCTION('calculateAuftragsTotal':U, bAufko.Firma,
                bAufko.Aufnr,
                OUTPUT nTotale ) NO-ERROR.
            RELEASE bAufko.
        END.
    END.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-AUSGABE_ARTIKELZEILE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE AUSGABE_ARTIKELZEILE Procedure 
PROCEDURE AUSGABE_ARTIKELZEILE :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cZellen AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cWerte  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE iPos    AS INTEGER   NO-UNDO.
    
    FOR EACH tDokument
        WHERE tDokument.cGruppe = 'ArtikelZeile1'
        BREAK BY tDokument.cGruppe
        BY tDokument.iZeile:
        IF FIRST-OF ( tDokument.cGruppe ) THEN 
        DO:
            iVPagePos = vpr_getPageVPos() + 20.
            RUN vpr_setPageVPos  ( iVPagePos ).
            RUN vpr_setGroupVPos ( 'ArtikelZeile1', iVPagePos ).
        END.
        IF FIRST-OF ( tDokument.iZeile ) THEN 
        DO:
            cZellen = ''.
            cWerte  = ''.
        END.
        cWerte  = cWerte 
            + tDokument.cInhalt.
        cZellen = cZellen
            + tDokument.cFeld.
        IF NOT LAST-OF ( tDokument.iZeile ) THEN 
        DO:
            ASSIGN 
                cWerte  = cWerte  + CHR(01)
                cZellen = cZellen + ','.
            NEXT.
        END.
        
        RUN vpr_SetDelimiter (CHR(01)).
        RUN vpr_setGroupText ('ArtikelZeile1', cZellen, cWerte).
        iVPagePos = vpr_getPageVPos().
        iPos      = iVPagePos + vpr_getGroupHeight('ArtikelZeile1').
        IF iPos > iMaxPos THEN 
        DO:
            RUN VIPER_NEUE_SEITE.
            RUN DRUCKEN_ADRESSE.
            iVPagePos = vpr_getPageVPos() + 20.
            RUN vpr_setPageVPos ( iVPagePos ).
            RUN vpr_setGroupText ('ArtikelZeile1', cZellen, cWerte).
        END.
        RUN vpr_FlushGroup   ('ArtikelZeile1').
        iVPagePos = vpr_getPageVPos().

        IF LAST-OF ( tDokument.cGruppe ) THEN LEAVE.
            
        iVPagePos = vpr_getPageVPos().
        RUN vpr_setGroupVPos ( 'ArtikelZeile1', iVPagePos ).
    END.
    FOR EACH tDokument
        WHERE tDokument.cGruppe = 'ArtikelZeile1':
        DELETE  tDokument.
    END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-AUSGABE_GRUPPE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE AUSGABE_GRUPPE Procedure 
PROCEDURE AUSGABE_GRUPPE :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipGruppe    AS CHARACTER     NO-UNDO.

    DEFINE VARIABLE cZellen AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cWerte  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE iSpace  AS INTEGER   NO-UNDO.
    
    FIND FIRST tParam.
    
    iSpace = vpr_getPageVPos().
    FOR EACH tDokument NO-LOCK
        WHERE tDokument.cGruppe = ipGruppe
        BREAK BY tDokument.cGruppe
        BY tDokument.iZeile:
        IF FIRST-OF ( tDokument.iZeile ) THEN iSpace = iSpace + 40.
    END.
    IF iSpace > iMaxPos THEN 
    DO:
        RUN vpr_NewPage.
        RUN vpr_InitGroups('').
        IF iLauf = iAnzDok THEN RUN vpr_initGraphObj.
        iSeite = iSeite + 1.
        RUN DRUCKEN_ADRESSE.
    END.
    
    iVPagePos = vpr_getPageVPos().
    CASE ipGruppe:
        WHEN 'Gebindeabrechnung' THEN 
            DO:
                iVPagePos = iVPagePos + 20.
                RUN vpr_setGroupVPos ( 'GebindeabrechnungTitel', iVPagePos ).
                RUN vpr_FlushGroup   ( 'GebindeabrechnungTitel').
                iVPagePos = vpr_getPageVPos().
            END.
        OTHERWISE 
        DO:
        END.
    END CASE.
    
    FOR EACH tDokument
        WHERE tDokument.cGruppe = ipGruppe
        BREAK BY tDokument.cGruppe
        BY tDokument.iZeile:
        IF FIRST-OF ( tDokument.cGruppe ) THEN 
        DO:
            IF ipGruppe <> 'Kondition' AND
                ipGruppe <> 'BESR'      AND
                ipGruppe <> 'ADRESSE'   THEN 
            DO:
                iVPagePos = vpr_getPageVPos().
                RUN vpr_setGroupVPos ( ipGruppe, iVPagePos ).
            END.
        END.
        IF FIRST-OF ( tDokument.iZeile ) THEN 
        DO:
            cZellen = ''.
            cWerte  = ''.
        END.
        cWerte  = cWerte 
            + tDokument.cInhalt.
        cZellen = cZellen
            + tDokument.cFeld.
        IF NOT LAST-OF ( tDokument.iZeile ) THEN 
        DO:
            ASSIGN 
                cWerte  = cWerte  + CHR(01)
                cZellen = cZellen + ','.
            NEXT.
        END.
        RUN vpr_SetDelimiter (CHR(01)).
        RUN vpr_setGroupText (ipGruppe, cZellen, cWerte).
        RUN vpr_FlushGroup   (ipGruppe).
    END.
    FOR EACH tDokument
        WHERE tDokument.cGruppe = ipGruppe:
        DELETE  tDokument.
    END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN Procedure 
PROCEDURE DRUCKEN :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cText     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cLAdresse AS CHARACTER NO-UNDO.
    DEFINE VARIABLE RText     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE WText     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE i1        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE nBetrag   AS DECIMAL   NO-UNDO.
    DEFINE VARIABLE iMwstCd   AS INTEGER   NO-UNDO.
    DEFINE VARIABLE nZeiTot   AS DECIMAL   DECIMALS 4 NO-UNDO.
    DEFINE VARIABLE lJa       AS LOG       NO-UNDO.
    DEFINE VARIABLE cPDFName  AS CHARACTER INIT '' NO-UNDO.
    
    FIND FIRST tParam.
    IF tParam.lBatch THEN 
    DO:
        ASSIGN  
            tParam.lOpenPDF = FALSE.
    END.

    nFakBetr = 0.
    IF iSeite = 0 THEN RUN VIPER_INIT.
    
    RUN DRUCKEN_KOPF.

    iArtZeile = 0.
    iVPagePos = vpr_getPageVPos().
    RUN vpr_setGroupVPos ( 'ArtikelZeile1', iVPagePos ).
    
    FOR EACH tAufze NO-LOCK
        BY tAufze.Aufnr
        BY tAufze.Sort1
        BY tAufze.LagOrt
        BY tAufze.Sort2
        BY tAufze.Pos  :
             
        FIND Aufze NO-LOCK WHERE RECID(Aufze) = tAufze.Zeile.
        
        RUN ARTIKELZEILE ( RECID(tAufze) ).

        nFakBetr = nFakBetr + Aufze.Net_Betr.
        RELEASE Aufze.
    END.

    IF lPreis THEN 
    DO:    
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1'  , ' ' ).
        iArtZeile = iArtZeile + 1.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1'  , TRIM(SUBSTRING(cFormText[10],41,20)) ).
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Betrag', TRIM(STRING(nFakBetr,'->>>,>>9.99')) ).
    END.
    iArtZeile = iArtZeile + 1.
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1'  , ' ' ).
    
    RUN AUSGABE_ARTIKELZEILE.

    /*  Auftragsrabatt  ----------------------------------------------------    */

    FOR EACH tRabSumm
        WHERE tRabSumm.Auf_Rab <> 0
        BY tRabSumm.Rab_Summ:
        Rundbetr = tRabSumm.Auf_Rab.
        nFakBetr = nFakBetr - Rundbetr.
    END.

    /*  Abholrabatt  -------------------------------------------------------    */
    
    FOR EACH tRabSumm
        WHERE tRabSumm.Abh_Rab <> 0
        BY tRabSumm.Rab_Summ:
        Rundbetr = tRabSumm.Abh_Rab.
        nFakBetr = nFakBetr - Rundbetr.
    END.
    
    /*  Spezialpreis-Auftragsrabatte  ----------------------------------------  */
    
    FOR EACH tSpeRab WHERE tSpeRab.Auf_Betr <> 0
        BY tSpeRab.Rab_Grp:
        Rundbetr = tSpeRab.Auf_Betr.
        nFakBetr = nFakBetr - Rundbetr.
    END.
    /*  Recycling-Gebuehren  -----------------------------------------------    */

    FOR EACH AufGKon NO-LOCK
        WHERE AufGKon.Firma    = BAufko.Firma
        AND   AufGKon.Aufnr    = BAufko.Aufnr
        AND   AufGKon.Gebuehr <> 0
        AND   AufGKon.Betrag  <> 0 :
        iMwstCd  = AufGKon.MWST_Cd.
        nFakBetr = nFakBetr + AufGKon.Betrag.
    END.
    RELEASE AufGKon.

    /*  Gebinde Aus- und Eingänge   ----------------------------------------    */
    IF FDebst.Geb_Rg THEN 
    DO:
        FOR EACH AufGKon NO-LOCK
            WHERE AufGKon.Firma    = BAufko.Firma
            AND   AufGKon.Aufnr    = BAufko.Aufnr
            AND   AufGKon.Depot   <> 0
            AND   AufGKon.Betrag  <> 0 :

            FIND FIRST tGebKto WHERE tGebKto.Geb_Cd = AufGKon.Geb_Cd NO-ERROR.
            IF NOT AVAILABLE tGebKto THEN 
            DO:
                FIND GebKonto NO-LOCK
                    WHERE GebKonto.Firma  = AufGKon.Firma
                    AND   GebKonto.Geb_Cd = AufGKon.Geb_Cd.
                CREATE  tGebKto.
                ASSIGN  
                    tGebKto.Sort_Cd = GebKonto.Sort_Cd
                    tGebKto.Geb_Cd  = GebKonto.Geb_Cd
                    tGebKto.Bez     = GebKonto.Bez
                    tGebKto.Preis   = AufGKon.Depot
                    tGebKto.MWST_Cd = AufGKon.MWSt_Cd.
            END.
            tGebKto.A_Anz    = tGebKto.A_Anz + AufGKon.Ausgang.
            tGebKto.A_Betrag = tGebKto.A_Anz * tGebKto.Preis.
            tGebKto.E_Anz    = tGebKto.E_Anz + AufGKon.Eingang.
            tGebKto.E_Betrag = tGebKto.E_Anz * tGebKto.Preis.
        END.
        RELEASE AufGKon.
    
        /*  Gebindelieferungen  ------------------------------------------------    */

        nBetrag   = 0.
        iArtZeile = 0.
        FOR EACH AufGKon NO-LOCK
            WHERE AufGKon.Firma    = BAufko.Firma
            AND   AufGKon.Aufnr    = BAufko.Aufnr
            AND   AufGKon.Depot   <> 0
            AND  (AufGKon.Eingang <> 0  OR
            AufGKon.Ausgang <> 0)
                      
            BREAK BY AufgKon.Firma
            BY AufGKon.Aufnr:

            FIND GebKonto NO-LOCK
                WHERE GebKonto.Firma  = cFirma
                AND   GebKonto.Geb_Cd = AufGKon.Geb_Cd.
            i1        = AufGKon.Ausgang - AufGKon.Eingang.
            Rundbetr  = AufGKon.Betrag.
            iMwstCd   = AufGKon.MWSt_Cd.
            nBetrag   = nBetrag   + Rundbetr.
            iArtZeile = iArtZeile + 1.
            RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'Gebindetext' , GebKonto.Bez ).
            RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeGel'  , TRIM(STRING(AufGKon.Ausgang,"->>,>>9")) ).
            RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeRet'  , TRIM(STRING(AufGKon.Eingang,"->>,>>9")) ).
            RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeSaldo', TRIM(STRING(i1             ,"->>,>>9")) ).
            IF lPreis THEN 
                RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeBetr' , TRIM(STRING(Rundbetr    ,"->>,>>9.999")) ).
        END.
        RELEASE AufGKon.
        RELEASE GebKonto.

        IF lPreis        AND
            iArtZeile > 0 THEN 
            RUN VIPER_CREATE_DOKUMENT ( 'Gebindeabrechnung', iArtZeile,  'GebindeTot'  , TRIM(STRING(nBetrag      ,"->>>,>>9.999")) ).
        nFakBetr = nFakBetr + nBetrag.
        IF iArtZeile > 0 THEN RUN AUSGABE_GRUPPE ('Gebindeabrechnung').
    END.
    
    /*  ------  RUECKSTAENDE  ----------------------------------------------------  */
    
    DO WHILE TRUE:
        FIND FIRST tRueckst NO-ERROR.
        IF NOT AVAILABLE tRueckst THEN LEAVE.
        
        iVPagePos = vpr_getPageVPos() + 150.
        IF iVPagePos > iMaxPos THEN 
        DO:
            RUN VIPER_NEUE_SEITE.
            RUN DRUCKEN_ADRESSE.
        END.

        cText = 'Rückstände bitte neu bestellen'.        
        iVPagePos = vpr_getPageVPos() + 50.
        RUN vpr_setGroupVPos ('Rueckstand', iVPagePos ).
        RUN vpr_setCellText  ('RueckTitel', 'Rueckstand', cText ).
        RUN vpr_flushGroup   ('Rueckstand').

        iArtZeile = 1.        
        FOR EACH tRueckst:
            RUN DRUCKEN_RUECKSTAND ( RECID(tRueckst) ).
        END.
        RUN AUSGABE_ARTIKELZEILE.
        LEAVE.
    END.
    
    /*  Gebinderücknahmetabelle  -------------------------------------------    */

    iVPagePos  = vpr_getPageVPos().
    iVGroupPos = vpr_getGroupVPos('Gebindetabelle').
    IF iVPagePos < iVGroupPos THEN RUN vpr_flushGroup('Gebindetabelle').
    ELSE 
    DO:
        RUN VIPER_NEUE_SEITE.
        RUN DRUCKEN_ADRESSE.
        RUN vpr_flushGroup('Gebindetabelle').
    END.

    /*  ------------------------------------------------------  */
    /*  Druckausgabe                                            */    
    /*  ------------------------------------------------------  */
    
    RUN vpr_EndDoc.
    cvpr_Dokument = SUBSTITUTE('Lieferscheine\&1-&2_&3.vpr',
        STRING(bAufko.Knr  ,'999999'),
        STRING(bAufko.Aufnr,'9999999'),
        tParam.cDokument).
    RUN vpr_SaveDoc ( cvpr_Dokument ).

    DO WHILE tParam.lDokDruck:
        IF NOT tParam.lBatch THEN 
        DO:
            SESSION:PRINTER-NAME = tParam.Drucker NO-ERROR.
            IF  ERROR-STATUS:ERROR                     OR
                SESSION:PRINTER-NAME <> tParam.Drucker THEN 
            DO:
                RUN vpr_printerDialog ( OUTPUT lJa ).
                IF NOT lJa THEN LEAVE.
            END.
        END.
        RUN vpr_printDoc (0, 0).
        LEAVE.
    END.
    IF tParam.lCreatePDF THEN 
    DO:
/*        IF tParam.lBatch THEN RUN vpr_SetPrinterAttrib('copies=1').*/
        RUN vpr_SetPrinterAttrib('copies=1').
        cPDFName = REPLACE(cvpr_Dokument, '.vpr', '.pdf').
        RUN vpr_printPDF (0, 0, INPUT-OUTPUT cPDFName ).
    END.

    IF tParam.lOpenPDF THEN 
    DO:    
        DEFINE VARIABLE o-i AS i NO-UNDO.    
        FILE-INFO:FILE-NAME = cPDFName.
        cPDFName = FILE-INFO:FULL-PATHNAME.
        RUN shellExecuteA (0,
            "open",
            cPDFName,
            "",
            "",
            0,
            OUTPUT o-i).
    END.
    
    IF tParam.lSendMail THEN RUN SEND_MAIL ( cPDFName ).
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN_ADRESSE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN_ADRESSE Procedure 
PROCEDURE DRUCKEN_ADRESSE :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cZellen AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cWerte  AS CHARACTER NO-UNDO.
    
    FIND FIRST tParam.

    FIND FIRST tDokument
        WHERE tDokument.cGruppe = 'KOPF'
        AND   tDokument.iZeile  = 1
        AND   tDokument.cFeld   = 'Seite' NO-ERROR.
    IF NOT AVAILABLE tDokument THEN 
    DO:
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPF'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Seite'.
    END.
    tDokument.cInhalt = STRING(iSeite,'z9').

    cZellen = ''.
    cWerte  = ''.
    FOR EACH tDokument
        WHERE tDokument.cGruppe = 'Kopf'
        BREAK BY tDokument.cGruppe
        BY tDokument.cFeld:
        cWerte  = cWerte 
            + tDokument.cInhalt.
        cZellen = cZellen
            + tDokument.cFeld.
        IF NOT LAST-OF ( tDokument.cGruppe ) THEN ASSIGN cWerte  = cWerte  + CHR(01)
                cZellen = cZellen + ','.
    END.

    RUN vpr_SetDelimiter (CHR(01)).
    RUN vpr_setGroupText ('Kopf', cZellen, cWerte).
    RUN vpr_FlushGroup   ('Kopf').
    
    IF iSeite  = 1 THEN 
    DO:
        cZellen = ''.
        cWerte  = ''.
        FOR EACH tDokument
            WHERE tDokument.cGruppe = 'KopfDetail'
            BREAK BY tDokument.cGruppe
            BY tDokument.cFeld:
            cWerte  = cWerte 
                + tDokument.cInhalt.
            cZellen = cZellen
                + tDokument.cFeld.
            IF NOT LAST-OF ( tDokument.cGruppe ) THEN ASSIGN cWerte  = cWerte  + CHR(01)
                    cZellen = cZellen + ','.
        END.
        RUN vpr_SetDelimiter (CHR(01)).
        RUN vpr_setGroupText ('KopfDetail', cZellen, cWerte).
        RUN vpr_FlushGroup   ('KopfDetail').
    END.

    RUN vpr_FlushGroup ('Fusstext').
    RUN vpr_FlushGroup ('Ueberschrift').

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN_KOPF) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN_KOPF Procedure 
PROCEDURE DRUCKEN_KOPF :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cText AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii    AS INTEGER   NO-UNDO.
    DEFINE VARIABLE i1    AS INTEGER   NO-UNDO.
    
    FIND FIRST tParam.

    RUN VIPER_NEUE_SEITE.

    IF iSeite = 1 THEN 
    DO:
        iFaknr = tParam.iAufnr.
        
        cBesrKopf = ''.
        IF bAufko.Adresse[05] <> '' THEN 
        DO:
            i1 = 6.
            DO ii = 1 TO 5:
                CREATE  tDokument.
                ASSIGN  
                    tDokument.cGruppe = 'KOPF'
                    tDokument.iZeile  = 1
                    tDokument.cFeld   = 'Adresse_' + STRING((6 + ii),'99')
                    tDokument.cInhalt = bAufko.Adresse[ii].
                i1 = i1 + 1.
                cBesrKopf[i1] = bAufko.Adresse[ii].
            END.
        END.
        ELSE 
        DO:
            DO ii = 5 TO 11:
                CREATE  tDokument.
                ASSIGN  
                    tDokument.cGruppe = 'KOPF'
                    tDokument.iZeile  = 1
                    tDokument.cFeld   = 'Adresse_' + STRING(ii,'99')
                    tDokument.cInhalt = bAdresse.Anschrift[ii].
                cBesrKopf[ii] = bAdresse.Anschrift[ii].
            END.
        END.
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPF'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Ort_Datum'
            tDokument.cInhalt = TRIM(SUBSTRING(cFormText[07],01,20))
                                  + " "
                                  + STRING(TODAY,"99.99.9999").

        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPF'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'T_Dokument'
            tDokument.cInhalt = (IF bAufko.Auf_Tot >= 0
                                    THEN TRIM(SUBSTRING(cFormText[02],01,20))
                                    ELSE TRIM(SUBSTRING(cFormText[02],21,20))).
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPF'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Aufnr'
            tDokument.cInhalt = STRING(iFaknr,'z999999').
    
        FIND FIRST tTabTexte WHERE tTabTexte.cRecArt = 'WISO' NO-ERROR.
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Wirtesonntag'
            tDokument.cInhalt = (IF AVAILABLE tTabTexte THEN tTabTexte.cFeld3 ELSE ' ').
    
        FIND FIRST tTabTexte WHERE tTabTexte.cRecArt = 'ABLAD' NO-ERROR.
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Ablade'
            tDokument.cInhalt = (IF AVAILABLE tTabTexte THEN tTabTexte.cFeld3 ELSE ' ').
    
        FIND FIRST tTabTexte WHERE tTabTexte.cRecArt = 'FAHRER' NO-ERROR.
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Chauffeur'
            tDokument.cInhalt = (IF AVAILABLE tTabTexte THEN tTabTexte.cFeld1 ELSE ' ').
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Auf_Datum'
            tDokument.cInhalt = STRING(bAufko.Auf_Datum,'99.99.9999').
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Lief_Datum'
            tDokument.cInhalt = STRING(bAufko.Lief_Datum,'99.99.9999').
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'U_Ref'
            tDokument.cInhalt = bAufko.U_Ref.
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Knr'
            tDokument.cInhalt = STRING(bAufko.Knr,'999999').
    
        cText = ''.
        cText = (IF bAdresse.Tel-1 <> '' THEN bAdresse.Tel-1 ELSE bAdresse.Tel-2).
        IF bAdresse.Natel <> '' THEN cText = cText
                + (IF cText = '' THEN '' ELSE ' / ')
                + bAdresse.Natel.

        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Telefon'
            tDokument.cInhalt = cText.
    
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'KOPFDETAIL'
            tDokument.iZeile  = 1
            tDokument.cFeld   = 'Gewicht'
            tDokument.cInhalt = TRIM(STRING(bAufko.Gewicht,'->>>,>>9.999')).
    END.
    
    RUN DRUCKEN_ADRESSE.
    
    IF iSeite <> 1 THEN RETURN.
    
    cText = bAufko.Abh_Text
        + (IF bAufko.Abh_Text <> '' THEN CHR(10) + CHR(10) ELSE '')
        + bAufko.Auf_Text.
    IF cText = '' THEN RETURN.
    
    iVPagePos = vpr_getPageVPos() + 20.
    RUN vpr_setGroupVPos ( 'Zusatztext' , iVPagePos ).
    RUN vpr_setCellText  ( 'Bemerkung_1', 'Zusatztext', cText ).
    RUN vpr_flushGroup   ( 'Zusatztext' ).
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-DRUCKEN_RUECKSTAND) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE DRUCKEN_RUECKSTAND Procedure 
PROCEDURE DRUCKEN_RUECKSTAND :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipRecid AS RECID            NO-UNDO.
    
    DEFINE VARIABLE cString AS CHARACTER NO-UNDO.
    
    FIND tRueckst WHERE RECID(tRueckst) = ipRecid        NO-LOCK.
    FIND Aufze    WHERE RECID(Aufze)    = tRueckst.Zeile NO-LOCK.

    iArtZeile = iArtZeile + 1.    
    DO WHILE Aufze.Artnr = 0:
        CREATE  tDokument.
        ASSIGN  
            tDokument.cGruppe = 'ArtikelZeile1'
            tDokument.iZeile  = iArtZeile
            tDokument.cFeld   = 'Bez1'
            tDokument.cInhalt = Aufze.Bez1.
                
        IF Aufze.Bez2 <> '' THEN 
        DO:
            iArtZeile = iArtZeile + 1.
            CREATE  tDokument.
            ASSIGN  
                tDokument.cGruppe = 'ArtikelZeile1'
                tDokument.iZeile  = iArtZeile
                tDokument.cFeld   = 'Bez1'
                tDokument.cInhalt = Aufze.Bez2.
        END.
        RETURN.
    END.

    FIND Artst OF Aufze NO-LOCK.
            
    FIND VGebinde NO-LOCK
        WHERE VGebinde.Firma  = cFirma
        AND   VGebinde.Geb_Cd = Aufze.VGeb_Cd NO-ERROR.
    FIND KGebinde NO-LOCK
        WHERE KGebinde.Firma  = cFirma
        AND   KGebinde.Geb_Cd = Aufze.KGeb_Cd NO-ERROR.

    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'KGebinde', KGebinde.Kbez ).
    
    IF Aufze.VGeb_Ru <> 0 THEN 
    DO:
        cString = STRING(Aufze.VGeb_Ru,'->>>>')
            + 'x '
            + VGebinde.KBez.
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'VGebinde', cString ).
    END.
    
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Menge', STRING(Aufze.MRuek,'->>,>>9') ).


    cString = Aufze.Bez1.
    IF Aufze.Bez2 <> '' THEN cString = cString
            + (IF cString = '' THEN '' ELSE CHR(10))
            + Aufze.Bez2.
    IF Aufze.Aktion     THEN cString = cString
            + (IF cString = '' THEN '' ELSE CHR(10))
            + Aufze.Aktion_Text.
    RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Bez1', cString ).
    
    IF Aufze.Jahr > 9 THEN 
    DO:
        cString = STRING(Aufze.Jahr,"9999").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'JG', cString ).
    END.
    
    IF Aufze.Alk_Gehalt <> 0 THEN 
    DO:
        cString = STRING(Aufze.Alk_Gehalt,"zz9.9%").
        RUN VIPER_CREATE_DOKUMENT ( 'ArtikelZeile1', iArtZeile, 'Alk%', cString ).
    END.
    RUN AUSGABE_GRUPPE ( 'ArtikelZeile1' ).
    
    RELEASE Aufze   .
    RELEASE Artst   .
    RELEASE VGebinde.
    RELEASE KGebinde.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-FUELLEN_tAufze) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE FUELLEN_tAufze Procedure 
PROCEDURE FUELLEN_tAufze :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipAufnr     AS INTEGER          NO-UNDO.

    DEFINE VARIABLE minPos     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE maxPos     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE jPlatz     AS INTEGER   NO-UNDO.
    DEFINE VARIABLE cLagOrt    AS CHARACTER NO-UNDO.
    DEFINE VARIABLE iRuestArt  AS INTEGER   NO-UNDO.
    DEFINE VARIABLE iPlusMinus AS INTEGER   NO-UNDO.
    DEFINE VARIABLE lArtikel   AS LOG       NO-UNDO.

    EMPTY TEMP-TABLE tAufze.
    
    FIND Steuer NO-LOCK
        WHERE Steuer.Firma = cFirma NO-ERROR.
    IF AVAILABLE Steuer THEN iRuestArt = Steuer.RuestArt.

    ASSIGN  
        minPos     = 0
        maxPos     = 9999
        iPlusMinus = 0.
            
    /*  Kommentar zu Beginn eines Auftrages     */
    lArtikel = FALSE.
    FOR EACH Aufze NO-LOCK
        WHERE Aufze.Firma = cFirma
        AND   Aufze.Aufnr = ipAufnr
        AND   Aufze.Pos   > minPos:
        IF Aufze.Artnr > 0 THEN 
        DO:
            lArtikel = TRUE.
            LEAVE.
        END.
        
        minPos = Aufze.Pos.
        CREATE  tAufze.
        ASSIGN  
            tAufze.Aufnr  = Aufze.Aufnr
            tAufze.Artnr  = Aufze.Artnr
            tAufze.Inhalt = Aufze.Inhalt
            tAufze.Jahr   = Aufze.Jahr
            tAufze.Pos    = Aufze.Pos
            tAufze.Zeile  = RECID(Aufze)
            tAufze.Aktion = Aufze.Aktion
            tAufze.Preis  = Aufze.Preis
            tAufze.MGeli  = Aufze.MGeli
            tAufze.MRuek  = Aufze.MRuek.
                
        ASSIGN  
            tAufze.Sort1 = STRING(0,'99')
            tAufze.Sort2 = ''
            tAufze.Sort3 = STRING(tAufze.Artnr ,'999999')
                             + STRING(tAufze.Inhalt,'9999')
                             + STRING(tAufze.Jahr  ,'9999')
                             + STRING(iPlusMinus   ,'9')
                             + STRING(tAufze.Pos   ,'99999').
        tAufze.LagOrt = ''.
    END.
    
    /*  Kommentar am Ende eines Auftrages       */
    IF lArtikel THEN 
    DO:
        FOR EACH Aufze NO-LOCK
            WHERE Aufze.Firma = cFirma
            AND   Aufze.Aufnr = ipAufnr
            BY Aufze.Pos DESCENDING:
            IF Aufze.Artnr > 0 THEN LEAVE.
            
            maxPos = Aufze.Pos.
            CREATE  tAufze.
            ASSIGN  
                tAufze.Aufnr  = Aufze.Aufnr
                tAufze.Artnr  = Aufze.Artnr
                tAufze.Inhalt = Aufze.Inhalt
                tAufze.Jahr   = Aufze.Jahr
                tAufze.Pos    = Aufze.Pos
                tAufze.Zeile  = RECID(Aufze)
                tAufze.Aktion = Aufze.Aktion
                tAufze.Preis  = Aufze.Preis
                tAufze.MGeli  = Aufze.MGeli
                tAufze.MRuek  = Aufze.MRuek.
                    
            ASSIGN  
                tAufze.Sort1 = STRING(0,'99')
                tAufze.Sort2 = ''
                tAufze.Sort3 = STRING(tAufze.Artnr ,'999999')
                                 + STRING(tAufze.Inhalt,'9999')
                                 + STRING(tAufze.Jahr  ,'9999')
                                 + STRING(iPlusMinus   ,'9')
                                 + STRING(tAufze.Pos   ,'99999').
            tAufze.LagOrt = ''.
        END.
    END.
    
    /*  Artikelzeilen nach Ruestplatz und Ort   */
    cLagOrt = ''.
    FOR EACH Aufze NO-LOCK
        WHERE Aufze.Firma = cFirma
        AND   Aufze.Aufnr = ipAufnr
        AND   Aufze.Pos   > minPos
        AND   Aufze.Pos   < MaxPos
        BY Aufze.Pos DESCENDING:
            
        IF Aufze.Artnr > 0 THEN 
        DO:
            FIND ArtLager NO-LOCK
                WHERE ArtLager.Firma  = Aufze.Firma
                AND   ArtLager.Artnr  = Aufze.Artnr
                AND   ArtLager.Inhalt = Aufze.Inhalt
                AND   ArtLager.Jahr   = Aufze.Jahr
                AND   ArtLager.Lager  = Aufze.Lager.
            cLagOrt = ArtLager.Ort.
        END.
        iPlusMinus = (IF Aufze.MGeli < 0 THEN 1 ELSE 0).
        FIND LAST RuestPlatz USE-INDEX RuestPlatz-k2
            WHERE RuestPlatz.Firma     = Aufze.Firma
            AND   RuestPlatz.RuestArt  = iRuestArt
            AND   RuestPlatz.abLagOrt <= cLagOrt NO-ERROR.
        IF NOT AVAILABLE RuestPlatz THEN jPlatz = 90.
        ELSE                             jPlatz = RuestPlatz.Platz.
        CREATE  tAufze.
        ASSIGN  
            tAufze.Aufnr  = Aufze.Aufnr
            tAufze.Artnr  = Aufze.Artnr
            tAufze.Inhalt = Aufze.Inhalt
            tAufze.Jahr   = Aufze.Jahr
            tAufze.Pos    = Aufze.Pos
            tAufze.Zeile  = RECID(Aufze)
            tAufze.Aktion = Aufze.Aktion
            tAufze.Preis  = Aufze.Preis
            tAufze.MGeli  = Aufze.MGeli
            tAufze.MRuek  = Aufze.MRuek.
                
        ASSIGN  
            tAufze.Sort1 = STRING(jPlatz,'99')
            tAufze.Sort2 = cLagOrt
            tAufze.Sort3 = STRING(tAufze.Artnr ,'999999')
                             + STRING(tAufze.Inhalt,'9999')
                             + STRING(tAufze.Jahr  ,'9999')
                             + STRING(iPlusMinus   ,'9')
                             + STRING(tAufze.Pos   ,'99999').
        tAufze.LagOrt = cLagort.
                
        IF tAufze.MRuek > 0 THEN 
        DO:
            CREATE  tRueckst.
            BUFFER-COPY tAufze
                TO      tRueckst
                ASSIGN  
                tRueckst.Zeile = RECID(Aufze).
        END.
        
        IF  tAufze.Artnr > 0  AND
            tAufze.MGeli = 0  THEN DELETE tAufze.
    END.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-SEND_MAIL) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE SEND_MAIL Procedure 
PROCEDURE SEND_MAIL :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipAttachment    AS CHARACTER     NO-UNDO.

    FIND FIRST tParam.

    DEFINE VARIABLE cTo       AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cCc       AS CHARACTER NO-UNDO.
    DEFINE VARIABLE lRetValue AS LOG       NO-UNDO.
    DEFINE VARIABLE cMeldung  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cSubject  AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cBody     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cQuittung AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cName     AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE iInd      AS INTEGER   NO-UNDO.
    DEFINE VARIABLE cNamen    AS CHARACTER NO-UNDO.
    
    FIND FIRST tParam.    
    
    FIND Adresse NO-LOCK
        WHERE Adresse.Firma = AdFirma
        AND   Adresse.Knr   = tParam.iKnr NO-ERROR.
    cTo = Adresse.Mail.
    cCc = 'wr@adprime.ch'.
    
    IF cTo             = '' THEN RETURN.
    IF INDEX(cTo, '@') = 0 THEN RETURN.

    cSubject     = SUBSTITUTE('Lieferschein &1 vom &2', tParam.iAufnr, STRING(TODAY,'99.99.9999') ).
    cBody        = SUBSTITUTE('Im Anhang den Lieferschein/die Rechnung von der Lieferung vom &1 ', STRING(TODAY,'99.99.9999') ).
    cQuittung    = SUBSTITUTE('&1&2-&3-Quittung.pdf', cPathQuittung, STRING(tParam.iKnr,'999999'), STRING(tParam.iAufnr,'9999999')).
    
    FILE-INFO:FILE-NAME = cQuittung.
    cQuittung    = FILE-INFO:FULL-PATHNAME NO-ERROR.
    IF cQuittung = ? THEN cQuittung = ''.
    IF cQuittung <> '' THEN 
    DO:
        ipAttachment = ipAttachment
            + (IF ipAttachment = '' THEN '' ELSE ';')
            + cQuittung.
    END.
                  
    DO ii = 1 TO NUM-ENTRIES(ipAttachment, ';'):
        cName  = ENTRY(ii, ipAttachment, ';').
        cName  = REPLACE(cName, '\', '/').
        IF R-INDEX(cName, '/') > 0 THEN cName = SUBSTRING(cName, R-INDEX(cName, '/') + 1).
        cNamen = cNamen
            + (IF cNamen = '' THEN '' ELSE ';')
            + cName.
    END.

    EMPTY TEMP-TABLE ttSendMail.
    CREATE  ttSendMail.
    ASSIGN  
        ttSendMail.cFrom         = cMailFromFreigabe
        ttSendMail.cTo           = cTo
        ttSendMail.cCC           = cCC /* cMailCCFreigabe*/
        ttSendMail.cSubject      = cSubject
        ttSendMail.cBody         = cBody
        ttSendMail.cAttachedName = cNamen
        ttSendMail.cAttachedFile = ipAttachment
        ttSendMail.cMailServer   = cMailServer
        ttSendMail.cMailPort     = cMailPort
        ttSendMail.cMailKonto    = cMailKonto
        ttSendMail.cMailPassw    = cMailPassw
        ttSendMail.cDomaine      = cMailDomaine
        ttsendmail.lAuth         = lMailAuth
        ttSendMail.lSSLEnabled   = lSSLEnabled.
        
    RUN sendsmtpmail.p ( httSendMail, OUTPUT cMeldung, OUTPUT lRetValue ).

    RETURN cMeldung.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-VIPER_CREATE_DOKUMENT) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE VIPER_CREATE_DOKUMENT Procedure 
PROCEDURE VIPER_CREATE_DOKUMENT :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE INPUT PARAMETER ipGruppe    AS CHARACTER         NO-UNDO.
    DEFINE INPUT PARAMETER ipZeile     AS INTEGER          NO-UNDO.
    DEFINE INPUT PARAMETER ipFeld      AS CHARACTER         NO-UNDO.
    DEFINE INPUT PARAMETER ipInhalt    AS CHARACTER         NO-UNDO.
    
    CREATE  tDokument.
    ASSIGN  
        tDokument.cGruppe = ipGruppe
        tDokument.iZeile  = ipZeile
        tDokument.cFeld   = ipFeld
        tDokument.cInhalt = ipInhalt.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-VIPER_INIT) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE VIPER_INIT Procedure 
PROCEDURE VIPER_INIT :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE cTemplate AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cDokument AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cZellen   AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cZelle    AS CHARACTER NO-UNDO.
    DEFINE VARIABLE cGruppe   AS CHARACTER NO-UNDO.
    DEFINE VARIABLE ii        AS INTEGER   NO-UNDO.
    DEFINE VARIABLE cString   AS CHARACTER NO-UNDO.
    
    FIND FIRST tParam.

    IF iLauf = 1 THEN 
    DO:
        cTemplate = tParam.cInstall  + '/' + tParam.cDokument + '.vfr'.
        RUN vpr_LoadVFR         (cTemplate).
        RUN vpr_ActivateReport  (tParam.cDokument).
        RUN vpr_SelectPrinter   (tParam.Drucker).
        RUN vpr_setPrinterAttrib('duplex=1').
/*        cString = SUBSTITUTE('copies=&1', tParam.Anzahl). */
/*        IF tParam.lBatch THEN RUN vpr_SetPrinterAttrib('copies=1').*/
/*        ELSE                  RUN vpr_SetPrinterAttrib('copies=2').*/
        RUN vpr_SetPrinterAttrib('copies=2').
        RUN vpr_ResetDoc.
        RUN vpr_SetDocAttrib    ('PAPERSIZE=A4').
        RUN vpr_SetPreviewMode  ('Direct').
        RUN vpr_setDocTitle     (tParam.cDokument).
        IF tParam.Schacht_Original > 0 THEN RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Original ).
    END.
    ELSE 
    DO:
        RUN vpr_NewPage.
        IF tParam.Schacht_Kopie    > 0 THEN RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Kopie    ).
    END.
    RUN vpr_InitGroups("").
    RUN vpr_InitGraphObj.
    
    RUN vpr_SetGroupAttrib ("Kopf"     , "Fixed=true").
    RUN vpr_SetGroupAttrib ("Fusstext" , "Fixed=true").
    RUN vpr_SetGroupAttrib ("Kondition", "Fixed=true").
    
    iMaxPos = 2650.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF

&IF DEFINED(EXCLUDE-VIPER_NEUE_SEITE) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE VIPER_NEUE_SEITE Procedure 
PROCEDURE VIPER_NEUE_SEITE :
    /*------------------------------------------------------------------------------
      Purpose:     
      Parameters:  <none>
      Notes:       
    ------------------------------------------------------------------------------*/

    DEFINE VARIABLE iPos AS INTEGER NO-UNDO.
    
    FIND FIRST tParam.

    DO WHILE TRUE:
        IF iSeite = 0 THEN 
        DO:
            RUN vpr_InitGroups('').
            IF iLauf = iAnzDok THEN RUN vpr_initGraphObj.
            iSeite = iSeite + 1.
            LEAVE.
        END.
        
        RUN vpr_NewPage.
        RUN vpr_InitGroups('').
        IF iLauf = 1       THEN RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Original ).
        ELSE                    RUN vpr_SetCurrentPageProperties ( "Papertray", tParam.Schacht_Kopie    ).
        RUN vpr_initGraphObj.
        iSeite = iSeite + 1.
        LEAVE.
    END.
    
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ENDIF



/* ************************  Function Implementations ***************** */
&IF DEFINED(EXCLUDE-generateLSMail) = 0 &THEN

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _FUNCTION generateLSMail Procedure
FUNCTION generateLSMail RETURNS LOGICAL 
    ( iprsAufko AS RECID  ):
    /*------------------------------------------------------------------------------
     Purpose:
     Notes:
    ------------------------------------------------------------------------------*/

    DEFINE BUFFER bsAufko  FOR sAufko.
    DEFINE BUFFER mAdresse FOR Adresse.
    DEFINE BUFFER mDebst   FOR Debst.
    
    FIND bsAufko WHERE RECID(bsAufko) = iprsAufko.

END FUNCTION.
    
/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ENDIF