GeMIS_WEB/GUI/g-p_auftrag-analyse.w

&ANALYZE-SUSPEND _VERSION-NUMBER AB_v10r12 GUI ADM2
&ANALYZE-RESUME
&Scoped-define WINDOW-NAME CURRENT-WINDOW
&Scoped-define FRAME-NAME gAuftragsanalyse
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _DEFINITIONS gAuftragsanalyse 
/*------------------------------------------------------------------------

  File: 

  Description: from cntnrdlg.w - ADM2 SmartDialog Template

  Input Parameters:
      <none>

  Output Parameters:
      <none>

  Author: 

  Created: 
------------------------------------------------------------------------*/
/*          This .W file was created with the Progress AppBuilder.      */
/*----------------------------------------------------------------------*/

/* Create an unnamed pool to store all the widgets created 
     by this procedure. This is a good default which assures
     that this procedure's triggers and internal procedures 
     will execute in this procedure's storage, and that proper
     cleanup will occur on deletion of the procedure. */

CREATE WIDGET-POOL.

/* ***************************  Definitions  ************************** */

/* Parameters Definitions ---                                           */

/* Local Variable Definitions ---                                       */

DEF VAR MaxPage         AS INT                      NO-UNDO.
DEF VAR AktSeite        AS INT                      NO-UNDO.
DEF VAR FMutFlag        AS LOG                      NO-UNDO.
DEF VAR Firma           AS CHAR                     NO-UNDO.
DEF VAR AdFirma         AS CHAR                     NO-UNDO.

DEF VAR cVorlage        AS CHAR                     NO-UNDO.
DEF VAR cDaten          AS CHAR                     NO-UNDO.
DEF VAR cDokument       AS CHAR                     NO-UNDO.
DEF VAR cDateiName      AS CHAR                     NO-UNDO.
DEF VAR Zelle           AS CHAR                     NO-UNDO.
DEF VAR excelAppl       AS COM-HANDLE               NO-UNDO.

DEF TEMP-TABLE TUmsatz  FIELD Knr       AS INT
                        FIELD Aufnr     AS INT
                        FIELD Datum     AS DATE
                        FIELD Anz_Fak   AS INT
                        FIELD Anz_Zei   AS INT
                        FIELD Brutto    AS DEC  DECIMALS 4
                        FIELD Netto     AS DEC  DECIMALS 4
                        FIELD Rabatte   AS DEC  DECIMALS 4
                        FIELD EP        AS DEC  DECIMALS 4
                        FIELD Gewicht   AS DEC  DECIMALS 4
                        FIELD Anz_KGeb  AS DEC
                        FIELD Anz_VGeb  AS DEC 
                        FIELD Adresse   AS CHAR

                        INDEX TUmsatz-k1
                              Knr
                              Aufnr .

DEF BUFFER BUmsatz      FOR TUmsatz.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ANALYZE-SUSPEND _UIB-PREPROCESSOR-BLOCK 

/* ********************  Preprocessor Definitions  ******************** */

&Scoped-define PROCEDURE-TYPE SmartDialog
&Scoped-define DB-AWARE no

&Scoped-define ADM-CONTAINER DIALOG-BOX

&Scoped-define ADM-SUPPORTED-LINKS Data-Target,Data-Source,Page-Target,Update-Source,Update-Target

/* Name of designated FRAME-NAME and/or first browse and/or first query */
&Scoped-define FRAME-NAME gAuftragsanalyse

/* Standard List Definitions                                            */
&Scoped-Define ENABLED-OBJECTS RECT-12 F_VonKnr F_BisKnr F_Kundengrp F_Tour ~
F_Vertreter F_VonArtnr F_BisArtnr F_Warengrp F_VonDatum F_BisDatum T_Marge ~
T_Detail Btn_OK Btn_Cancel 
&Scoped-Define DISPLAYED-OBJECTS F_VonKnr F_BisKnr F_Kundengrp F_Tour ~
F_Vertreter F_VonArtnr F_BisArtnr F_Warengrp F_VonDatum F_BisDatum T_Marge ~
T_Detail 

/* Custom List Definitions                                              */
/* List-1,List-2,List-3,List-4,List-5,List-6                            */
&Scoped-define List-6 F_VonKnr F_BisKnr F_Kundengrp F_Tour F_Vertreter ~
F_VonArtnr F_BisArtnr F_Warengrp F_VonDatum F_BisDatum T_Marge T_Detail 

/* _UIB-PREPROCESSOR-BLOCK-END */
&ANALYZE-RESUME



/* ***********************  Control Definitions  ********************** */

/* Define a dialog box                                                  */

/* Definitions of the field level widgets                               */
DEFINE BUTTON Btn_Cancel AUTO-END-KEY 
     LABEL "&abbrechen" 
     SIZE 14 BY 1.19.

DEFINE BUTTON Btn_OK 
     IMAGE-UP FILE "grafik/results%.ico":U
     IMAGE-INSENSITIVE FILE "grafik/results%.ico":U
     LABEL "Excel" 
     SIZE 7 BY 1.71.

DEFINE VARIABLE F_BisArtnr AS INTEGER FORMAT "999999":U INITIAL 0 
     LABEL "-" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 11 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_BisDatum AS DATE FORMAT "99.99.9999":U 
     LABEL "-" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 16 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_BisKnr AS INTEGER FORMAT "999999":U INITIAL 0 
     LABEL "-" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 11 BY 1 TOOLTIP "ALT-F suchen einer Kundennummer"
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_Kundengrp AS CHARACTER FORMAT "X(256)":U 
     LABEL "Kudengruppen" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 46.4 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_Tour AS CHARACTER FORMAT "X(256)":U 
     LABEL "Tourenplan" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 46.4 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_Vertreter AS CHARACTER FORMAT "X(256)":U 
     LABEL "Vertreter" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 46.4 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_VonArtnr AS INTEGER FORMAT "999999":U INITIAL 0 
     LABEL "von - bis Artikelnummer" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 11 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_VonDatum AS DATE FORMAT "99.99.9999":U 
     LABEL "von - bis Datum" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 16 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_VonKnr AS INTEGER FORMAT "999999":U INITIAL 0 
     LABEL "von - bis Knr" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 11 BY 1 TOOLTIP "ALT-F suchen einer Kundennummer"
     BGCOLOR 15  NO-UNDO.

DEFINE VARIABLE F_Warengrp AS CHARACTER FORMAT "X(256)":U 
     LABEL "Warengruppen" 
     VIEW-AS FILL-IN NATIVE 
     SIZE 46.4 BY 1
     BGCOLOR 15  NO-UNDO.

DEFINE RECTANGLE RECT-12
     EDGE-PIXELS 2 GRAPHIC-EDGE  NO-FILL   
     SIZE 84 BY 14.05.

DEFINE VARIABLE T_Detail AS LOGICAL INITIAL no 
     LABEL "Details ? (jeden Lieferschein)" 
     VIEW-AS TOGGLE-BOX
     SIZE 40.2 BY 1 NO-UNDO.

DEFINE VARIABLE T_Marge AS LOGICAL INITIAL no 
     LABEL "Margenberechnung ?" 
     VIEW-AS TOGGLE-BOX
     SIZE 40.2 BY 1 NO-UNDO.


/* ************************  Frame Definitions  *********************** */

DEFINE FRAME gAuftragsanalyse
     F_VonKnr AT ROW 2 COL 28 COLON-ALIGNED
     F_BisKnr AT ROW 2 COL 41 COLON-ALIGNED
     F_Kundengrp AT ROW 3 COL 28 COLON-ALIGNED
     F_Tour AT ROW 4 COL 28 COLON-ALIGNED
     F_Vertreter AT ROW 5 COL 28 COLON-ALIGNED
     F_VonArtnr AT ROW 6.52 COL 28 COLON-ALIGNED
     F_BisArtnr AT ROW 6.52 COL 41 COLON-ALIGNED
     F_Warengrp AT ROW 7.52 COL 28 COLON-ALIGNED
     F_VonDatum AT ROW 9 COL 28 COLON-ALIGNED
     F_BisDatum AT ROW 9 COL 47 COLON-ALIGNED
     T_Marge AT ROW 10.52 COL 30
     T_Detail AT ROW 11.52 COL 30
     Btn_OK AT ROW 13.29 COL 30
     Btn_Cancel AT ROW 13.52 COL 55.8
     RECT-12 AT ROW 1.24 COL 2
     SPACE(0.99) SKIP(0.22)
    WITH VIEW-AS DIALOG-BOX KEEP-TAB-ORDER 
         SIDE-LABELS NO-UNDERLINE THREE-D  SCROLLABLE 
         TITLE "Auftragsanalyse"
         CANCEL-BUTTON Btn_Cancel.


/* *********************** Procedure Settings ************************ */

&ANALYZE-SUSPEND _PROCEDURE-SETTINGS
/* Settings for THIS-PROCEDURE
   Type: SmartDialog
   Allow: Basic,Browse,DB-Fields,Query,Smart
   Container Links: Data-Target,Data-Source,Page-Target,Update-Source,Update-Target
   Design Page: 1
   Other Settings: COMPILE
 */
&ANALYZE-RESUME _END-PROCEDURE-SETTINGS

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _INCLUDED-LIB gAuftragsanalyse 
/* ************************* Included-Libraries *********************** */

{src/adm2/containr.i}

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME




/* ***********  Runtime Attributes and AppBuilder Settings  *********** */

&ANALYZE-SUSPEND _RUN-TIME-ATTRIBUTES
/* SETTINGS FOR DIALOG-BOX gAuftragsanalyse
   FRAME-NAME                                                           */
ASSIGN 
       FRAME gAuftragsanalyse:SCROLLABLE       = FALSE
       FRAME gAuftragsanalyse:HIDDEN           = TRUE.

/* SETTINGS FOR FILL-IN F_BisArtnr IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_BisDatum IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_BisKnr IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_Kundengrp IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_Tour IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_Vertreter IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_VonArtnr IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_VonDatum IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_VonKnr IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR FILL-IN F_Warengrp IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR TOGGLE-BOX T_Detail IN FRAME gAuftragsanalyse
   6                                                                    */
/* SETTINGS FOR TOGGLE-BOX T_Marge IN FRAME gAuftragsanalyse
   6                                                                    */
/* _RUN-TIME-ATTRIBUTES-END */
&ANALYZE-RESUME


/* Setting information for Queries and Browse Widgets fields            */

&ANALYZE-SUSPEND _QUERY-BLOCK DIALOG-BOX gAuftragsanalyse
/* Query rebuild information for DIALOG-BOX gAuftragsanalyse
     _Options          = "SHARE-LOCK"
     _Query            is NOT OPENED
*/  /* DIALOG-BOX gAuftragsanalyse */
&ANALYZE-RESUME

 



/* ************************  Control Triggers  ************************ */

&Scoped-define SELF-NAME gAuftragsanalyse
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL gAuftragsanalyse gAuftragsanalyse
ON END-ERROR OF FRAME gAuftragsanalyse /* Auftragsanalyse */
DO:
    RUN ENDE.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL gAuftragsanalyse gAuftragsanalyse
ON GO OF FRAME gAuftragsanalyse /* Auftragsanalyse */
DO:
    /*
    RUN ENDE_PROGRAMM ( INPUT THIS-PROCEDURE:FILE-NAME ) NO-ERROR.
    */
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL gAuftragsanalyse gAuftragsanalyse
ON WINDOW-CLOSE OF FRAME gAuftragsanalyse /* Auftragsanalyse */
DO:  
    RUN ENDE.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME Btn_Cancel
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL Btn_Cancel gAuftragsanalyse
ON CHOOSE OF Btn_Cancel IN FRAME gAuftragsanalyse /* abbrechen */
DO:
    RUN ENDE.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME Btn_OK
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL Btn_OK gAuftragsanalyse
ON CHOOSE OF Btn_OK IN FRAME gAuftragsanalyse /* Excel */
DO:
    DO WITH FRAME {&FRAME-NAME}:
        Btn_OK:SENSITIVE     = FALSE.
        Btn_Cancel:SENSITIVE = FALSE.
        SESSION:SET-WAIT-STATE ('GENERAL').
    END.
    RUN REPORT.
    DO WITH FRAME {&FRAME-NAME}:
        Btn_OK:SENSITIVE     = TRUE.
        Btn_Cancel:SENSITIVE = TRUE.
        SESSION:SET-WAIT-STATE('').
    END.
    RUN ENDE.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME F_BisKnr
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL F_BisKnr gAuftragsanalyse
ON ALT-F OF F_BisKnr IN FRAME gAuftragsanalyse /* - */
DO:
    DEF VAR iRecid      AS RECID                    NO-UNDO.

    RUN 'g-suchen-adresse.w':U ( 'AUF', OUTPUT iRecid ).
    IF iRecid = ? OR
       iRecid = 0 THEN RETURN NO-APPLY.
    FIND Adresse NO-LOCK WHERE RECID(Adresse) = iRecid NO-ERROR.
    SELF:SCREEN-VALUE = STRING(Adresse.Knr).
    APPLY 'ENTRY' TO SELF.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME F_Kundengrp
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL F_Kundengrp gAuftragsanalyse
ON RIGHT-MOUSE-CLICK OF F_Kundengrp IN FRAME gAuftragsanalyse /* Kudengruppen */
DO:
    RUN g-auswahl-tabelle.w ( INPUT SELF, INPUT 'KUNDGRP' ).
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME F_Tour
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL F_Tour gAuftragsanalyse
ON RIGHT-MOUSE-CLICK OF F_Tour IN FRAME gAuftragsanalyse /* Tourenplan */
DO:
    RUN g-auswahl-tabelle.w ( INPUT SELF, INPUT 'TOUR1' ).
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME F_Vertreter
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL F_Vertreter gAuftragsanalyse
ON RIGHT-MOUSE-CLICK OF F_Vertreter IN FRAME gAuftragsanalyse /* Vertreter */
DO:
    RUN g-auswahl-tabelle.w ( INPUT SELF, INPUT 'VERTR' ).
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME F_VonKnr
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL F_VonKnr gAuftragsanalyse
ON ALT-F OF F_VonKnr IN FRAME gAuftragsanalyse /* von - bis Knr */
DO:
    DEF VAR iRecid      AS RECID                    NO-UNDO.

    RUN 'g-suchen-adresse.w':U ( 'AUF', OUTPUT iRecid ).
    IF iRecid = ? OR
       iRecid = 0 THEN RETURN NO-APPLY.
    FIND Adresse NO-LOCK WHERE RECID(Adresse) = iRecid NO-ERROR.
    SELF:SCREEN-VALUE = STRING(Adresse.Knr).
    F_BisKnr:SCREEN-VALUE = STRING(Adresse.Knr).
    APPLY 'ENTRY' TO SELF.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME F_Warengrp
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL F_Warengrp gAuftragsanalyse
ON RIGHT-MOUSE-CLICK OF F_Warengrp IN FRAME gAuftragsanalyse /* Warengruppen */
DO:
    RUN g-auswahl-wgr.w ( INPUT SELF ).
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME T_Detail
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL T_Detail gAuftragsanalyse
ON RETURN OF T_Detail IN FRAME gAuftragsanalyse /* Details ? (jeden Lieferschein) */
DO:
    APPLY 'TAB' TO SELF.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&Scoped-define SELF-NAME T_Marge
&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CONTROL T_Marge gAuftragsanalyse
ON RETURN OF T_Marge IN FRAME gAuftragsanalyse /* Margenberechnung ? */
DO:
    APPLY 'TAB' TO SELF.
    RETURN NO-APPLY.
END.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


&UNDEFINE SELF-NAME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _CUSTOM _MAIN-BLOCK gAuftragsanalyse 


/* ***************************  Main Block  *************************** */

    MaxPage  = 1.
    AktSeite = 1.
    Firma    = DYNAMIC-FUNCTION('GETMANDANT':U)   NO-ERROR.
    AdFirma  = DYNAMIC-FUNCTION('GETADMANDANT':U) NO-ERROR.

    SESSION:DATA-ENTRY-RETURN = TRUE.

/*  TRIGGERS    ------------------------------------------------------  */

/*
    ON 'END-ERROR':U OF FRAME {&FRAME-NAME} ANYWHERE
    DO:
        FMutFlag = DYNAMIC-FUNCTION('getMutflagAlt':U) NO-ERROR.
        IF FMutFlag = FALSE THEN DO:
            RUN ENDE.
            RETURN NO-APPLY.
        END.
        RUN TOOLBAR IN h_dyntoolbar ( INPUT 'CANCEL':U ).
        RETURN NO-APPLY.
    END.
*/    
/*  ------------------------------------------------------------------  */

    {src/adm2/dialogmn.i}

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME


/* **********************  Internal Procedures  *********************** */

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE adm-create-objects gAuftragsanalyse  _ADM-CREATE-OBJECTS
PROCEDURE adm-create-objects :
/*------------------------------------------------------------------------------
  Purpose:     Create handles for all SmartObjects used in this procedure.
               After SmartObjects are initialized, then SmartLinks are added.
  Parameters:  <none>
------------------------------------------------------------------------------*/

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE BEREINIGEN gAuftragsanalyse 
PROCEDURE BEREINIGEN :
/*------------------------------------------------------------------------------
  Purpose:     
  Parameters:  <none>
  Notes:       
------------------------------------------------------------------------------*/

    DEF INPUT PARAMETER ipHandle    AS HANDLE           NO-UNDO.

    DEF VAR cString     AS CHAR                     NO-UNDO.
    DEF VAR i           AS INT                      NO-UNDO.

    cString = ''.
    DO i = 1 TO LENGTH(ipHandle:SCREEN-VALUE):
        IF SUBSTRING(ipHandle:SCREEN-VALUE,i,1) < '0'    OR
           SUBSTRING(ipHandle:SCREEN-VALUE,i,1) > '9'    THEN DO:
            SUBSTRING(ipHandle:SCREEN-VALUE,i) = ','.
        END.
    END.
    DO i = 1 TO NUM-ENTRIES(ipHandle:SCREEN-VALUE, ','):
        IF cString <> '' THEN cString = cString + ','.
        cString = cString
                + STRING(INTEGER(ENTRY(i, ipHandle:SCREEN-VALUE, ',')),'999').
    END.
    ipHandle:SCREEN-VALUE = cString.
    RETURN.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE disable_UI gAuftragsanalyse  _DEFAULT-DISABLE
PROCEDURE disable_UI :
/*------------------------------------------------------------------------------
  Purpose:     DISABLE the User Interface
  Parameters:  <none>
  Notes:       Here we clean-up the user-interface by deleting
               dynamic widgets we have created and/or hide 
               frames.  This procedure is usually called when
               we are ready to "clean-up" after running.
------------------------------------------------------------------------------*/
  /* Hide all frames. */
  HIDE FRAME gAuftragsanalyse.
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE enableObject gAuftragsanalyse 
PROCEDURE enableObject :
/*------------------------------------------------------------------------------
  Purpose:     Super Override
  Parameters:  
  Notes:       
------------------------------------------------------------------------------*/

    RUN LESEN_FEHLWERTE.

    RUN SUPER.

    RUN FENSTER_TITEL ( INPUT FRAME {&FRAME-NAME}:HANDLE ) NO-ERROR.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE enable_UI gAuftragsanalyse  _DEFAULT-ENABLE
PROCEDURE enable_UI :
/*------------------------------------------------------------------------------
  Purpose:     ENABLE the User Interface
  Parameters:  <none>
  Notes:       Here we display/view/enable the widgets in the
               user-interface.  In addition, OPEN all queries
               associated with each FRAME and BROWSE.
               These statements here are based on the "Other 
               Settings" section of the widget Property Sheets.
------------------------------------------------------------------------------*/
  DISPLAY F_VonKnr F_BisKnr F_Kundengrp F_Tour F_Vertreter F_VonArtnr F_BisArtnr 
          F_Warengrp F_VonDatum F_BisDatum T_Marge T_Detail 
      WITH FRAME gAuftragsanalyse.
  ENABLE RECT-12 F_VonKnr F_BisKnr F_Kundengrp F_Tour F_Vertreter F_VonArtnr 
         F_BisArtnr F_Warengrp F_VonDatum F_BisDatum T_Marge T_Detail Btn_OK 
         Btn_Cancel 
      WITH FRAME gAuftragsanalyse.
  VIEW FRAME gAuftragsanalyse.
  {&OPEN-BROWSERS-IN-QUERY-gAuftragsanalyse}
END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE ENDE gAuftragsanalyse 
PROCEDURE ENDE :
/*------------------------------------------------------------------------------
  Purpose:     
  Parameters:  <none>
  Notes:       
------------------------------------------------------------------------------*/

    AktSeite = DYNAMIC-FUNCTION('getCurrentPage':U) NO-ERROR.

    IF AktSeite > 1 THEN DO:
        RUN selectPage ( INPUT 1 ).
        RETURN NO-APPLY.
    END.

    RUN ENDE_PROGRAMM ( INPUT THIS-PROCEDURE:FILE-NAME ).
    APPLY 'GO' TO FRAME {&FRAME-NAME}.
    RETURN NO-APPLY.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE exitObject gAuftragsanalyse 
PROCEDURE exitObject :
/*------------------------------------------------------------------------------
  Purpose:     Super Override
  Parameters:  
  Notes:       
------------------------------------------------------------------------------*/

    RUN ENDE.
    RETURN NO-APPLY.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE KOPF gAuftragsanalyse 
PROCEDURE KOPF :
/*------------------------------------------------------------------------------
  Purpose:     
  Parameters:  <none>
  Notes:       
------------------------------------------------------------------------------*/

    DEF INPUT PARAMETER eh  AS COM-HANDLE       NO-UNDO.

    DEF VAR Zelle   AS CHAR                     NO-UNDO.

    FIND Steuer USE-INDEX Steuer-k1
                WHERE Steuer.Firma = Firma NO-LOCK NO-ERROR.

    IF T_Marge THEN DO:
        Zelle = 'B1'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = Steuer.Firma1.
        Zelle = 'C1'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = 'Auftragsstatistik'.
        Zelle = 'K1'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = 'Datum : ' + STRING(TODAY,'99.99.9999').

        Zelle = 'B2'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = Steuer.Ort.
        Zelle = 'C2'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = STRING(F_VonDatum,'99.99.9999')
                           + ' - '
                           + STRING(F_BisDatum,'99.99.9999').
        Zelle = 'K2'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = 'Zeit  :     ' + STRING(TIME,'HH:MM:SS').
        RETURN.
    END.

    Zelle = 'B1'.
    eh:Range(Zelle):SELECT.
    eh:SELECTION:VALUE = Steuer.Firma1.
    Zelle = 'C1'.
    eh:Range(Zelle):SELECT.
    eh:SELECTION:VALUE = 'Auftragsstatistik'.
    Zelle = 'I1'.
    eh:Range(Zelle):SELECT.
    eh:SELECTION:VALUE = 'Datum : ' + STRING(TODAY,'99.99.9999').

    Zelle = 'B2'.
    eh:Range(Zelle):SELECT.
    eh:SELECTION:VALUE = Steuer.Ort.
    Zelle = 'C2'.
    eh:Range(Zelle):SELECT.
    eh:SELECTION:VALUE = STRING(F_VonDatum,'99.99.9999')
                       + ' - '
                       + STRING(F_BisDatum,'99.99.9999').
    Zelle = 'I2'.
    eh:Range(Zelle):SELECT.
    eh:SELECTION:VALUE = 'Zeit  :     ' + STRING(TIME,'HH:MM:SS').

    IF T_Detail THEN DO:
        Zelle = 'C3'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = 'Liefer'.
        Zelle = 'C4'.
        eh:Range(Zelle):SELECT.
        eh:SELECTION:VALUE = 'Datum '.
    END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE LESEN_FEHLWERTE gAuftragsanalyse 
PROCEDURE LESEN_FEHLWERTE :
/*------------------------------------------------------------------------------
  Purpose:     
  Parameters:  <none>
  Notes:       
------------------------------------------------------------------------------*/

    DEF VAR cVal    AS CHAR                     NO-UNDO.
    DEF VAR cKey    AS CHAR                     NO-UNDO.
    DEF VAR i       AS INT                      NO-UNDO.
    DEF VAR cWert   AS CHAR                     NO-UNDO.

    cKey = ENTRY(1, THIS-PROCEDURE:FILE-NAME, '.' ) NO-ERROR.
    GET-KEY-VALUE SECTION 'Auswertungen' KEY cKey VALUE cVal.
    IF cVal = ? THEN RETURN.

DO WITH FRAME {&FRAME-NAME}:
    DO i = 1 TO NUM-ENTRIES(cVal, '@'):
        cWert = ENTRY(i, cVal, '@').
        CASE i:
            WHEN  1 THEN F_VonKnr        :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  2 THEN F_BisKnr        :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  3 THEN F_Kundengrp     :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  4 THEN F_Tour          :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  5 THEN F_Vertreter     :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  6 THEN F_VonArtnr      :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  7 THEN F_BisArtnr      :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  8 THEN F_Warengrp      :SCREEN-VALUE = cWert NO-ERROR.
            WHEN  9 THEN F_VonDatum      :SCREEN-VALUE = cWert NO-ERROR.
            WHEN 10 THEN F_BisDatum      :SCREEN-VALUE = cWert NO-ERROR.
            WHEN 11 THEN T_Marge         :SCREEN-VALUE = cWert NO-ERROR.
            WHEN 12 THEN T_Detail        :SCREEN-VALUE = cWert NO-ERROR.
        END CASE.
    END.
    ASSIGN  {&List-6}.
END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE REPORT gAuftragsanalyse 
PROCEDURE REPORT :
/*------------------------------------------------------------------------------
  Purpose:     
  Parameters:  <none>
  Notes:       
------------------------------------------------------------------------------*/

    DEF VAR ja          AS LOG                      NO-UNDO.
    DEF VAR cString     AS CHAR                     NO-UNDO.
    DEF VAR cWgr        AS CHAR                     NO-UNDO.

    DEF VAR Ep          AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR Vp          AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR Ma          AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR MWST%       AS DEC                      NO-UNDO.
    DEF VAR AnzFak      AS INT                      NO-UNDO.
    DEF VAR AnzZei      AS INT                      NO-UNDO.
    DEF VAR TotGewicht  AS DEC  DECIMALS 3          NO-UNDO.
    DEF VAR TotBrutto   AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR TotRabatt   AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR TotNetto    AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR TotEP       AS DEC  DECIMALS 4          NO-UNDO.
    DEF VAR TotKGeb     AS INT                      NO-UNDO.
    DEF VAR TotVGeb     AS INT                      NO-UNDO.

DO WITH FRAME {&FRAME-NAME}:
    RUN BEREINIGEN ( INPUT F_Kundengrp :HANDLE ).
    RUN BEREINIGEN ( INPUT F_Tour      :HANDLE ).
    RUN BEREINIGEN ( INPUT F_Vertreter :HANDLE ).
    RUN BEREINIGEN ( INPUT F_Warengrp  :HANDLE ).

    ASSIGN  {&List-6}.

    IF F_VonKnr = 0 AND F_BisKnr = 0 THEN F_BisKnr = 999999.
    IF F_VonKnr > F_BisKnr           THEN F_BisKnr = F_VonKnr.

    IF F_VonArtnr = 0 AND F_BisArtnr = 0 THEN F_BisArtnr = 999999.
    IF F_VonArtnr > F_BisArtnr THEN F_BisArtnr = F_VonArtnr.

    IF F_VonDatum = ? THEN F_VonDatum = DATE(01,01,YEAR(TODAY)).
    IF F_BisDatum = ? THEN F_BisDatum = DATE(12,31,YEAR(TODAY)).
    IF F_BisDatum < F_VonDatum THEN F_BisDatum = F_VonDatum.

    DISPLAY {&List-6}.

    RUN SCHREIBEN_FEHLWERTE.
END.

    EMPTY TEMP-TABLE TUmsatz.

    FOR EACH Savko USE-INDEX Savko-k2
                   WHERE Savko.Firma       = Firma
                   AND   Savko.Knr        >= F_VonKnr
                   AND   Savko.Knr        <= F_BisKnr
                   AND   Savko.Lief_Datum >= F_VonDatum
                   AND   Savko.Lief_Datum <= F_BisDatum NO-LOCK,
        FIRST Debst   USE-INDEX Debst-k1
                      WHERE Debst.Firma = Savko.Firma
                      AND   Debst.Knr   = Savko.Knr
                      AND   Debst.Aktiv = TRUE          NO-LOCK,
        FIRST Adresse USE-INDEX Adresse-k1
                      WHERE Adresse.Firma = AdFirma
                      AND   Adresse.Knr   = Debst.Knr
                      AND   Adresse.Aktiv = TRUE        NO-LOCK :

        IF F_Kundengrp = '' THEN.
        ELSE DO:
            IF LOOKUP(STRING(Savko.Ku_Grp  ,'999'), F_Kundengrp, ',') = 0 THEN NEXT.
        END.
        IF F_Tour      = '' THEN.
        ELSE DO:
            IF LOOKUP(STRING(Savko.Tour_Nr1,'999'), F_Tour     , ',') = 0 THEN NEXT.
        END.
        IF F_Vertreter = '' THEN.
        ELSE DO:
            IF LOOKUP(STRING(Savko.Vertr ,'999')  , F_Vertreter, ',') = 0 THEN NEXT.
        END.

        IF NOT T_Detail THEN DO:
            FIND FIRST TUmsatz USE-INDEX TUmsatz-k1
                               WHERE TUmsatz.Knr  = Savko.Knr NO-ERROR.
        END.
        ELSE DO:
            FIND FIRST TUmsatz USE-INDEX TUmsatz-k1
                               WHERE TUmsatz.Knr   = Savko.Knr
                               AND   TUmsatz.Aufnr = Savko.Aufnr NO-ERROR.
        END.
        IF NOT AVAILABLE TUmsatz THEN DO:
            CREATE  TUmsatz.
            ASSIGN  TUmsatz.Knr       = Savko.Knr
                    TUmsatz.Adresse   = Adresse.Anzeig_Br
                    TUmsatz.Anz_Fak   = 0
                    TUmsatz.Anz_Zei   = 0
                    TUmsatz.Brutto    = 0
                    TUmsatz.Netto     = 0
                    TUmsatz.Rabatte   = 0
                    TUmsatz.EP        = 0
                    TUmsatz.Gewicht   = 0
                    TUmsatz.Anz_KGeb  = 0
                    TUmsatz.Anz_VGeb  = 0.
            IF T_Detail THEN ASSIGN TUmsatz.Aufnr = Savko.Aufnr
                                    TUmsatz.Datum = Savko.Lief_Datum.
        END.

        ja = TRUE.
        FOR EACH Savze USE-INDEX Savze-k1
                       WHERE Savze.Firma  = Savko.Firma
                       AND   Savze.Aufnr  = Savko.Aufnr
                       AND   Savze.Artnr >= F_VonArtnr
                       AND   savze.Artnr <= F_BisArtnr  NO-LOCK,
            FIRST Artst   USE-INDEX Artst-k1
                          WHERE Artst.Firma  = Savze.Firma
                          AND   Artst.Artnr  = Savze.Artnr
                          AND   Artst.Inhalt = Savze.Inhalt
                          AND   Artst.Jahr   = Savze.Jahr
                          AND   Artst.Aktiv  = TRUE     NO-LOCK:
            IF F_Warengrp   = '' THEN.
            ELSE DO:
                IF LOOKUP(STRING(Artst.Wg_Grp,'999'), F_Warengrp  , ',') = 0 THEN NEXT.
            END.

            IF ja THEN DO:
                TUmsatz.Anz_Fak = TUmsatz.Anz_Fak + 1.
                ja = FALSE.
            END.

            MWST% = Savze.MWST%.
            Ep    = Savze.EP * Savze.MGel .
            Vp    = Savze.Net_Betr
                  - Savze.Auf_Rab
                  - Savze.Abh_Rab
                  - Savze.Auf_Sp_Rab.

            IF Savze.MWST_Inkl THEN DO:
                IF MWST% = 0 THEN DO:
                    FIND LAST MWSTAns USE-INDEX MWSTAns-k1
                                      WHERE MWSTAns.MWST_Cd = Savze.WuCd
                                      AND   MWSTAns.Datum  <= Savko.Kond_Datum NO-LOCK NO-ERROR.
                    IF AVAILABLE MWSTAns THEN MWST% = MWSTAns.Ansatz.
                END.
                Vp = Vp * 100 / (100 + MWST%).
            END.
            ASSIGN  TUmsatz.Anz_Zei  = TUmsatz.Anz_Zei + 1
                    TUmsatz.Brutto   = TUmsatz.Brutto  + Savze.Bru_Betr
                    TUmsatz.Netto    = TUmsatz.Netto   + Vp
                    TUmsatz.Rabatte  = TUmsatz.Rabatte
                                     + Savze.Auf_Rab
                                     + Savze.Abh_Rab
                                     + Savze.Auf_Sp_Rab
                    TUmsatz.EP       = TUmsatz.EP + EP
                    TUmsatz.Gewicht  = TUmsatz.Gewicht  + Savze.Gewicht
                    TUmsatz.Anz_KGeb = TUmsatz.Anz_KGeb + Savze.KGeb_Me
                    TUmsatz.Anz_VGeb = TUmsatz.Anz_VGeb + Savze.VGeb_Me.
        END.
    END.

    IF T_Marge = TRUE THEN cString = 'J'.
    ELSE                   cString = 'N'.

    cVorlage    = 'AuftragStat' + cString + '.xls'.
    cDokument   = 'AuftragStat' + cString + '.xls'.
    cDaten      = 'AuftragStat' + cString + '.txt'.

    cDateiName  = cDokument + CHR(01) + cVorlage.
    RUN CREATEDATEI ( INPUT cDateiName ).
    IF RETURN-VALUE BEGINS 'ERROR' THEN RETURN NO-APPLY.
    cDokument   = RETURN-VALUE.

    cDateiName  = cDaten.
    RUN CREATEDATEI ( INPUT cDateiName ).
    IF RETURN-VALUE BEGINS 'ERROR' THEN RETURN NO-APPLY.
    cDaten      = RETURN-VALUE.

    OUTPUT TO VALUE(cDaten).

    FOR EACH TUmsatz USE-INDEX TUmsatz-k1 NO-LOCK
                     BREAK BY TUmsatz.Knr
                           BY TUmsatz.Aufnr :

        Ma = 0.
        IF TUmsatz.EP    <> 0 AND
           TUmsatz.Netto <> 0 THEN Ma = 100 - (TUmsatz.EP * 100 / TUmsatz.Netto).

        IF FIRST-OF ( TUmsatz.Knr ) THEN DO:
            AnzFak     = 0.
            AnzZei     = 0.
            TotGewicht = 0.
            TotBrutto  = 0.
            TotRabatt  = 0.
            TotNetto   = 0.
            TotEP      = 0.
            TotKGeb    = 0.
            TotVGeb    = 0.
            PUT CONTROL '£'
                        STRING(TUmsatz.Knr,'999999  ')
                        TUmsatz.Adresse                                 '£'.
        END.
        ELSE DO:
            PUT CONTROL '££'.
        END.
        IF T_Detail
             THEN PUT CONTROL STRING(TUmsatz.Datum,'99.99.9999')        '£'.
        ELSE      PUT CONTROL TRIM(STRING(TUmsatz.Anz_Fak ,'->>>,>>9')) '£'.

        PUT CONTROL TRIM(STRING(TUmsatz.Anz_Zei ,'->>>,>>9'))           '£'
                    TRIM(STRING(TUmsatz.Anz_KGeb,'->>>,>>9'))           '£'
                    TRIM(STRING(TUmsatz.Anz_VGeb,'->>>,>>9'))           '£'
                    TRIM(STRING(TUmsatz.Gewicht ,'->>>,>>9.999'))       '£'
                    TRIM(STRING(TUmsatz.Brutto  ,'->>>,>>>,>>9.99'))    '£'
                    TRIM(STRING(TUmsatz.Netto   ,'->>>,>>>,>>9.99')).
        IF T_Marge THEN DO:
            PUT CONTROL '£'
                        TRIM(STRING(TUmsatz.EP,'->>>,>>>,>>9.99'))      '£'
                        TRIM(STRING(Ma        ,'->>9.99')).
        END.
        PUT CONTROL CHR(10).
        AnzFak     = AnzFak     + 1.
        AnzZei     = AnzZei     + TUmsatz.Anz_Zei.
        TotGewicht = TotGewicht + TUmsatz.Gewicht.
        TotBrutto  = TotBrutto  + TUmsatz.Brutto.
        TotRabatt  = TotRabatt  + TUmsatz.Rabatte.
        TotNetto   = TotNetto   + TUmsatz.Netto.
        TotEP      = TotEP      + TUmsatz.EP.
        TotKGeb    = TotKGeb    + TUmsatz.Anz_KGeb.
        TotVGeb    = TotVGeb    + TUmsatz.Anz_VGeb.
        IF NOT T_Detail                 THEN NEXT.
        IF NOT LAST-OF ( TUmsatz.Knr )  THEN NEXT.

        Ma = 0.
        IF TotEP    <> 0 AND
           TotNetto <> 0 THEN Ma = 100 - (TotEP * 100 / TotNetto).
        PUT CONTROL '£Kundentotal£'
                    TRIM(STRING(AnzFak      ,'->>>,>>9'))           '£'
                    TRIM(STRING(AnzZei      ,'->>>,>>9'))           '£'
                    TRIM(STRING(TotKGeb     ,'->>>,>>9'))           '£'
                    TRIM(STRING(TotVGeb     ,'->>>,>>9'))           '£'
                    TRIM(STRING(TotGewicht  ,'->>>,>>9.999'))       '£'
                    TRIM(STRING(TotBrutto   ,'->>>,>>>,>>9.99'))    '£'
                    TRIM(STRING(TotNetto    ,'->>>,>>>,>>9.99')).
        IF T_Marge THEN DO:
            PUT CONTROL '£'
                        TRIM(STRING(TotEP   ,'->>>,>>>,>>9.99'))    '£'
                        TRIM(STRING(Ma      ,'->>9.99')).
        END.
        PUT CONTROL CHR(10)
                    '£'  CHR(10).
    END.

    OUTPUT CLOSE.

    excelAppl = DYNAMIC-FUNCTION('CREATEEXCEL':U) NO-ERROR.
    IF NOT VALID-HANDLE(excelAppl) THEN DO:
        RUN FEHLER ( INPUT 1035 ).
        RETURN.
    END.

    RUN OPENEXCEL ( INPUT excelAppl, INPUT cDokument, INPUT '', OUTPUT ja ).
    IF NOT ja THEN DO:
        RUN FEHLER ( INPUT 1040 ).
        DYNAMIC-FUNCTION('RELEASEEXCEL':U, INPUT excelAppl ) NO-ERROR.
        RETURN NO-APPLY.
    END.

    Zelle = 'A6'.
    excelAppl:Range(Zelle):SELECT.
    excelAppl:SELECTION:FormulaR1C1 = 'TEXT;' + cDaten.
    excelAppl:APPLICATION:RUN ( 'DateiEinfügen' ).

    RUN KOPF ( INPUT excelAppl ).

    Zelle = 'A1'.
    excelAppl:Range(Zelle):SELECT.
    excelAppl:SELECTION:ColumnWidth = 0.3.
    
    DYNAMIC-FUNCTION('RELEASEEXCEL':U, INPUT excelAppl ) NO-ERROR.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME

&ANALYZE-SUSPEND _UIB-CODE-BLOCK _PROCEDURE SCHREIBEN_FEHLWERTE gAuftragsanalyse 
PROCEDURE SCHREIBEN_FEHLWERTE :
/*------------------------------------------------------------------------------
  Purpose:     
  Parameters:  <none>
  Notes:       
------------------------------------------------------------------------------*/

    DEF VAR cVal    AS CHAR                     NO-UNDO.
    DEF VAR cKey    AS CHAR                     NO-UNDO.

DO WITH FRAME {&FRAME-NAME}:
    ASSIGN  {&List-6}.
    cKey = ENTRY(1, THIS-PROCEDURE:FILE-NAME, '.' ) NO-ERROR.
    cVal = F_VonKnr    :SCREEN-VALUE        + '@'
         + F_BisKnr    :SCREEN-VALUE        + '@'
         + F_Kundengrp :SCREEN-VALUE        + '@'
         + F_Tour      :SCREEN-VALUE        + '@'
         + F_Vertreter :SCREEN-VALUE        + '@'
         + F_VonArtnr  :SCREEN-VALUE        + '@'
         + F_BisArtnr  :SCREEN-VALUE        + '@'
         + F_Warengrp  :SCREEN-VALUE        + '@'
         + F_VonDatum  :SCREEN-VALUE        + '@'
         + F_BisDatum  :SCREEN-VALUE        + '@'
         + T_Marge     :SCREEN-VALUE        + '@'
         + T_Detail    :SCREEN-VALUE        + '@'.
    PUT-KEY-VALUE SECTION 'Auswertungen' KEY cKey VALUE cVal.
END.

END PROCEDURE.

/* _UIB-CODE-BLOCK-END */
&ANALYZE-RESUME